@AbapCatalog.sqlViewName: 'CCAINVDOC_I'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@VDM.viewType: #CONSUMPTION
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel: {
usageType:{
serviceQuality: #D,
sizeCategory: #XL,
dataClass: #TRANSACTIONAL
},
semanticKey: ['CAInvcgDocItem'],
representativeKey: 'CAInvcgDocItem'
}
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Fakturierungsbelegposition'
@UI:{
headerInfo: {
typeName: 'Fakturierungsbelegposition',
typeNamePlural: 'Fakturierungsbelegpositionen'
},
presentationVariant: [{
sortOrder: [{ by: 'CAInvcgDocItem', direction: #ASC }],
requestAtLeast: ['CAInvcgSourceDocumentSemObj', 'CAContractSemanticObject']
}]
}
define view C_CAInvcgDocItem
as select from P_CAInvcgDocItem as _CAInvcgDocItem
association [0..1] to C_CAInvcgDocHeader as _CAInvcgDocHeader on $projection.CAInvoicingDocument = _CAInvcgDocHeader.CAInvoicingDocument
// extension
association [0..1] to E_CAInvcgDocItem as _Extension on $projection.CAInvoicingDocument = _Extension.CAInvoicingDocument
and $projection.CAInvcgDocItem = _Extension.CAInvcgDocItem
{
//INVDOCNO
@UI.hidden: true
key _CAInvcgDocItem.CAInvoicingDocument,
//INVDOCITEM
@UI.lineItem: { position: 10, importance: #HIGH }
key _CAInvcgDocItem.CAInvcgDocItem,
//ITEM_SIMULATED
_CAInvcgDocItem.CAIsDocItemSimulated,
//ITEMTYPTE
@UI.lineItem: { position: 30, importance: #HIGH }
@ObjectModel.text.element: 'CAInvcgDocItemTypeText'
_CAInvcgDocItem.CAInvcgDocumentItemType,
//VTREF
@UI.lineItem: { position: 40, importance: #HIGH }
_CAInvcgDocItem.CAContract,
@UI.hidden: true
@ObjectModel: {
readOnly: true,
virtualElement: true,
virtualElementCalculatedBy: 'ABAP:CL_CINV_VTREF_SEMOBJ'
}
cast ( '' as vtref_semobj_kk ) as CAContractSemanticObject,
//BUKRS
@UI.lineItem: { position: 50, importance: #HIGH }
@ObjectModel.text.element: 'CompanyCodeName'
_CAInvcgDocItem.CompanyCode,
//HVORG
@UI.lineItem: { position: 60, importance: #HIGH }
@ObjectModel.text.element: 'CAMainTransactionName'
_CAInvcgDocItem.CAMainTransaction,
//TVORG
@UI.lineItem: { position: 70, importance: #HIGH }
@ObjectModel.text.element: 'CASubTransactionName'
_CAInvcgDocItem.CASubTransaction,
//POSTREL
@UI.lineItem: { position: 80, importance: #HIGH }
_CAInvcgDocItem.CAInvcgIsItemPostingRelevant,
//PRINTREL
@UI.lineItem: { position: 90, importance: #HIGH }
_CAInvcgDocItem.CAInvcgIsItemPrintingRelevant,
//TOTALREL
@UI.lineItem: { position: 100, importance: #HIGH }
_CAInvcgDocItem.CAInvcgIsInFinalAmt,
//Amount and Currency
_CAInvcgDocItem.TransactionCurrency,
@UI.lineItem: { position: 110, importance: #HIGH }
_CAInvcgDocItem.CAAmountInTransactionCurrency,
//TAX_INCLUDED
_CAInvcgDocItem.CATaxIsIncluded,
//TAXGR
_CAInvcgDocItem.CAInvcgTaxGroupingKey,
//MWSKZ
@ObjectModel.text.element: 'TaxCodeName'
_CAInvcgDocItem.TaxCode,
//TAX_PERC
_CAInvcgDocItem.CATaxRateInPercent,
//TAX_COUNTRY
@ObjectModel.text.element: 'TaxCountryName'
TaxCountry,
//OFFSET_ACTION
@ObjectModel.text.element: 'CAInvcgOffsettingActionText'
CAInvcgOffsettingAction,
//OFFSET_CAT
@ObjectModel.text.element: ['CAInvcgOffsettingCategoryTxt']
CAInvcgOffsettingCategory,
//OFFSET_PROC
@ObjectModel.text.element: ['CAInvcgOffsettingProcedText']
CAInvcgOffsettingProcedure,
//MENGE
_CAInvcgDocItem.Quantity,
//FAEDN
_CAInvcgDocItem.CANetDueDate,
//SPART
@ObjectModel.text.element: 'DivisionName'
_CAInvcgDocItem.Division,
//VTPOS
_CAInvcgDocItem.CAProviderContractItemNumber,
//SUBAP
@ObjectModel.text.element: 'CASubApplicationText'
_CAInvcgDocItem.CASubApplication,
//GPART_A
@Consumption.semanticObject: 'CAContractPartner'
@ObjectModel.text.association: '_CAInvcgItmAltvBusinessPartner'
_CAInvcgDocItem.CAInvcgItmAltvBusinessPartner,
//VKONT_A
@Consumption.semanticObject: 'ContractAccount'
@ObjectModel.text.association: '_CAInvcgItmAltvContractAccount'
_CAInvcgDocItem.CAInvcgItmAltvContractAccount,
//GPVKT_A_CAT
@ObjectModel.text.element: 'CAInvcgDocItmAltvMDCatText'
_CAInvcgDocItem.CAInvcgDocItmAltvMDCat,
//REVERSALITEM
_CAInvcgDocItem.CAInvcgDocItemIsReversal,
//NOT_BPREL
_CAInvcgDocItem.CAInvcgIsNotBPRelevant,
//PRINT_SUBSTITUTE
_CAInvcgDocItem.CAInvcgSubstituteGroupPrinting,
//SRCOC_CURR
_CAInvcgDocItem.CACurrencySourceDocument,
//SRCOC_AMT
_CAInvcgDocItem.CAInvcgSourceDocumentAmount,
//CURR_GROUP
_CAInvcgDocItem.CAGroupingCurrencyTranslation,
//KOFIZ
_CAInvcgDocItem.CAAccountDeterminationCode,
//BUPLA
_CAInvcgDocItem.BusinessPlace,
//GSBER
@ObjectModel.text.element: 'BusinessAreaName'
_CAInvcgDocItem.BusinessArea,
//TAX_DET_TYPE
@ObjectModel.text.element: 'CATaxDetnTypeText'
_CAInvcgDocItem.CATaxDetnType,
// STRKZ
@ObjectModel.text.element: 'CAOtherTaxCodeName'
@ObjectModel.foreignKey.association: '_CAOtherTaxCode'
_CAInvcgDocItem.CAOtherTaxCode,
//ERMWSKZ
_CAInvcgDocItem.CATaxDeterminationCode,
//TXJCD
@ObjectModel.text.element: 'TaxJurisdictionName'
_CAInvcgDocItem.TaxJurisdiction,
//KTOSL
@ObjectModel.text.element: 'CATransactionKeyAcctDetnText'
_CAInvcgDocItem.CATransactionKeyAccountDetn,
//KSCHL
@ObjectModel.text.element: 'ConditionTypeName'
_CAInvcgDocItem.CAConditionType,
//TXCAT
_CAInvcgDocItem.CATaxDate,
//SBASW
_CAInvcgDocItem.CATaxBaseAmount,
//SBETW
_CAInvcgDocItem.CATaxAmountInTransCurrency,
//STTAX
_CAInvcgDocItem.CATaxPortionInTransCurrency,
//QSSKZ
_CAInvcgDocItem.WithholdingTaxCode,
//XANZA
_CAInvcgDocItem.CAIsDownPaymentRequest,
//STAKZ
@ObjectModel.text.element: ['CAStatisticalItemCodeText']
_CAInvcgDocItem.CAStatisticalItemCode,
//OFFSET_INV_GR
_CAInvcgDocItem.CAInvcgOffsettingGroup,
//DEFREV_STAT
@ObjectModel.text.element: 'CADeferredRevenueStatusText'
_CAInvcgDocItem.CAInvcgDfrrdRevenueStatus,
//RAREL
_CAInvcgDocItem.CAIsRevenueAccountingRelevant,
//RA_INVGR
_CAInvcgDocItem.CAInvcgRevenueGrouping,
//SERVICE_TYPE
@ObjectModel.text.element: ['CARevnAcctgServiceTypeText']
_CAInvcgDocItem.CARevenueAccountingServiceType,
//BILLAC_TYPE
@ObjectModel.text.element: ['CAInvcgAccrualPostingTypeTxt']
_CAInvcgDocItem.CAInvcgAccrualPostingType,
//PREPAID
_CAInvcgDocItem.CAIsPrepaid,
//MEINS
@ObjectModel.text.element: 'UnitOfMeasureName'
_CAInvcgDocItem.UnitOfMeasure,
//FAEDS
_CAInvcgDocItem.CACashDiscountDueDate,
//SKTPZ
_CAInvcgDocItem.CACashDiscountRate,
//XSTUND
@ObjectModel.text.element: 'CAInvcgDocItmDefStatusText'
_CAInvcgDocItem.CAInvcgDocItemDefStatus,
//DATE_FROM
_CAInvcgDocItem.CAItemPeriodStartDate,
//DATE_TO
_CAInvcgDocItem.CAItemPeriodEndDate,
//CADOCTYPE
@ObjectModel.text.element: 'CAInvcgRefPostgDocTypeTxt'
_CAInvcgDocItem.CAInvcgRefPostingDocType,
//OPBEL
@Consumption.semanticObject: 'CADocument'
_CAInvcgDocItem.CADocumentNumber,
//PSGRP
_CAInvcgDocItem.CAGroupingKeyDocumentItems,
//INVGR
_CAInvcgDocItem.CAInvcgGroupingKey,
//AUGBL
_CAInvcgDocItem.CAClearingDocumentNumber,
//AUGBW
_CAInvcgDocItem.CAClearingAmountInTransCrcy,
//CRMET
@ObjectModel.text.element: 'CAInvcgDocItmCrtnMethodText'
_CAInvcgDocItem.CAInvcgDocItemCrtnMethod,
//INV_FUNCTION
@ObjectModel.text.element: 'CAInvcgFunctionText'
_CAInvcgDocItem.CAInvcgFunction,
//SRCDOCCAT
@ObjectModel.text.element: 'CAInvcgSourceDocCatText'
_CAInvcgDocItem.CAInvcgSourceDocumentCat,
//SRCDOCNO
_CAInvcgDocItem.CAInvcgSourceDocumentNumber,
@UI.hidden: true
_CAInvcgSourceDocCat.CAInvcgSourceDocumentSemObj,
//SRCITEMCAT
@ObjectModel.text.element: 'CAInvcgDocItmSrceItmCatText'
_CAInvcgDocItem.CAInvcgDocItemSourceItmCat,
//SRDOCITEM
_CAInvcgDocItem.CAInvcgSourceDocumentItem,
//DISCKEY
@ObjectModel.text.element: 'CABllbleItmDiscountKeyText'
_CAInvcgDocItem.CABllbleItmDiscountKey,
//DISCKEY_VERSNO
_CAInvcgDocItem.CABllbleItmDiscountVersion,
//CORRCAT
@ObjectModel.text.element: 'CAInvcgCorrectionCatText'
_CAInvcgDocItem.CAInvcgCorrectionCategory,
//applk
@Consumption.hidden: true
CAApplicationArea,
@Consumption.hidden: true
TaxCalculationProcedure,
@Consumption.hidden: true
CompanyCodeCountry,
@UI.hidden: true
_CAInvcgDocItem._CompCode.CompanyCodeName,
@UI.hidden: true
_CAMainTransaction._Text[1: Language=$session.system_language].CAMainTransactionName,
@UI.hidden: true
_CASubTransaction._Text[1: Language=$session.system_language].CASubTransactionName,
@UI.hidden: true
_CAInvcgDocItemType._CAInvcgDocItemTypeText[1: Language=$session.system_language].CAInvcgDocItemTypeText,
@UI.hidden: true
_CASubApplication._CASubApplicationText[1: Language=$session.system_language].CASubApplicationText,
@UI.hidden: true
_Division._Text[1: Language=$session.system_language].DivisionName,
@UI.hidden: true
_CAInvcgDocItmAltvMDCat._CAInvcgDocItmAltvMDCatText[1: Language=$session.system_language].CAInvcgDocItmAltvMDCatText,
@UI.hidden: true
_BusinessArea._Text[1: Language=$session.system_language].BusinessAreaName,
@UI.hidden: true
_TaxCountry._Text[1: Language=$session.system_language].CountryName as TaxCountryName,
@UI.hidden: true
_CAInvcgOffsettingAction._Text[1: Language=$session.system_language].CAInvcgOffsettingActionText,
@UI.hidden: true
_CAInvcgOffsettingCategory._Text[1: Language=$session.system_language].CAInvcgOffsettingCategoryTxt,
@UI.hidden: true
_CAInvcgOffsettingProcedure._Text[1: Language=$session.system_language].CAInvcgOffsettingProcedText,
@UI.hidden: true
_CATaxDetnType._CATaxDetnTypeText[1: Language=$session.system_language].CATaxDetnTypeText,
@UI.hidden: true
_CAOtherTaxCode._Text[1: Language=$session.system_language].CAOtherTaxCodeName,
@UI.hidden: true
_TaxCode._Text[1: Language=$session.system_language].TaxCodeName,
@UI.hidden: true
_TaxJurisdiction._Text[1: Language=$session.system_language].TaxJurisdictionName,
@UI.hidden: true
_CAConditionType._Text[1: Language=$session.system_language].ConditionTypeName,
@UI.hidden: true
_CATransactionKeyAcctDetn._CATransactionKeyAcctDetnText[1: Language=$session.system_language].CATransactionKeyAcctDetnText,
@UI.hidden: true
_CAStatisticalItemCode._CAStatisticalItemCodeText[1: Language=$session.system_language].CAStatisticalItemCodeText,
@UI.hidden: true
_CADeferredRevenueStatus._CADeferredRevenueStatusText[1: Language=$session.system_language].CADeferredRevenueStatusText,
@UI.hidden: true
_CAInvcgDocItmDefStatus._CAInvcgDocItmDefStatusText[1: Language=$session.system_language].CAInvcgDocItmDefStatusText,
@UI.hidden: true
_CARevnAcctgServiceType._CARevnAcctgServiceTypeText[1: Language=$session.system_language].CARevnAcctgServiceTypeText,
@UI.hidden: true
_CAInvcgAccrualPostingType._Text[1: Language=$session.system_language].CAInvcgAccrualPostingTypeTxt,
@UI.hidden: true
_CAInvcgRefPostgDocTyp._CAInvcgRefPostgDocTypTxt[1: Language=$session.system_language].CAInvcgRefPostgDocTypeTxt,
@UI.hidden: true
_CAInvcgDocItmCrtnMethod._CAInvcgDocItmCrtnMethodText[1: Language=$session.system_language].CAInvcgDocItmCrtnMethodText,
@UI.hidden: true
_CAInvcgFunction._CAInvcgFunctionText[1: Language=$session.system_language].CAInvcgFunctionText,
@UI.hidden: true
_CAInvcgSourceDocCat._CAInvcgSourceDocCatText[1: Language=$session.system_language].CAInvcgSourceDocCatText,
@UI.hidden: true
_CAInvcgDocItmSrceItmCat._CAInvcgDocItmSrceItmCatText[1: Language=$session.system_language].CAInvcgDocItmSrceItmCatText,
@UI.hidden: true
_CABllbleItmDiscountKey._CABllbleItmDiscountKeyText[1: Language=$session.system_language].CABllbleItmDiscountKeyText,
@UI.hidden: true
_UnitOfMeasure._Text[1: Language=$session.system_language].UnitOfMeasureName,
@UI.hidden: true
_CAInvcgCorrectionCat._CAInvcgCorrectionCatText[1: Language=$session.system_language].CAInvcgCorrectionCatText,
_CAInvcgDocHeader,
_CAMainTransaction,
_CASubTransaction,
_CAOtherTaxCode,
_TaxCode,
_WithholdingTaxCode,
_TaxJurisdiction,
_BusinessArea,
_CAAccountDetnCode,
_CABllbleItmDiscountKey,
_CAConditionType,
_CACurrencySourceDocument,
_CADeferredRevenueStatus,
_CADocumentHeader,
_CAInvcgDocItemType,
_CAInvcgDocItmAltvMDCat,
_CAInvcgDocItmCrtnMethod,
_CAInvcgDocItmDefStatus,
_CAInvcgDocItmSrceItmCat,
_CAInvcgFunction,
_CAInvcgItmAltvBusinessPartner,
_CAInvcgItmAltvContractAccount,
_CAInvcgRefPostgDocTyp,
_CAInvcgSourceDocCat,
_CARevnAcctgServiceType,
_CAInvcgAccrualPostingType,
_CAStatisticalItemCode,
_CASubApplication,
_CATaxDetnType,
_CATransactionKeyAcctDetn,
_CompCode,
_Division,
_TaxCountry,
_TransactionCurrency,
_UnitOfMeasure,
_CAInvcgCorrectionCat,
_CAInvcgOffsettingAction,
_CAInvcgOffsettingCategory,
_CAInvcgOffsettingProcedure
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BUSINESSAREA",
"I_BUSINESSAREATEXT",
"I_CABLLBLEITMDISCOUNTKEY",
"I_CABLLBLEITMDISCOUNTKEYTEXT",
"I_CADEFERREDREVENUESTATUS",
"I_CADEFERREDREVENUESTATUSTEXT",
"I_CAINVCGACCRUALPOSTINGTYPE",
"I_CAINVCGACCRUALPOSTINGTYPETXT",
"I_CAINVCGCORRECTIONCAT",
"I_CAINVCGCORRECTIONCATTEXT",
"I_CAINVCGDOCITEMTYPE",
"I_CAINVCGDOCITEMTYPETEXT",
"I_CAINVCGDOCITMALTVMDCAT",
"I_CAINVCGDOCITMALTVMDCATTEXT",
"I_CAINVCGDOCITMCRTNMETHOD",
"I_CAINVCGDOCITMCRTNMETHODTEXT",
"I_CAINVCGDOCITMDEFSTATUS",
"I_CAINVCGDOCITMDEFSTATUSTEXT",
"I_CAINVCGDOCITMSRCEITMCAT",
"I_CAINVCGDOCITMSRCEITMCATTEXT",
"I_CAINVCGFUNCTION",
"I_CAINVCGFUNCTIONTEXT",
"I_CAINVCGOFFSETTINGACTION",
"I_CAINVCGOFFSETTINGACTIONTEXT",
"I_CAINVCGOFFSETTINGCATEGORY",
"I_CAINVCGOFFSETTINGCATEGORYTXT",
"I_CAINVCGOFFSETTINGPROCEDTXT",
"I_CAINVCGOFFSETTINGPROCEDURE",
"I_CAINVCGREFPOSTGDOCTYP",
"I_CAINVCGREFPOSTGDOCTYPTXT",
"I_CAINVCGSOURCEDOCCAT",
"I_CAINVCGSOURCEDOCCATTEXT",
"I_CAMAINTRANSACTION",
"I_CAMAINTRANSACTIONTEXT",
"I_CAOTHERTAXCODE",
"I_CAOTHERTAXCODETEXT",
"I_CAREVNACCTGSERVICETYPE",
"I_CAREVNACCTGSERVICETYPETEXT",
"I_CASTATISTICALITEMCODE",
"I_CASTATISTICALITEMCODETEXT",
"I_CASUBAPPLICATION",
"I_CASUBAPPLICATIONTEXT",
"I_CASUBTRANSACTION",
"I_CASUBTRANSACTIONTEXT",
"I_CATAXDETNTYPE",
"I_CATAXDETNTYPETEXT",
"I_CATRANSACTIONKEYACCTDETN",
"I_CATRANSACTIONKEYACCTDETNTEXT",
"I_COMPANYCODE",
"I_CONDITIONTYPE",
"I_CONDITIONTYPETEXT",
"I_COUNTRY",
"I_COUNTRYTEXT",
"I_DIVISION",
"I_DIVISIONTEXT",
"I_TAXCODE",
"I_TAXCODETEXT",
"I_TAXJURISDICTION",
"I_TAXJURISDICTIONTEXT",
"I_UNITOFMEASURE",
"I_UNITOFMEASURETEXT",
"P_CAINVCGDOCITEM"
],
"ASSOCIATED":
[
"C_CAINVCGDOCHEADER",
"E_CAINVCGDOCITEM",
"I_BUSINESSAREA",
"I_BUSINESSPARTNER",
"I_CAACCOUNTDETNCODE",
"I_CABLLBLEITMDISCOUNTKEY",
"I_CADEFERREDREVENUESTATUS",
"I_CADOCUMENTHEADER",
"I_CAINVCGACCRUALPOSTINGTYPE",
"I_CAINVCGCORRECTIONCAT",
"I_CAINVCGDOCITEMTYPE",
"I_CAINVCGDOCITMALTVMDCAT",
"I_CAINVCGDOCITMCRTNMETHOD",
"I_CAINVCGDOCITMDEFSTATUS",
"I_CAINVCGDOCITMSRCEITMCAT",
"I_CAINVCGFUNCTION",
"I_CAINVCGOFFSETTINGACTION",
"I_CAINVCGOFFSETTINGCATEGORY",
"I_CAINVCGOFFSETTINGPROCEDURE",
"I_CAINVCGREFPOSTGDOCTYP",
"I_CAINVCGSOURCEDOCCAT",
"I_CAMAINTRANSACTION",
"I_CAOTHERTAXCODE",
"I_CAREVNACCTGSERVICETYPE",
"I_CASTATISTICALITEMCODE",
"I_CASUBAPPLICATION",
"I_CASUBTRANSACTION",
"I_CATAXDETNTYPE",
"I_CATRANSACTIONKEYACCTDETN",
"I_COMPANYCODE",
"I_CONDITIONTYPE",
"I_CONTRACTACCOUNTHEADER",
"I_COUNTRY",
"I_CURRENCY",
"I_DIVISION",
"I_TAXCODE",
"I_TAXJURISDICTION",
"I_UNITOFMEASURE",
"I_WITHHOLDINGTAXCODE"
],
"BASE":
[
"P_CAINVCGDOCITEM"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/