C_CSPRCount

@AbapCatalog.sqlViewName: 'CCSPRCOUNT'
@EndUserText.label: 'Count Products with RFID: Count'

@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true

@AccessControl.authorizationCheck: #CHECK
@AccessControl.privilegedAssociations: ['_CountGTIN','_CountDifference','_CountProductInstance']
@ClientHandling.algorithm: #SESSION_VARIABLE

@VDM.viewType: #CONSUMPTION
@ObjectModel: {
    representativeKey: 'StoreProductRFIDCountUUID',
    usageType.serviceQuality: #C,
    usageType.sizeCategory: #L,
    usageType.dataClass: #MIXED
}
define view C_CSPRCount
  as select from I_StoreProductRFIDCount
    join         I_StoreProductRFIDCountNumbers on I_StoreProductRFIDCountNumbers.StoreProductRFIDCountUUID = I_StoreProductRFIDCount.StoreProductRFIDCountUUID
    join         I_StoreProductRFIDCountApplLog on I_StoreProductRFIDCountApplLog.StoreProductRFIDCountUUID = I_StoreProductRFIDCount.StoreProductRFIDCountUUID

  association [0..*] to C_CSPRCountGTIN            as _CountGTIN            on $projection.StoreProductRFIDCountUUID = _CountGTIN.StoreProductRFIDCountUUID
  association [0..*] to C_CSPRCountProductInstance as _CountProductInstance on $projection.StoreProductRFIDCountUUID = _CountProductInstance.StoreProductRFIDCountUUID
  association [0..*] to C_CSPRCountDifference      as _CountDifference      on $projection.StoreProductRFIDCountUUID = _CountDifference.StoreProductRFIDCountUUID
{
  key I_StoreProductRFIDCount.StoreProductRFIDCountUUID,

      I_StoreProductRFIDCount.Store,
      I_StoreProductRFIDCount.StorageLocation,
      I_StoreProductRFIDCount.StoreProductRFIDCntProcgStatus,
      I_StoreProductRFIDCount.StoreProdRFIDCntExprtnDteTme,
      cast(I_StoreProductRFIDCountApplLog.ApplicationLogHandle as abap.char(22)) as ApplicationLogHandle, // avoid edm.guid in metadata with automatic guid conversion by casting to standard string

      I_StoreProductRFIDCount.CreationDateTime,
      I_StoreProductRFIDCount.SubmissionDateTime,

      I_StoreProductRFIDCount.NumberOfExpectedItems,
      I_StoreProductRFIDCountNumbers.NumberOfCountedItems,
      I_StoreProductRFIDCountNumbers.NumberOfMissingItems,
      I_StoreProductRFIDCountNumbers.NumberOfSurplusItems,
      I_StoreProductRFIDCount.NotPostedNrOfSubmdMissingItems,
      I_StoreProductRFIDCount.NotPostedNrOfSubmdSurplusItems,
      I_StoreProductRFIDCount.SkippedNrOfSubmdMissingItems,
      I_StoreProductRFIDCount.SkippedNrOfSubmdSurplusItems,

      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _CountGTIN,
      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _CountProductInstance,
      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _CountDifference
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_STOREPRODUCTRFIDCOUNT",
"I_STOREPRODUCTRFIDCOUNTAPPLLOG",
"I_STOREPRODUCTRFIDCOUNTNUMBERS"
],
"ASSOCIATED":
[
"C_CSPRCOUNTDIFFERENCE",
"C_CSPRCOUNTGTIN",
"C_CSPRCOUNTPRODUCTINSTANCE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/