C_CAPaymentRunSearch

@AbapCatalog.sqlViewName: 'CCAPAYTSEARCHRUN'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Zahlungen im Zahllauf suchen'
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@Search.searchable: true
@UI: {
    headerInfo: {
        typeName: 'Zahlung',
        typeNamePlural: 'Zahlungen',
        title: {
            value:   'CAPaymentDocumentReference',
            label:   'Zahlung'
        },
        description:{
            value: 'CAPaymentDocumentType'
     }
    }
}
@UI.presentationVariant: [{
  requestAtLeast:  [
    'CAMassRunDate',
    'CAMassRunID',
    'CAMassRunDateAndID'
  ]
}]
@VDM.viewType: #CONSUMPTION
define view C_CAPaymentRunSearch
  as select from I_CAPaymentRunHeader

  association [1..*] to I_CAPaymentRunItem            as _PaymentRunItem              on  $projection.CAMassRunDate                  = _PaymentRunItem.CAMassRunDate
                                                                                      and $projection.CAMassRunID                    = _PaymentRunItem.CAMassRunID
                                                                                      and $projection.CAIntPaymentIdentification     = _PaymentRunItem.CAIntPaymentIdentification
                                                                                      and $projection.CAIntAddlPaymentIdentification = _PaymentRunItem.CAIntAddlPaymentIdentification

  association [0..1] to I_CAPaymentMethod             as _PaymentMethod               on  $projection.CAPaymentMethod = _PaymentMethod.CAPaymentMethod
                                                                                      and $projection.PayeeCountry    = _PaymentMethod.Country

  association [0..1] to I_CADocumentHeader            as _DocHeader                   on  $projection.CADocumentNumber = _DocHeader.CADocumentNumber

  association [0..1] to I_CAPaymentOrder              as _PaymentOrder                on  $projection.CAPaymentOrder = _PaymentOrder.CAPaymentOrder
  //22.12.22 replace with CADocumentGLItemPaymentData

  //association [0..1] to I_CADocumentPaytSrvcPrvdrData as _CADocumentPaytSrvcPrvdrData on  $projection.CADocumentNumber = _CADocumentPaytSrvcPrvdrData.CADocumentNumber

  
  association [0..1] to I_CADocumentGLItemPaymentData as _CADocumentGLItemPaymentData on  $projection.CADocumentNumber = _CADocumentGLItemPaymentData.CADocumentNumber

  association [0..1] to I_Bank                        as _Bank                        on  $projection.PayeeBankCountry = _Bank.BankCountry
                                                                                      and $projection.PayeeBank        = _Bank.BankInternalID

  association [1..1] to C_CAPaytRunSrchPaymentOrder   as _AssocPaymentOrder           on  $projection.CAMassRunDate                  = _AssocPaymentOrder.CAMassRunDate
                                                                                      and $projection.CAMassRunID                    = _AssocPaymentOrder.CAMassRunID
                                                                                      and $projection.CAIntPaymentIdentification     = _AssocPaymentOrder.CAIntPaymentIdentification
                                                                                      and $projection.CAIntAddlPaymentIdentification = _AssocPaymentOrder.CAIntAddlPaymentIdentification

  association [1..1] to C_CAPaymentRunSearchPayment   as _AssocPayment                on  $projection.CAMassRunDate                  = _AssocPayment.CAMassRunDate
                                                                                      and $projection.CAMassRunID                    = _AssocPayment.CAMassRunID
                                                                                      and $projection.CAIntPaymentIdentification     = _AssocPayment.CAIntPaymentIdentification
                                                                                      and $projection.CAIntAddlPaymentIdentification = _AssocPayment.CAIntAddlPaymentIdentification

  association [1..1] to C_CAPaytRunSrchRepaymentReq   as _AssocRepaymentRequest       on  $projection.CAMassRunDate                  = _AssocRepaymentRequest.CAMassRunDate
                                                                                      and $projection.CAMassRunID                    = _AssocRepaymentRequest.CAMassRunID
                                                                                      and $projection.CAIntPaymentIdentification     = _AssocRepaymentRequest.CAIntPaymentIdentification
                                                                                      and $projection.CAIntAddlPaymentIdentification = _AssocRepaymentRequest.CAIntAddlPaymentIdentification

  association [0..1] to I_Housebank                   as _HouseBank                   on  $projection.CompanyCode = _HouseBank.CompanyCode
                                                                                      and $projection.HouseBank   = _HouseBank.HouseBank

  association [0..1] to I_HouseBankAccount            as _HouseBankAccount            on  $projection.CompanyCode      = _HouseBankAccount.CompanyCode
                                                                                      and $projection.HouseBank        = _HouseBankAccount.HouseBank
                                                                                      and $projection.HouseBankAccount = _HouseBankAccount.HouseBankAccount

  association [0..1] to I_CAReturnHistory             as _ReturnHistory               on  $projection.BusinessPartner  = _ReturnHistory.BusinessPartner
                                                                                      and $projection.ContractAccount  = _ReturnHistory.ContractAccount
                                                                                      and $projection.CADocumentNumber = _ReturnHistory.CADocumentNumber

  association [0..1] to I_PaymentCardTypes            as _PaymentCardType             on  $projection.PaymentCardType = _PaymentCardType.PaymentCardType
  
  association [1..1] to I_CASubApplication            as _CASubApplication            on  $projection.casubapplication = _CASubApplication.CASubApplication


