@AbapCatalog.sqlViewName: 'CCAMYWLITM'
@AbapCatalog.preserveKey: true
@VDM.viewType: #CONSUMPTION
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Worklist Items'
@UI.selectionVariant: [
{qualifier: 'openItem', text : 'Open', filter: 'CAClrfctnStatus NE "03"'},
{qualifier: 'closedItem', text : 'Closed', filter: 'CAClrfctnStatus EQ "03"'}
]
@UI: {
headerInfo: {
typeName: 'Worklist Item',
typeNamePlural: 'Worklist Items',
title: { value: 'CAWorklistTitle' },
description: { value: 'CAWorklistNumber' }
}
}
@UI.presentationVariant: [{
requestAtLeast: ['TransactionCurrency']
}]
define view C_CAMyOpenWorklistItem
as select from I_CAWorklistItem as _WLItem
association [0..1] to I_BusinessPartner as _BusinessPartner on _WLItem.BusinessPartner = _BusinessPartner.BusinessPartner
association [1] to P_CAWorklistItemTotals as _ItemTotalAmount on $projection.CAWorklistUUID = _ItemTotalAmount.CAWorklistUUID
and $projection.BusinessPartner = _ItemTotalAmount.BusinessPartner
association [0..*] to P_CAWorklistItemCrdtDbtTotals as _WorklistItemTotalAmount on $projection.BusinessPartner = _WorklistItemTotalAmount.BusinessPartner
association [0..1] to C_CAInvcgUserContact as _LastProcessorContact on $projection.CAClrfctnLastProcessedByUser = _LastProcessorContact.ContactCardID
{
//I_CAWorklistItem
@UI.hidden: true
@Semantics.uuid
key CAWorklistItemUUID,
@UI.hidden: true
@Semantics.uuid
CAWorklistUUID,
CAWorklistNumber,
@ObjectModel: {
text.element: [ 'BusinessPartnerFullName' ]
}
@Semantics: { contact.type: #PERSON }
@Consumption.semanticObject: 'CAContractPartner'
@UI : {
lineItem: [{position: 10, importance: #HIGH }, { qualifier: 'opn', position: 1, importance: #HIGH }
]
}
_WLItem.BusinessPartner,
@UI.hidden: true
@ObjectModel.readOnly: true
_BusinessPartner.BusinessPartnerFullName,
//_____________________________
//--- Amount in Display Currency
@Semantics.currencyCode: true
@UI.hidden: true
cast('' as waers_kk) as DisplayCurrency,
@Semantics.amount.currencyCode: 'DisplayCurrency'
@UI : {
lineItem: [{position: 20, importance: #HIGH }]
}
cast(_ItemTotalAmount.CAWorklistOpenAmountInTC as wl_open_amount_cds_kk preserving type ) as CAWorklistOpenAmountInDC,
@Semantics.amount.currencyCode: 'DisplayCurrency'
@UI : {
lineItem: [{position: 40, importance: #HIGH }]
}
cast(_ItemTotalAmount.CAWorklistClosedAmountInTC as wl_closed_amount_cds_kk preserving type ) as CAWorklistClosedAmountInDC,
@Semantics.amount.currencyCode: 'DisplayCurrency'
@UI : {
lineItem: [{position: 30, importance: #HIGH }]
}
cast(_ItemTotalAmount.CAWorklistInProcessAmountInTC as wl_in_process_amount_cds_kk preserving type ) as CAWorklistInProcessAmountInDC,
@Semantics.amount.currencyCode: 'DisplayCurrency'
@UI: {
lineItem: [{position: 50, importance: #MEDIUM}]
}
cast(cast(0 as abap.curr(23,2)) as my_wklst_bal_kk preserving type ) as CAWorklistItmBalanceAmountInDC,
// _WorklistItemTotalAmount( P_DisplayCurrency:'EUR' ).CAWorklistBPCredits+_WorklistItemTotalAmount( P_DisplayCurrency:'EUR').CAWorklistBPDebits as CAWorklistItmBalanceAmountInDC,
@Semantics.amount.currencyCode: 'DisplayCurrency'
@UI: {
lineItem: [{position: 60, importance: #MEDIUM}]
}
cast(cast(0 as abap.curr(23,2) ) as my_wklst_credit_kk preserving type ) as CAWorklistItemCreditAmountInDC,
@UI.hidden: true
@Semantics.amount.currencyCode: 'DisplayCurrency'
cast(0 as betrw_aggr_kk) as CAWorklistItemDebitAmountInDC,
@UI.hidden: true
TransactionCurrency,
// @ObjectModel: {
// text.element: [ 'CAWorklistLastProcessorName' ]
// }
@UI : {
lineItem: [{position: 70, importance: #HIGH, label: 'Last Processor' }]
}
CAClrfctnLastProcessedByUser,
@ObjectModel: {
text.element: [ 'CAClrfctnStatusName' ]
}
@UI.hidden: true
CAClrfctnStatus,
@UI : {
lineItem: [{position: 80, label: 'Status', importance: #HIGH}]
}
@EndUserText.label: 'Status'
@EndUserText.quickInfo: 'Status'
_WorklistItemStatus._Text[1:Language = $session.system_language].CAClrfctnStatusName,
@UI : {
lineItem: [{position: 90, label: 'Processing Status', importance: #HIGH}],
textArrangement: #TEXT_ONLY
}
@ObjectModel.text.element: ['CAClrfctnProcgStatusName']
CAClrfctnProcgStatus,
@UI.hidden: true
@Semantics.text
_ProcgStatus._Text[1:Language = $session.system_language].CAClrfctnProcgStatusName,
@UI.hidden: true
CAWorklistPriority,
@UI.hidden: true
CAWorklistDueDate,
@UI.hidden: true
CAClarificationActionCode,
@UI.hidden: true
CAWorklistItemReference1,
@UI.hidden: true
CAWorklistItemReference2,
@UI.hidden: true
CAWorklistItemReference3,
@UI.hidden: true
CAClrfctnLockedToDate,
@UI.hidden: true
CAClrfctnResubmsnDate,
@UI.hidden: true
CAClrfctnNmbrOfWorkflows,
@UI.hidden: true
CreatedByUser,
@UI.hidden: true
CreationDate,
@UI.hidden: true
CreationTime,
@UI.hidden: true
CAInternalAppCode,
/* Associations */
//I_CAWorklistItem
_BusinessPartner,
_Currency,
_Header,
_ProcgStatus
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BUSINESSPARTNER",
"I_CACLRFCTNPROCGSTATUS",
"I_CACLRFCTNPROCGSTATUSTEXT",
"I_CACLRFCTNSTATUS",
"I_CACLRFCTNSTATUSTEXT",
"I_CAWORKLISTITEM",
"P_CAWORKLISTITEMTOTALS"
],
"ASSOCIATED":
[
"C_CAINVCGUSERCONTACT",
"I_BUSINESSPARTNER",
"I_CACLRFCTNPROCGSTATUS",
"I_CAWORKLISTHEADER",
"I_CURRENCY",
"P_CAWORKLISTITEMCRDTDBTTOTALS",
"P_CAWORKLISTITEMTOTALS"
],
"BASE":
[
"I_CAWORKLISTITEM"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/