C_CAInvcgDocSource

@AbapCatalog.sqlViewName: 'CCAINVDOC_S'
@AbapCatalog.compiler.compareFilter: true
@VDM.viewType: #CONSUMPTION
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Fakturierungsbeleg Quellen'
@UI:{
  headerInfo: {
    typeName:       'Quellbeleg',
    typeNamePlural: 'Quellbelege'
  },
  presentationVariant: [{ 
    sortOrder: [ { by: 'CAInvcgCreationDate', direction: #DESC }],
    requestAtLeast: ['CAInvcgSourceDocumentSemObj'] 
  }]
}
define view C_CAInvcgDocSource
  as select from I_CAInvcgDocSource as _CAInvDocSource

  -- required for in-app navigation
  association [1..1] to C_CAInvcgDocDisp as _CAInvcgReversalDocument on $projection.CAInvcgReversalDocument = _CAInvcgReversalDocument.CAInvoicingDocument
  association [1..1] to C_CAInvcgDocDisp as _CAInvcgReversedDocument on $projection.CAInvcgReversedDocument = _CAInvcgReversedDocument.CAInvoicingDocument

{
      //INVDOCNO

      @UI.lineItem:       { position: 09, importance: #HIGH}
  key _CAInvDocSource.CAInvoicingDocument,

      //SRCDOCNO

      @UI.lineItem:       { position: 10, importance: #HIGH, semanticObjectAction: 'display'}
      @Consumption.semanticObject: 'CABillgDocument'
  key _CAInvDocSource.CAInvcgSourceDocumentNumber,

      //SRCDOCCAT

      @UI.lineItem:       { position: 20, importance: #HIGH}
      @ObjectModel.text.element: 'CAInvcgSourceDocCatText'
  key _CAInvDocSource.CAInvcgSourceDocumentCat,

      @UI.hidden: true
      _CAInvcgSourceDocCat.CAInvcgSourceDocumentSemObj,

      //SRCDOCTYPE

      @UI.lineItem:       { position: 30, importance: #HIGH}
      @ObjectModel.text.element: 'CAInvcgSourceDocTypeText'
      _CAInvDocSource.CAInvcgSourceDocumentType,

      //SIMULATED

      @UI.lineItem:       { position: 40, importance: #HIGH}
      _CAInvDocSource.CAInvcgIsDocumentSimulated,


      //PRELIMINARY

      @UI.lineItem:       { position: 50, importance: #HIGH}
      _CAInvDocSource.CAInvcgIsDocumentPreliminary,

      // Hidden fields


      //LOGSYSTEM

      _CAInvDocSource.LogicalSystem,

      //APPLK

      _CAInvDocSource.CAApplicationArea,

      //INVOICED

      _CAInvDocSource.CAInvcgIsDocumentPosted,

      //REVERSALDOC

      @UI.lineItem: [{ position: 60, importance: #LOW, type: #WITH_NAVIGATION_PATH, value: 'CAInvcgReversalDocument', targetElement: '_CAInvcgReversalDocument' }]        
      _CAInvDocSource.CAInvcgReversalDocument,

      //REVERSEDDOC

      @UI.lineItem: [{ position: 70, importance: #LOW, type: #WITH_NAVIGATION_PATH, value: 'CAInvcgReversedDocument', targetElement: '_CAInvcgReversedDocument' }]  
      _CAInvDocSource.CAInvcgReversedDocument,

      //CRDATE

      _CAInvDocSource.CAInvcgCreationDate,

      @UI.hidden: true
      _CAInvcgSourceDocCat._CAInvcgSourceDocCatText[1: Language=$session.system_language].CAInvcgSourceDocCatText,
      @UI.hidden: true
      _CAInvcgSourceDocType._CAInvcgSourceDocTypeText[1: Language=$session.system_language].CAInvcgSourceDocTypeText,


      // Make association public

      _CAInvcgDocHeader,
      _CAInvcgSourceDocCat,
      _CAInvcgSourceDocType,
      _CAInvcgReversalDocument,
      _CAInvcgReversedDocument
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CAINVCGDOCSOURCE",
"I_CAINVCGSOURCEDOCCAT",
"I_CAINVCGSOURCEDOCCATTEXT",
"I_CAINVCGSOURCEDOCTYPE",
"I_CAINVCGSOURCEDOCTYPETEXT"
],
"ASSOCIATED":
[
"C_CAINVCGDOCDISP",
"I_CAINVCGDOCHEADER",
"I_CAINVCGSOURCEDOCCAT",
"I_CAINVCGSOURCEDOCTYPE"
],
"BASE":
[
"I_CAINVCGDOCSOURCE"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/