{
      // This view is NOT used as RDS bis is mapped instead

      // -> Change of annotations will have no effect for the List Report page

      // -> annotations are defined locally in the annotations.xml file of the frontend project

      // However, this view is reused by other RDS views and annotations are inherited

  @Consumption.valueHelpDefinition: [{ entity: { name: 'I_CAPaymentRunValueHelp', element: 'CAMassRunDate'}, additionalBinding: [{ localElement: 'CAMassRunID' , element: 'CAMassRunID' }]}]
  key CAMassRunDate,
  key CAMassRunID,
  key CAIntPaymentIdentification,
  key CAIntAddlPaymentIdentification,

      CAPaymentCompanyCode                                                                                                                                                  as CompanyCode,
      _PaymentCompCode.CompanyCodeName                                                                                                                                      as CompanyCodeName,
      concat_with_space(  concat_with_space( cast(CAMassRunDate as date) , '/', 1), CAMassRunID, 1)                                                                         as CAMassRunDateAndID,

      BusinessPartner,
      _BusinessPartner.BusinessPartnerFullName,

      //Get Business Partner Names from _BusinessPartner for Search Field

      _BusinessPartner.FirstName,
      _BusinessPartner.LastName,
      _BusinessPartner.OrganizationBPName1,
      _BusinessPartner.OrganizationBPName2,
      _BusinessPartner.GroupBusinessPartnerName1,
      _BusinessPartner.GroupBusinessPartnerName2,

      ContractAccount,
      _CAHeader.ContractAccountName,
      
      //SUBAP

      _CASubApplication.CASubApplication,

      CAPaymentDocumentReference,
      CAPaymentDocumentType,
      cast('' as char70)                                                                                                                                                    as CAPaymentDocumentTypeName,

      CADocumentNumber,
      CAPaymentOrder,
      CARepaymentRequest,
      CASEPAPreNotificationNumber,

      _BankCountry._Text[1: Language=$session.system_language].CountryName                                                                                                  as BankCountryName,
      BankCountry,
      cast(BankNumber as bankl preserving type )                                                                                                                            as BankNumber,
      cast(BankAccount as farp_bankn preserving type )                                                                                                                      as BankAccount,

      _PayeeBankCountry._Text[1: Language=$session.system_language].CountryName                                                                                             as PayeeBankCountryName,
      cast(PayeeBankCountry as banks preserving type )                                                                                                                      as PayeeBankCountry,
      PayeeBank,
      _Bank.BankName                                                                                                                                                        as PayeeBankName,
      PayeeBankNumber,
      cast(PayeeBankAccount as farp_bankn preserving type )                                                                                                                 as PayeeBankAccount,
      PayeeIBAN,
      CABankAccountHolderName,
      _PayeeCountry._Text[1: Language=$session.system_language].CountryName                                                                                                 as PayeeCountryName,
      PayeeCountry,

      CityName,
      AddressPostalCode,
      concat_with_space( AddressPostalCode, CityName, 1)                                                                                                                    as AddressLine2,
      AddressStreetName,
      AddressHouseNumber,
      concat_with_space( AddressStreetName, AddressHouseNumber, 1)                                                                                                          as AddressLine1,
      SWIFTCode,
      TransactionCurrency,

      //Currency Text for Search Field

      _Currency._Text[1: Language=$session.system_language].CurrencyName,

      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      PaytAmountInCoCodeCurrency,
      cast(_PaymentCompCode.Currency as fis_hwaer preserving type) as CompanyCodeCurrency,      
      
      ValueDate,

      _PaymentMethod._Text[1:Language = $session.system_language].CAPaymentMethodName,
      CAPaymentMethod,

      _HouseBank._Bank.BankName,
      HouseBank,
      _HouseBank._Bank.BankName                                                                                                                                             as HouseBankName,
      HouseBankAccount,
      _HouseBankAccount._Text[1: Language=$session.system_language].HouseBankAccountDescription                                                                             as HouseBankAccountDescription,


      _CADocumentGLItemPaymentData.PaymentCardHolderName as CardHolder,

      _CADocumentGLItemPaymentData.PaymentCardValidityEndDate as ValidityEndDate,


      cast(concat_with_space(CardNumber, concat_with_space('(', concat_with_space(_PaymentCardType._Text[1: Language=$session.system_language].CardTypeText, ')', 1), 1), 1) as ccnum_ccins_kk)    as PaymentCardData,
      PaymentCardType,
      _PaymentCardType._Text[1: Language=$session.system_language].CardTypeText,

      case
      when _CADocumentGLItemPaymentData.PaymentCardMaskedNumber is null or _CADocumentGLItemPaymentData.PaymentCardMaskedNumber = ''
      then CardNumber
      else cast(_CADocumentGLItemPaymentData.PaymentCardMaskedNumber as bu_ccnum preserving type )
      end                                                                                                                                                                   as CardNumber,

      PaymentAdvicePrintingReason,


      //I_CAPaymentRunItem


      //Master Data for Paid Item

      //      @UI.fieldGroup: { qualifier: 'RegulierterPostenDaten', groupLabel: 'Stammdaten zum regulierten Posten', position: 10 }

      //      @EndUserText.label: 'Geschäftspartner zum regulierten Posten'

      //      @Consumption.valueHelpDefinition: [{entity: { name: 'C_CAContractPartnerValueHelp', element: 'BusinessPartner'}}]

      //              _PaymentRunItem.BusinessPartner as PaidItemBusinessPartner,

      ''                                                                                                                                                                    as PaidItemBusinessPartner,

      //      @UI.fieldGroup: { qualifier: 'RegulierterPostenDaten', groupLabel: 'Stammdaten zum regulierten Posten', position: 20 }

      //      @EndUserText.label: 'Vertragskonto zum regulierten Posten'

      //      @Consumption.valueHelpDefinition: [{entity: { name: 'C_ContractAccountValueHelp', element: 'PaytItemContractAccount'}}]

      //              _PaymentRunItem.ContractAccount as PaidItemContractAccount,

      ''                                                                                                                                                                    as PaidItemContractAccount,

      //      @UI.fieldGroup: { qualifier: 'RegulierterPostenDaten', groupLabel: 'Stammdaten zum regulierten Posten', position: 30 }

      //      @EndUserText.label: 'Vertrag zum regulierten Posten'

      //        _PaymentRunItem.CAContract,

      ''                                                                                                                                                                    as CAContract,
      
      cast('' as vtref_semobj_kk) as CAContractSemanticObject,

      //I_CADocumentHeader


      cast (_DocHeader.DocumentDate as co_bldat preserving type)                                                                                                            as DocumentDate,
      _DocHeader.CAPostingDate,
      _DocHeader._DocType._Text[1:Language = $session.system_language].CADocumentTypeName,
      _DocHeader.CADocumentType,
      _ReturnHistory.CAReturnReason,
      _ReturnHistory._CAReturnReason._Text[1:Language = $session.system_language].CAReturnReasonName,
      _DocHeader.CAReversalDocumentNumber,


      //I_CAPaymentOrder


      _PaymentOrder.PaidItemDueDate,

      //      @UI.fieldGroup:{qualifier: 'Zahlungsauftrag', position: 50, importance: #HIGH, label: 'Verfallsdatum'}

      //      @EndUserText.label: 'Verfallsdatum'

      _PaymentOrder.CAPaymentOrderExpirationDate,

      //        @UI.fieldGroup:{qualifier: 'Zahlungsauftrag', position: 20, importance: #HIGH, label: 'Status'}

      //      @EndUserText.label: 'Status'

      //      @ObjectModel: { text.element:  [ 'CAPaymentOrderStatusName' ] }

      _PaymentOrder.CAPaymentOrderStatus,

      //      @UI.hidden: true

      _PaymentOrder._CAPaymentOrderStatus._Text[1: Language=$session.system_language].CAPaymentOrderStatusName,

      //      @UI.fieldGroup:{qualifier: 'Zahlungsauftrag', position: 15, importance: #HIGH, label: 'Zahlbeleg'}

      //      @Consumption.semanticObject: 'CADocument'

      //      @EndUserText.label: 'Zahlbeleg'

      _PaymentOrder.CAPaymentDocument,

      //      @EndUserText.label: 'Storniert'

      //      @UI.lineItem: [{label: 'Storniert', position: 8, importance: #HIGH }]

      //        @UI.fieldGroup:{qualifier: 'Zahllaufdaten', position: 40 ,importance: #HIGH, label: 'Storniert'}

      //      @Consumption.filter.hidden: true

      case
      when ( _DocHeader.CAReversalDocumentNumber != '' and CADocumentNumber != '' ) or _PaymentOrder.CAPaymentOrderStatus = '2' or _PaymentOrder.CAPaymentOrderStatus = '4'
      then 'X'
      else ''
      end                                                                                                                                                                   as CADocumentIsReversed,

      //      @UI.hidden: true

      //      @Semantics.text: true

      cast('' as char20)                                                                                                                                                    as CADocumentReversalStatusName,


      //for on premise only

      CAPaymentSpecification,
      CAPaymentSpecificationRef,

      CAPromiseToPay,
      CAPromisedPaymentDate,


      /* Associations */
      //I_CAPaymentRunHeader

      _BankCountry,
      //        _BusinessArea,

      _BusinessPartner,
      _CAPartner,
      //        _CAPartner,

      //        _CompCodeOfPaidItem,

      _Currency,
      _DocHeader,
      _ReturnHistory,
      //        _HouseBank,

      //        _PayeeAddress,

      _PayeeBankCountry,
      _PayeeCountry,
      _PaymentRunItem,
      _AssocPaymentOrder,
      _AssocPayment,
      _AssocRepaymentRequest,
      //        _PayeeLanguage,

      _PaymentCompCode
      //        _Region


}

