C_CAInvcgDocReversalRequest

@AbapCatalog.sqlViewName: 'CCAINVDOCREV'
@AbapCatalog.preserveKey: true
@AbapCatalog.compiler.compareFilter: true
@VDM.viewType: #CONSUMPTION
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Stornoauftrag für Fakt.belege'
@ObjectModel:{
  usageType:{
    serviceQuality: #D,
    sizeCategory: #L,
    dataClass: #TRANSACTIONAL
  },
  semanticKey: ['CAInvoicingDocument']
}
@UI:{
  headerInfo:{
    typeName: 'Stornoauftrag für Fakturierungsbeleg',
    typeNamePlural: 'Stornoaufträge für Fakturierungsbelege'
  },
  presentationVariant.sortOrder: { by: 'CreationDateTime', direction: #DESC }
}
define view C_CAInvcgDocReversalRequest
  as select from I_CAInvcgDocReversalRequest as _CAInvcgDocReversalRequest
  association [0..1] to C_CAInvcgDocHeader as _CAInvcgDocHeader on $projection.CAInvoicingDocument = _CAInvcgDocHeader.CAInvoicingDocument
{
      //  INVDOCNO

      @UI.lineItem:       { position: 30, importance: #HIGH}
  key _CAInvcgDocReversalRequest.CAInvoicingDocument,

      // REVTASK

      @UI.lineItem:       { position: 20, importance: #HIGH}
  key _CAInvcgDocReversalRequest.CARvslTsk,

      // STATUS

      @UI.lineItem:       { position: 10, importance: #HIGH}
      @ObjectModel.text.element: 'CAReversalRequestStatusText'
      _CAInvcgDocReversalRequest.CAReversalRequestStatus,

      // revreason

      @UI.lineItem:       { position: 40, importance: #HIGH}
      @ObjectModel.text.element: 'CAInvcgDocReversalReasonText'
      _CAInvcgDocReversalRequest.CAInvcgDocumentReversalReason,

      // stodt

      @UI.lineItem:       { position: 50, importance: #HIGH}
      _CAInvcgDocReversalRequest.CAReversalRequestDate,

      // inv_type

      @UI.lineItem:       { position: 60, importance: #HIGH}
      @ObjectModel.text.element: 'CAInvcgTypeText'
      _CAInvcgDocReversalRequest.CAInvcgType,

      // inv_process

      @UI.lineItem:       { position: 70, importance: #HIGH}
      @ObjectModel.text.element: 'CAInvcgProcessText'
      _CAInvcgDocReversalRequest.CAInvcgProcess,

      // inv_category

      @UI.lineItem:       { position: 80, importance: #HIGH}
      @ObjectModel.text.element: 'CAInvcgCategoryText'
      _CAInvcgDocReversalRequest.CAInvcgCategory,

      // crname

      @UI.lineItem:       { position: 90, importance: #HIGH}
      _CAInvcgDocReversalRequest.CreatedByUser,

      // crdate

      @Consumption.hidden: true
      //@UI.lineItem:       { position: 100, importance: #HIGH}

      _CAInvcgDocReversalRequest.CreationDate,

      // crtime

      @Consumption.hidden: true
      _CAInvcgDocReversalRequest.CreationTime,

      //combined field of crdate and crtime

      @UI.lineItem:       { position: 100, importance: #HIGH}
      @Consumption.filter.selectionType: #INTERVAL
      @ObjectModel.filter.transformedBy: 'ABAP:CL_CINV_SADL_FILTER_DATETIME'
      cast(dats_tims_to_tstmp(_CAInvcgDocReversalRequest.CreationDate, _CAInvcgDocReversalRequest.CreationTime,
      abap_system_timezone($session.client, 'NULL'),
      $session.client, 'NULL') as crtimestamp_kk) as CreationDateTime,


      // Hidden fields

      // gpart

      @Consumption.semanticObject: 'CAContractPartner'
      _CAInvcgDocReversalRequest.BusinessPartner,

      // gpart_sel

      _CAInvcgDocReversalRequest.CABusinessPartnerDocRlvt,

      // vkont

      @Consumption.semanticObject: 'ContractAccount'
      _CAInvcgDocReversalRequest.ContractAccount,

      // vkont_sel

      _CAInvcgDocReversalRequest.CAContractAccountDocRlvt,

      // mdcat

      @ObjectModel.text.element: 'CAInvcgMasterDataTypeText'
      _CAInvcgDocReversalRequest.CAInvcgMasterDataType,

      // invdoc_crdate

      @Consumption.hidden: true
      _CAInvcgDocReversalRequest.CAInvcgCreationDate,

      // invdoc_crtime

      @Consumption.hidden: true
      _CAInvcgDocReversalRequest.CAInvcgCreationTime,
      
      //combined field of invdoc_crdate and invdoc_crtime

      @Consumption.filter.selectionType: #INTERVAL
      @ObjectModel.filter.transformedBy: 'ABAP:CL_CINV_SADL_FILTER_DATETIME'
      cast(dats_tims_to_tstmp(_CAInvcgDocReversalRequest.CAInvcgCreationDate, _CAInvcgDocReversalRequest.CAInvcgCreationTime,
      abap_system_timezone($session.client, 'NULL'),
      $session.client, 'NULL') as invdoc_crtsmp_kk) as CAInvcgCreationDateTime,
     
      // invpercat

      @ObjectModel.text.element: 'CAInvcgPeriodCatText'
      _CAInvcgDocReversalRequest.CAInvcgDocPeriodCategory,

      // invperiod

      _CAInvcgDocReversalRequest.CAInvcgDocPeriodDate,

      // faedn

      _CAInvcgDocReversalRequest.CANetDueDate,

      // total_curr

      _CAInvcgDocReversalRequest.TransactionCurrency,

      // total_amt

      _CAInvcgDocReversalRequest.CAAmountInTransactionCurrency,

      // loedt

      _CAInvcgDocReversalRequest.CADeletionDate,

      @UI.hidden: true
      _CAInvcgDocReversalReason._CAInvcgDocReversalReasonText[1: Language=$session.system_language].CAInvcgDocReversalReasonText,
      @UI.hidden: true
      _CAReversalRequestStatus._CAReversalRequestStatusText[1: Language=$session.system_language].CAReversalRequestStatusText,
      @UI.hidden: true
      _CAInvcgType._CAInvcgTypeText[1: Language=$session.system_language].CAInvcgTypeText,
      @UI.hidden: true
      _CAInvcgProcess._CAInvcgProcessText[1: Language=$session.system_language].CAInvcgProcessText,
      @UI.hidden: true
      _CAInvcgCategory._CAInvcgCategoryText[1: Language=$session.system_language].CAInvcgCategoryText,
      @UI.hidden: true
      _CAInvcgMasterDataType._CAInvcgMasterDataTypeText[1: Language=$session.system_language].CAInvcgMasterDataTypeText,
      @UI.hidden: true
      _CAInvcgPeriodCat._CAInvcgPeriodCatText[1: Language=$session.system_language].CAInvcgPeriodCatText,

      _CAInvcgDocHeader
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CAINVCGCATEGORY",
"I_CAINVCGCATEGORYTEXT",
"I_CAINVCGDOCREVERSALREASON",
"I_CAINVCGDOCREVERSALREASONTEXT",
"I_CAINVCGDOCREVERSALREQUEST",
"I_CAINVCGMASTERDATATYPE",
"I_CAINVCGMASTERDATATYPETEXT",
"I_CAINVCGPERIODCAT",
"I_CAINVCGPERIODCATTEXT",
"I_CAINVCGPROCESS",
"I_CAINVCGPROCESSTEXT",
"I_CAINVCGTYPE",
"I_CAINVCGTYPETEXT",
"I_CAREVERSALREQUESTSTATUS",
"I_CAREVERSALREQUESTSTATUSTEXT"
],
"ASSOCIATED":
[
"C_CAINVCGDOCHEADER"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/