C_CALockedOpenItem

@AbapCatalog.sqlViewName: 'CCALOCKEDOPENITM'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Gesperrte offene Posten'
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@VDM.viewType: #CONSUMPTION
define view C_CALockedOpenItem
  with parameters
    P_DisplayCurrency : waers_kk,
    @Environment.systemField : #SYSTEM_DATE
    P_ExchangeRateDate : syst_datum,
    P_CAInternalAppCode : tileid_kk
  as select from I_CADocumentBPItemLogical as BPItem
    association[0..1] to I_CALastWorklistItem as _LastWorkItem on $projection.BusinessPartner = _LastWorkItem.BusinessPartner
    association [0..1] to I_CAProviderContractItem as _ContractItem    on  $projection.CAContract = _ContractItem.CAProviderContract
                                                                      and  $projection.CAProviderContractItemNumber = _ContractItem.CAProviderContractItemNumber
{
  key BPItem.CADocumentNumber,
  key BPItem.CARepetitionItemNumber,
  key BPItem.CABPItemNumber,
  key BPItem.CASubItemNumber,

      BPItem.CompanyCode,
      BPItem.BusinessPartner,
      BPItem.ContractAccount,
      BPItem.CAContract,
      BPItem.CAProviderContractItemNumber,
      _ContractItem.CAProviderContractItemUUID,
      _CAHeader.ContractAccountCategory,

      BPItem._BusinessPartner.LastName,
      BPItem._BusinessPartner.FirstName,
      BPItem._BusinessPartner.BusinessPartnerName,

      BPItem.CAAmountInTransactionCurrency,
      BPItem.TransactionCurrency,

      @Semantics.amount.currencyCode: 'DisplayCurrency'
      currency_conversion( amount => BPItem.CAAmountInTransactionCurrency,
                                 source_currency => BPItem.TransactionCurrency,
                                 round =>  'X',
                                 target_currency => :P_DisplayCurrency,
                                 exchange_rate_date => :P_ExchangeRateDate,
                                 error_handling => 'FAIL_ON_ERROR' )
                                 as AmountInDisplayCurrency,
      $parameters.P_DisplayCurrency as DisplayCurrency,

      BPItem.CAMainTransaction,
      BPItem.CASubTransaction,
      BPItem.Division,
      BPItem.BusinessArea,
      BPItem.Segment,
      BPItem._CAPartner.CAAuthorizationGroup,
      BPItem._ProviderContract.CAAuthorizationGroup as CAProviderContractAuthznGroup,

      cast(cast(concat(BPItem.CADocumentNumber, concat(BPItem.CARepetitionItemNumber,
            concat (BPItem.CABPItemNumber, BPItem.CASubItemNumber))) as abap.char(32)) as loobj_kk) as CABusinessLockObject,

      // info about last worklist item

      _LastWorkItem( P_CAInternalAppCode : $parameters.P_CAInternalAppCode, P_Language : $session.system_language ).WorklistItemCreationDate,
      _LastWorkItem( P_CAInternalAppCode : $parameters.P_CAInternalAppCode, P_Language : $session.system_language ).CAClrfctnStatus,
      _LastWorkItem( P_CAInternalAppCode : $parameters.P_CAInternalAppCode, P_Language : $session.system_language ).CAClrfctnStatusName
}
where
  BPItem.CAClearingStatus = ''
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BUSINESSPARTNER",
"I_CADOCUMENTBPITEMLOGICAL",
"I_CALASTWORKLISTITEM",
"I_CAPROVIDERCONTRACTHEADER",
"I_CAPROVIDERCONTRACTITEM",
"I_CONTRACTACCOUNTHEADER",
"I_CONTRACTACCOUNTPARTNER"
],
"ASSOCIATED":
[
"I_CALASTWORKLISTITEM",
"I_CAPROVIDERCONTRACTITEM"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/