where
      CAPaymentDocumentReference != 'SIMU'
  and PaymentAdvicePrintingReason != 'A'
  and CASEPAPreNotificationNumber = ''
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BANK",
"I_BUSINESSPARTNER",
"I_CADOCUMENTGLITEMPAYMENTDATA",
"I_CADOCUMENTHEADER",
"I_CADOCUMENTTYPE",
"I_CADOCUMENTTYPETEXT",
"I_CAPAYMENTMETHOD",
"I_CAPAYMENTMETHODTEXT",
"I_CAPAYMENTORDER",
"I_CAPAYMENTORDERSTATUS",
"I_CAPAYMENTORDERSTATUSTEXT",
"I_CAPAYMENTRUNHEADER",
"I_CARETURNHISTORY",
"I_CARETURNREASON",
"I_CARETURNREASONTEXT",
"I_CASUBAPPLICATION",
"I_COMPANYCODE",
"I_CONTRACTACCOUNTHEADER",
"I_COUNTRY",
"I_COUNTRYTEXT",
"I_CURRENCY",
"I_CURRENCYTEXT",
"I_HOUSEBANK",
"I_HOUSEBANKACCOUNT",
"I_HOUSEBANKACCOUNTTEXT",
"I_PAYMENTCARDTYPES",
"I_PAYMENTCARDTYPETEXT"
],
"ASSOCIATED":
[
"C_CAPAYMENTRUNSEARCHPAYMENT",
"C_CAPAYTRUNSRCHPAYMENTORDER",
"C_CAPAYTRUNSRCHREPAYMENTREQ",
"I_BANK",
"I_BUSINESSPARTNER",
"I_CADOCUMENTGLITEMPAYMENTDATA",
"I_CADOCUMENTHEADER",
"I_CAPAYMENTMETHOD",
"I_CAPAYMENTORDER",
"I_CAPAYMENTRUNITEM",
"I_CARETURNHISTORY",
"I_CASUBAPPLICATION",
"I_COMPANYCODE",
"I_CONTRACTACCOUNTPARTNER",
"I_COUNTRY",
"I_CURRENCY",
"I_HOUSEBANK",
"I_HOUSEBANKACCOUNT",
"I_PAYMENTCARDTYPES"
],
"BASE":
[
"I_CAPAYMENTRUNHEADER"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/