C_BusinessPartnerPurgOrg

@AbapCatalog.sqlViewName: 'CBUPAPURGORG'
@AbapCatalog.compiler.compareFilter: true

@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@EndUserText.label: 'BP PURCHASING ORG CONSUMPTION VIEW'

@Metadata.allowExtensions: true

@ObjectModel.type: #CONSUMPTION
@ObjectModel.writeEnabled: true
@ObjectModel.semanticKey: [ 'BusinessPartner','PurchasingOrganizationForEdit']
@ObjectModel.createEnabled
@ObjectModel.updateEnabled
@ObjectModel.deleteEnabled
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #MASTER

@Search.searchable: true

@UI.headerInfo:{
  typeName: 'Purchasing Organization',
   typeNamePlural: 'Purchasing Organizations',
  title:  { label:'Purchasing Organization Description', value: '_PurgOrganizationValueHelp.PurchasingOrganizationName' }
  }

@VDM.viewType: #CONSUMPTION

define view C_BusinessPartnerPurgOrg
  as select from I_BusinessPartnerPurgOrgTP as BusinessPartnerPurgOrg
  association [1..1] to C_BusinessPartnerSupplier      as _BusinessPartnerSupplier       on  $projection.BusinessPartner = _BusinessPartnerSupplier.BusinessPartner
  association [1..1] to C_BusinessPartner              as _BusinessPartner               on  $projection.BusinessPartner = _BusinessPartner.BusinessPartner
  association [0..1] to C_PurchasingOrganizationVHTemp as _PurgOrganizationValueHelp     on  $projection.PurchasingOrganizationForEdit = _PurgOrganizationValueHelp.PurchasingOrganization
  association [0..1] to I_PurchasingGroup              as _PurchasingGroup               on  $projection.PurchasingGroup = _PurchasingGroup.PurchasingGroup
  association [0..*] to C_Currencytextvhtemp           as _CurrencyText                  on  $projection.PurchaseOrderCurrency = _CurrencyText.Currency
  association [0..*] to C_SchemaGroupTextVHTemp        as _SchemaGroupText               on  $projection.CalculationSchemaGroupCode = _SchemaGroupText.SchemaGroup
  association [0..*] to C_CustPaymentTermsTextVHTemp   as _PaymentTermsText              on  $projection.PaymentTerms = _PaymentTermsText.CustomerPaymentTerms
  association [1..*] to C_Pricingdatecontroltextvhtemp as _PriceDateControlText          on  $projection.PricingDateControl = _PriceDateControlText.PricingDateControl
  association [0..*] to C_IncotermsVersionTextVHTemp   as _IncotermsVersionText          on  $projection.IncotermsVersion = _IncotermsVersionText.IncotermsVersion
  association [0..*] to C_IncotermsClassfctnTextVHTemp as _IncotermsClassfctnText        on  $projection.IncotermsClassification = _IncotermsClassfctnText.IncotermsClassification
  //association [0..*] to C_BPSupplierPartnerFunction    as _BPSupplierPartnerFunction on $projection.PurchasingOrganization = _BPSupplierPartnerFunction.PurchasingOrganization

  //                                                                                    and $projection.BusinessPartner = _BPSupplierPartnerFunction.BusinessPartner

  //association [0..*] to C_BPSupplierPartnerFunction    as _BPSupplierPartFunc        on $projection.PurchasingOrganization = _BPSupplierPartFunc.PurchasingOrganization

  //                                                                                  and $projection.BusinessPartner = _BPSupplierPartFunc.BusinessPartner

  association [0..*] to C_BPSupplierPartnerFunction    as _BPSupplierPartnerFunction     on  $projection.PurchasingOrganization = _BPSupplierPartnerFunction.PurchasingOrganization
                                                                                         and $projection.BusinessPartner        = _BPSupplierPartnerFunction.BusinessPartner
  association [0..*] to C_BPSupplierPurchasingOrgText  as _BPSupplierPurchasingOrgTxt    on  $projection.PurchasingOrganization = _BPSupplierPurchasingOrgTxt.PurchasingOrganization
                                                                                         and $projection.BusinessPartner        = _BPSupplierPurchasingOrgTxt.BusinessPartner
  association [0..*] to C_BusinessPartnerSupplyRegion  as _BPSupplyRegion                on  $projection.PurchasingOrganization = _BPSupplyRegion.PurchasingOrganization
                                                                                         and $projection.BusinessPartner        = _BPSupplyRegion.BusinessPartner
  association [0..*] to I_LogisticalRoundingProfileT   as _LogisticalRoundingProfileText on  $projection.RoundingProfile = _LogisticalRoundingProfileText.LogisticalRoundingProfile

  association [0..*] to I_MRPPlanningPeriodText        as _MRPPlanningPeriodText         on  $projection.PlanningCycle = _MRPPlanningPeriodText.MRPPlant

  association [1..1] to I_EvaldRcptSettlmtProfileText  as _EvaldRcptSettlmtProfileVH     on  $projection.PurchasingOrganization     = _EvaldRcptSettlmtProfileVH.PurchasingOrganization
                                                                                         and $projection.EvaldRcptSettlementProfile = _EvaldRcptSettlmtProfileVH.EvaldRcptSettlementProfile
                                                                                         and _EvaldRcptSettlmtProfileVH.Language    = $session.system_language
  association [0..1] to I_TransportationLocationVH     as _TransportLocationVHText       on  $projection.IncotermsSupChnDvtgLocAddlUUID = _TransportLocationVHText.LocationAdditionalUUID

