C_CH_TaxReturnBoxCube

@AbapCatalog.sqlViewName: 'CCHTAXRETURNBOXC'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'ATR enabled Tax Items for Swiss Cube'
@VDM.viewType: #CONSUMPTION
@Analytics: { dataCategory: #CUBE }
@Analytics.internalName: #LOCAL
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.dataClass: #MIXED
@Metadata.allowExtensions: true
@AccessControl.personalData.blocking: #BLOCKED_DATA_INCLUDED
define view C_CH_TaxReturnBoxCube
  with parameters
    P_StatryRptgEntity  : srf_reporting_entity,
    P_StatryRptCategory : srf_rep_cat_id,
    P_StatryRptRunID    : srf_report_run_id,
    P_ReportingCountry  : land1

  as select from            I_StRpTaxReturnBoxCube(
                                      P_TaxIsDeferredRelevant : 'N',
                                      P_TaxIsMossRelevant     : 'N',
                                      P_StatryRptgEntity      : $parameters.P_StatryRptgEntity ,
                                      P_StatryRptCategory     : $parameters.P_StatryRptCategory,
                                      P_StatryRptRunID        : $parameters.P_StatryRptRunID,
                                      P_ReportingCountry      : $parameters.P_ReportingCountry,
                                      P_TaxBoxConfiguration   : '1'
                                                                                               )

    left outer to many join I_TaxGroup on  I_StRpTaxReturnBoxCube.Country       =  I_TaxGroup.Country
                                       and I_StRpTaxReturnBoxCube.TaxItemGroupingVersion =  I_TaxGroup.TaxItemGroupingVersion
                                       and I_StRpTaxReturnBoxCube.TaxItemGroupingVersion <> ' '
                                       and I_StRpTaxReturnBoxCube.TaxBox                 =  I_TaxGroup.TaxBalancesGrp

  association [0..1] to I_Currency as _ReportingCurrency on $projection.ReportingCurrency = _ReportingCurrency.Currency

{

  key    I_StRpTaxReturnBoxCube.CompanyCode,
  key    I_StRpTaxReturnBoxCube.AccountingDocument,
  key    I_StRpTaxReturnBoxCube.FiscalYear,
  key    I_StRpTaxReturnBoxCube.TaxItem,
  key    I_StRpTaxReturnBoxCube.TransactionTypeDetermination,
  key    I_StRpTaxReturnBoxCube.DebitCreditCode,
  key    I_StRpTaxReturnBoxCube.AccountingDocumentType,
  key    I_StRpTaxReturnBoxCube.SupplierAccountGroup,
  key    I_StRpTaxReturnBoxCube.TaxBox,
  key    I_StRpTaxReturnBoxCube.TaxDeclnAmountType,
  key    I_StRpTaxReturnBoxCube.TaxBoxStrucValidityStartDate,
  key    case
     when I_StRpTaxReturnBoxCube.UnifiedTaxBoxStructureType = ' '
        then 'EFM'
        else I_StRpTaxReturnBoxCube.UnifiedTaxBoxStructureType
     end                                                                                                     as UnifiedTaxBoxStructureType,
  key    I_StRpTaxReturnBoxCube.TaxGroup,
  key    I_StRpTaxReturnBoxCube.TaxItemGrpgDebitCreditCode,
  key    I_StRpTaxReturnBoxCube.TaxItemGrpgAcctgDocumentType,
  key    I_StRpTaxReturnBoxCube.TaxItemGrpgSupplierAcctGroup,
  key    I_StRpTaxReturnBoxCube.TaxItemGrpgSpecialGLCode,
  key    I_StRpTaxReturnBoxCube.StatryRptgEntity,
  key    I_StRpTaxReturnBoxCube.StatryRptCategory,
  key    I_StRpTaxReturnBoxCube.StatryRptRunID,

  key    cast(
       case
    when I_StRpTaxReturnBoxCube.UnifiedTaxBoxStructureType = ''
       then                             I_TaxGroup.TaxGroupExternalID
       else                             I_StRpTaxReturnBoxCube.TaxBox
    end as fi_exttaxbox preserving type)                                                                     as TaxGroupExternalID,

         I_StRpTaxReturnBoxCube.StatryRptRun,
         I_StRpTaxReturnBoxCube.TaxCode,
         I_StRpTaxReturnBoxCube.Country,
         I_StRpTaxReturnBoxCube.TaxBoxStrucValidityEndDate,
         I_StRpTaxReturnBoxCube.TaxBoxName,
         I_StRpTaxReturnBoxCube.TaxItemGroupingVersion,
         I_StRpTaxReturnBoxCube.TaxBoxStructureType,
         I_StRpTaxReturnBoxCube.TaxBoxStructure,
         I_StRpTaxReturnBoxCube.TaxBoxStructureName,
         I_StRpTaxReturnBoxCube.TaxBoxCondition,
         I_StRpTaxReturnBoxCube.TaxCountry,
         I_StRpTaxReturnBoxCube.TaxCalculationProcedure,
         @DefaultAggregation:#MIN
         I_StRpTaxReturnBoxCube.TaxRate,
         I_StRpTaxReturnBoxCube.TaxRateValidityStartDate,
         cast(right(cast( I_StRpTaxReturnBoxCube.TaxRate as char20 ), 10 ) as figen_taxrateinpercentastext ) as TaxRateInPercentAsText, // STW

         I_StRpTaxReturnBoxCube.GLAccount,
         I_StRpTaxReturnBoxCube.TaxItemGroup,
         I_StRpTaxReturnBoxCube.ReferenceDocumentType,
         I_StRpTaxReturnBoxCube.DocumentReferenceID, //XBLNR

         I_StRpTaxReturnBoxCube.PostingDate,
         I_StRpTaxReturnBoxCube.DocumentDate,
         I_StRpTaxReturnBoxCube.TaxReportingDate,
         I_StRpTaxReturnBoxCube.ReportingDate,
         I_StRpTaxReturnBoxCube.TaxType,
         I_StRpTaxReturnBoxCube.FiscalPeriod,
         // @DefaultAggregation:#MIN

         // ExchangeRate,

         I_StRpTaxReturnBoxCube.CompanyCodeCountry,
         I_StRpTaxReturnBoxCube.ReportingCountry,
         I_StRpTaxReturnBoxCube.TaxReturnCountry,
         I_StRpTaxReturnBoxCube.TaxTypeName,

         I_StRpTaxReturnBoxCube.BusinessPartner,
         I_StRpTaxReturnBoxCube.BusinessPartnerName,

         @Semantics.currencyCode:true
         I_StRpTaxReturnBoxCube.CompanyCodeCurrency,
         @Semantics.currencyCode:true
         I_StRpTaxReturnBoxCube.DocumentCurrency,
         @Semantics.currencyCode:true
         I_StRpTaxReturnBoxCube.ReportingCurrency,

         @DefaultAggregation:#SUM
         @Semantics.amount.currencyCode: 'ReportingCurrency'
         I_StRpTaxReturnBoxCube.AmountInReportingCurrency,
         @DefaultAggregation:#SUM
         @Semantics.amount.currencyCode: 'ReportingCurrency'
         I_StRpTaxReturnBoxCube.TaxBaseAmountInRptgCrcy,
         @DefaultAggregation:#SUM
         @Semantics.amount.currencyCode: 'ReportingCurrency'
         I_StRpTaxReturnBoxCube.TaxAmountInRptgCrcy,
         @DefaultAggregation:#SUM
         @Semantics.amount.currencyCode: 'ReportingCurrency'
         I_StRpTaxReturnBoxCube.NonDeductibleInputTaxAmount,
         @DefaultAggregation:#SUM
         @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
         I_StRpTaxReturnBoxCube.TaxBaseAmountInCoCodeCrcy,
         @DefaultAggregation:#SUM
         @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
         I_StRpTaxReturnBoxCube.TaxAmountInCoCodeCrcy,
         @DefaultAggregation:#SUM
         @Semantics.amount.currencyCode: 'DocumentCurrency'
         I_StRpTaxReturnBoxCube.TaxBaseAmountInTransCrcy,
         @DefaultAggregation:#SUM
         @Semantics.amount.currencyCode: 'DocumentCurrency'
         I_StRpTaxReturnBoxCube.TaxAmount,

         I_StRpTaxReturnBoxCube.TargetTaxCode,
         I_StRpTaxReturnBoxCube.CAReconciliationKey,
         I_StRpTaxReturnBoxCube.TaxIsNotDeductible,
         _ReportingCurrency,
         _TaxTypeText,
         _TaxCodeText

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_STRPTAXRETURNBOXCUBE",
"I_TAXGROUP"
],
"ASSOCIATED":
[
"I_CURRENCY",
"I_TAXCODETEXT",
"I_TAXTYPETEXT"
],
"BASE":
[
"I_STRPTAXRETURNBOXCUBE"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/