{
  key BusinessPartnerPurgOrg.BusinessPartner,
  key BusinessPartnerPurgOrg.PurchasingOrganization,
      BusinessPartnerPurgOrg.Supplier,
      BusinessPartnerPurgOrg.BusinessPartnerForEdit,
      BusinessPartnerPurgOrg.BusinessPartnerUUID,
      @ObjectModel: {
                      foreignKey.association: '_PurgOrganizationValueHelp'
                    }
      BusinessPartnerPurgOrg.PurchasingOrganizationForEdit,
      @ObjectModel.foreignKey.association: '_PurchasingGroup'
      BusinessPartnerPurgOrg.PurchasingGroup,
      BusinessPartnerPurgOrg.PlannedDeliveryDurationInDays,
      BusinessPartnerPurgOrg.PurchasingIsBlockedForSupplier,
      BusinessPartnerPurgOrg.SupplierRespSalesPersonName,
      BusinessPartnerPurgOrg.ContactPersonPhoneNumber,
      @Semantics.currencyCode: true
      @ObjectModel.text.association: '_CurrencyText'
      BusinessPartnerPurgOrg.PurchaseOrderCurrency,
      @Semantics.amount.currencyCode: 'PurchaseOrderCurrency'
      BusinessPartnerPurgOrg.MinimumOrderAmount,
      @ObjectModel.text.association: '_SchemaGroupText'
      BusinessPartnerPurgOrg.CalculationSchemaGroupCode,
      @ObjectModel.text.association: '_PaymentTermsText'
      BusinessPartnerPurgOrg.PaymentTerms,
      @ObjectModel.text.association: '_PriceDateControlText'
      BusinessPartnerPurgOrg.PricingDateControl,
      BusinessPartnerPurgOrg.SupplierABCClassificationCode,
      BusinessPartnerPurgOrg.ShippingCondition,
      BusinessPartnerPurgOrg.PurOrdAutoGenerationIsAllowed,
      BusinessPartnerPurgOrg.InvoiceIsGoodsReceiptBased,
      @ObjectModel.text.association: '_IncotermsVersionText'
      BusinessPartnerPurgOrg.IncotermsVersion,
      @ObjectModel.text.association: '_IncotermsClassfctnText'
      BusinessPartnerPurgOrg.IncotermsClassification,
      BusinessPartnerPurgOrg.IncotermsTransferLocation,
      BusinessPartnerPurgOrg.IncotermsLocation1,
      BusinessPartnerPurgOrg.IncotermsLocation2,
      BusinessPartnerPurgOrg.SupplierConfirmationControlKey,
      BusinessPartnerPurgOrg.IsOrderAcknRqd,
      BusinessPartnerPurgOrg.SuplrIsSubjToSubsqntSettlement,
      BusinessPartnerPurgOrg.SuplrPurgOrgAgrmtOfBusVolIsRqd,
      BusinessPartnerPurgOrg.SuplrInvcRevalIsAllowed,
      BusinessPartnerPurgOrg.SuplrPurgOrgIsRlvtForPriceDetn,
      @ObjectModel.text.association: '_LogisticalRoundingProfileText'
      BusinessPartnerPurgOrg.RoundingProfile,
      @ObjectModel.text.association: '_MRPPlanningPeriodText'
      BusinessPartnerPurgOrg.PlanningCycle,
      BusinessPartnerPurgOrg.SuplrDiscountInKindIsGranted,
      BusinessPartnerPurgOrg.SuplrIsRlvtForSettlmtMgmt,
      //    BusinessPartnerPurgOrg.InvoiceIsMMServiceEntryBased,

      //    @EndUserText.label: 'PROACT Control Prof'

      //    BusinessPartnerPurgOrg.ProdStockAndSlsDataTransfPrfl,

      @EndUserText.label: 'Evaluated Receipt Settlement'
      BusinessPartnerPurgOrg.EvaldReceiptSettlementIsActive,
      @ObjectModel.readOnly: true
      _EvaldRcptSettlmtProfileVH.EvaldRcptSettlementProfileText,
      @EndUserText.label: 'Settlement Profile'
      @ObjectModel.text.element: ['EvaldRcptSettlementProfileText']
      BusinessPartnerPurgOrg.EvaldRcptSettlementProfile,
      @Semantics.amount.currencyCode: 'PurchaseOrderCurrency'
      @EndUserText.label: 'Absolute Surcharge'
      BusinessPartnerPurgOrg.AbsoluteHandlingSurchargeAmt,
      BusinessPartnerPurgOrg.PercentageHandlingSurchargeAmt,
      @EndUserText.label: 'Minimum HSC'
      @Semantics.amount.currencyCode: 'PurchaseOrderCurrency'
      BusinessPartnerPurgOrg.MinimumHandlingSurchargeAmt,
      @EndUserText.label: 'Maximum HSC'
      @Semantics.amount.currencyCode: 'PurchaseOrderCurrency'
      BusinessPartnerPurgOrg.MaximumHandlingSurchargeAmt,
      @EndUserText.label: 'Automatic Evaluated Receipt Settlement'
      BusinessPartnerPurgOrg.AutomaticEvaluatedRcptSettlmt,
      @EndUserText.label: 'Automatic Debit Creation'
      BusinessPartnerPurgOrg.AutomDebitCrtnIsEnbldOnGI,
      BusinessPartnerPurgOrg.SupplierAccountNumber,
      BusinessPartnerPurgOrg.IncotermsLocation1Identifier,
      BusinessPartnerPurgOrg.IncotermsLocation2Identifier,
      @ObjectModel.readOnly: true
      @Semantics.text: true
      _TransportLocationVHText.LocationDescription as IncotermsDvtgLocDescription,
      @ObjectModel.text.element: ['IncotermsDvtgLocDescription']
      BusinessPartnerPurgOrg.IncotermsDvtgLocIdentifier,
      BusinessPartnerPurgOrg.IncotermsSupChnDvtgLocAddlUUID,
      @ObjectModel.association.type: [ #TO_COMPOSITION_ROOT , #TO_COMPOSITION_PARENT ]
      _BusinessPartnerSupplier,
      @ObjectModel.association.type: [ #TO_COMPOSITION_ROOT , #TO_COMPOSITION_PARENT ]
      _BusinessPartner,
      _PurgOrganizationValueHelp,
      _PurchasingGroup,
      _ShipgCndnValueHelp,
      _CurrencyText,
      _SchemaGroupText,
      _PaymentTermsText,
      _PriceDateControlText,
      _IncotermsVersionText,
      _IncotermsClassfctnText,
      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _BPSupplierPartnerFunction,
      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _BPSupplierPurchasingOrgTxt,
      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _BPSupplyRegion,
      _LogisticalRoundingProfileText,
      _EvaldRcptSettlmtProfileVH,
      _MRPPlanningPeriodText
      //_BPSupplierPartFunc

      //      _BPSupplierPartnerFunction

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BUSINESSPARTNERPURGORGTP",
"I_EVALDRCPTSETTLMTPROFILETEXT",
"I_TRANSPORTATIONLOCATIONVH"
],
"ASSOCIATED":
[
"C_BPSUPPLIERPARTNERFUNCTION",
"C_BPSUPPLIERPURCHASINGORGTEXT",
"C_BUSINESSPARTNER",
"C_BUSINESSPARTNERSUPPLIER",
"C_BUSINESSPARTNERSUPPLYREGION",
"C_CURRENCYTEXTVHTEMP",
"C_CUSTPAYMENTTERMSTEXTVHTEMP",
"C_INCOTERMSCLASSFCTNTEXTVHTEMP",
"C_INCOTERMSVERSIONTEXTVHTEMP",
"C_PRICINGDATECONTROLTEXTVHTEMP",
"C_PURCHASINGORGANIZATIONVHTEMP",
"C_SCHEMAGROUPTEXTVHTEMP",
"I_EVALDRCPTSETTLMTPROFILETEXT",
"I_LOGISTICALROUNDINGPROFILET",
"I_MRPPLANNINGPERIODTEXT",
"I_PURCHASINGGROUP",
"I_SHIPPINGCONDITION",
"I_TRANSPORTATIONLOCATIONVH"
],
"BASE":
[
"I_BUSINESSPARTNERPURGORGTP"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/