C_BusinessPartnerCust

@AbapCatalog.sqlViewName: 'CBUPACUST'
@AbapCatalog.compiler.compareFilter: true

@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@EndUserText.label: 'Business Partner Customer'

@Metadata.allowExtensions: true

@ObjectModel.type: #CONSUMPTION
@ObjectModel.writeEnabled: true
@ObjectModel: {
    semanticKey: ['BusinessPartner'],
    createEnabled,
    updateEnabled
}
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #MASTER

@Search.searchable: true

@UI.headerInfo:{
  typeName: 'Customer',
  typeNamePlural: 'Customers',
  title:  { label:'Business Partner', value: 'BusinessPartnerForEdit' }
  }
@ObjectModel.text.control: #ASSOCIATED_TEXT_UI_HIDDEN
@VDM.viewType: #CONSUMPTION

define view C_BusinessPartnerCust
  as select from I_BusinessPartnerCustomerTP as BusinessPartnerCustomer

  association [1..1] to C_BusinessPartnerCustomer       as _BusinessPartnerCustomer     on  $projection.BusinessPartner = _BusinessPartnerCustomer.BusinessPartner

  association [1..1] to C_BusinessPartner               as _BusinessPartner             on  $projection.BusinessPartner = _BusinessPartner.BusinessPartner

  association [0..1] to I_Supplier_VH                   as _SupplierValueHelp           on  $projection.Supplier = _SupplierValueHelp.Supplier

  association [0..1] to I_Customer_VH                   as _AlternativePayerValueHelp   on  $projection.AlternativePayerAccount = _AlternativePayerValueHelp.Customer

  association [0..*] to C_DataMdmExchTextVHTemp         as _DataMdmExchText             on  $projection.DataMediumExchangeIndicator = _DataMdmExchText.DataMediumExchangeIndicator

  association [0..*] to I_DeliveryDateTypeRuleText      as _DeliveryDateTypeRuleText    on  $projection.DeliveryDateTypeRule = _DeliveryDateTypeRuleText.DeliveryDateTypeRule

  association [0..1] to I_Globalcompany                 as _TradingPartnerValueHelp     on  $projection.TradingPartner = _TradingPartnerValueHelp.Company

  association [0..*] to I_BusPartAuthorizationGroupTxt  as _AuthorizationGroupText      on  $projection.AuthorizationGroup              = _AuthorizationGroupText.AuthorizationGroup
                                                                                      and _AuthorizationGroupText.AuthorizationObject = 'CUST'
  association [0..1] to I_PlantStdVH                  as _PlantStdVH                  on  $projection.Plant = _PlantStdVH.Plant

  association [0..*] to I_CityCodeText                as _CityCodeText                on  $projection.CityCode  = _CityCodeText.CityCode
                                                                                      and _CityCodeText.Country = BusinessPartnerCustomer.Country
                                                                                      and _CityCodeText.Region  = BusinessPartnerCustomer.Region

  association [0..*] to C_CountyCodeTempValueHelpText as _CountyCodeText              on  $projection.County  = _CountyCodeText.County
                                                                                      and $projection.Region  = _CountyCodeText.Region
                                                                                      and $projection.Country = _CountyCodeText.Country

  association [0..*] to I_CustIndustryCodeValHelpText as _CustIndustryCodeTextOne     on  $projection.IndustryCode1 = _CustIndustryCodeTextOne.IndustryCode1

  association [0..*] to I_CustIndustryCodeValHelpText as _CustIndustryCodeTextTwo     on  $projection.IndustryCode2 = _CustIndustryCodeTextTwo.IndustryCode1

  association [0..*] to I_CustIndustryCodeValHelpText as _CustIndustryCodeTextThree   on  $projection.IndustryCode3 = _CustIndustryCodeTextThree.IndustryCode1

  association [0..*] to I_CustCndnGroupValueHelpText  as _CustCndnGroupTextOne        on  $projection.CustomerConditionGroup1 = _CustCndnGroupTextOne.CustomerConditionGroup

  association [0..*] to I_CustCndnGroupValueHelpText  as _CustCndnGroupTextTwo        on  $projection.CustomerConditionGroup2 = _CustCndnGroupTextTwo.CustomerConditionGroup

  association [0..*] to I_CustCndnGroupValueHelpText  as _CustCndnGroupTextThree      on  $projection.CustomerConditionGroup3 = _CustCndnGroupTextThree.CustomerConditionGroup

  association [0..*] to I_CustCndnGroupValueHelpText  as _CustCndnGroupTextFour       on  $projection.CustomerConditionGroup4 = _CustCndnGroupTextFour.CustomerConditionGroup

  association [0..*] to I_CustCndnGroupValueHelpText  as _CustCndnGroupTextFive       on  $projection.CustomerConditionGroup5 = _CustCndnGroupTextFive.CustomerConditionGroup

  /// association [0..*] to I_PaymentReasonText as _PaymentReasonText on $projection.PaymentReason = _PaymentReasonText.PaymentReason


  association [0..1] to I_DataExchangeInstructionKeys as _DataExchangeInstructionKeys on  $projection.DataExchangeInstructionKey      = _DataExchangeInstructionKeys.DataExchangeInstructionKey
                                                                                      and _DataExchangeInstructionKeys.BankCountryKey = ''
                                                                                      and _DataExchangeInstructionKeys.PaymentMethod  = ''

  association [0..1] to I_Customer_VH                 as _FiscalAddressValueHelp      on  $projection.FiscalAddress = _FiscalAddressValueHelp.Customer
  
  association [0..*] to C_BPCustomerMultiAddrVH       as _BPCustomerMultiAddrVH       on  $projection.Customer = _BPCustomerMultiAddrVH.Customer
  

//  association [0..*] to C_OrderIsBlockedTextVHTemp     as _OrderBlockValueHelp         on $projection.OrderIsBlockedForCustomer = _OrderBlockValueHelp.OrderIsBlockedForCustomer

{
  key BusinessPartnerCustomer.BusinessPartner,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      BusinessPartnerCustomer.Customer,
      BusinessPartnerCustomer.BusinessPartnerForEdit,
      BusinessPartnerCustomer.BusinessPartnerUUID,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      BusinessPartnerCustomer.CustomerAccountGroup,
      @ObjectModel: {
                  foreignKey.association: '_AlternativePayerValueHelp'
                }
//      @Consumption.valueHelp: '_AlternativePayerValueHelp'

      @Consumption.valueHelpDefinition: [{ entity: { name: 'D_BPCustomerCVH',
                                         element: 'Customer' }
                              } ]
      BusinessPartnerCustomer.AlternativePayerAccount,
      @ObjectModel.text.association: '_DataMdmExchText'
      BusinessPartnerCustomer.DataMediumExchangeIndicator,
      @ObjectModel: {
                     foreignKey.association: '_SupplierValueHelp'
                   }
      @Consumption.valueHelp: '_SupplierValueHelp'
      BusinessPartnerCustomer.Supplier,
      BusinessPartnerCustomer.CustomerClassification,
      BusinessPartnerCustomer.VATLiability,
      BusinessPartnerCustomer.BillingIsBlockedForCustomer,
      BusinessPartnerCustomer.DeliveryIsBlocked,
      BusinessPartnerCustomer.PostingIsBlocked,
      // @ObjectModel: {

      //foreignKey.association: '_OrderBlockValueHelp'

      //}

      @EndUserText.label: 'Order Block'
      BusinessPartnerCustomer.OrderIsBlockedForCustomer,
      BusinessPartnerCustomer.IsNaturalPerson,
      @ObjectModel.text.association: '_AuthorizationGroupText'
      BusinessPartnerCustomer.AuthorizationGroup,
      @ObjectModel.text.association:'_DeliveryDateTypeRuleText'
      BusinessPartnerCustomer.DeliveryDateTypeRule,
      @ObjectModel: {
                  foreignKey.association: '_TradingPartnerValueHelp'
                }
      //@Consumption.valueHelp: '_TradingPartnerValueHelp'

      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      BusinessPartnerCustomer.TradingPartner,

      BusinessPartnerCustomer.ExpressTrainStationName,
      BusinessPartnerCustomer.TrainStationName,
      BusinessPartnerCustomer.CityLocationCoordinatesCode,
      @ObjectModel.text.association: '_PlantStdVH'
      BusinessPartnerCustomer.Plant,
      BusinessPartnerCustomer.CustomerCorporateGroup,
      BusinessPartnerCustomer.DataExchangeInstructionKey,
      @ObjectModel.text.association: '_CustIndustryCodeTextOne'
      @EndUserText.label: 'Industry Code 1'
      BusinessPartnerCustomer.IndustryCode1,
      @ObjectModel.text.association: '_CustIndustryCodeTextTwo'
      @EndUserText.label: 'Industry Code 2'
      BusinessPartnerCustomer.IndustryCode2,
      @ObjectModel.text.association: '_CustIndustryCodeTextThree'
      @EndUserText.label: 'Industry Code 3'
      BusinessPartnerCustomer.IndustryCode3,
      BusinessPartnerCustomer.IsCompetitor,
      BusinessPartnerCustomer.IsSalesPartner,
      BusinessPartnerCustomer.IsDefaultSoldToParty,
      BusinessPartnerCustomer.IsConsumer,
      @ObjectModel.text.association: '_FiscalAddressValueHelp'
      BusinessPartnerCustomer.FiscalAddress,
      BusinessPartnerCustomer.FreeDefinedAttribute03,
      @ObjectModel.text.association: '_CustCndnGroupTextOne'
      BusinessPartnerCustomer.CustomerConditionGroup1,
      @ObjectModel.text.association: '_CustCndnGroupTextTwo'
      BusinessPartnerCustomer.CustomerConditionGroup2,
      @ObjectModel.text.association: '_CustCndnGroupTextThree'
      BusinessPartnerCustomer.CustomerConditionGroup3,
      @ObjectModel.text.association: '_CustCndnGroupTextFour'
      BusinessPartnerCustomer.CustomerConditionGroup4,
      @ObjectModel.text.association: '_CustCndnGroupTextFive'
      BusinessPartnerCustomer.CustomerConditionGroup5,
      @EndUserText.quickInfo: 'Sales Equalizatn Tax'
      BusinessPartnerCustomer.BPIsEqualizationTaxSubject,
      @ObjectModel.text.association: '_CityCodeText'
      BusinessPartnerCustomer.CityCode,
      @ObjectModel.text.association: '_CountyCodeText'
      BusinessPartnerCustomer.County,
      BusinessPartnerCustomer.Country,
      BusinessPartnerCustomer.Region,
      BusinessPartnerCustomer.Language,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      BusinessPartnerCustomer.DeletionIndicator,
      BusinessPartnerCustomer.SalesIsBlockedForCustomer,
      BusinessPartnerCustomer.CustomerCentralDeletionIsBlock,
      //      @ObjectModel.text.association: '_PaymentReasonText'

      BusinessPartnerCustomer.PaymentReason,

      @ObjectModel.readOnly: true
      _BusinessPartner.BPCustMultiAddrIsActive as BPCustMultiAddrIsActive,


      @ObjectModel.association.type:  [#TO_COMPOSITION_PARENT,#TO_COMPOSITION_ROOT ]
      _BusinessPartnerCustomer,
      @ObjectModel.association.type:   [#TO_COMPOSITION_PARENT,#TO_COMPOSITION_ROOT ]
      _BusinessPartner,
      //   _PaymentReasonText,

      _DelivBlkRsnValueHelp,
      _SupplierValueHelp,
      _AlternativePayerValueHelp,
      _AccountGroupValueHelp,
      _CustomerAccountGroupText,
      _BillingBlockReasonValueHelp,
      _BillingBlockReasonText,
      _CustomerClassValueHelp,
      _CustomerClassificationText,
      _DataMdmExchText,
      _DeliveryDateTypeRuleText,
      _DeliveryBlockReasonText,
      _TradingPartnerValueHelp,
      _AuthorizationGroupText,
      _PlantStdVH,
      _CityCodeText,
      _CountyCodeText,
      _CustIndustryCodeTextOne,
      _CustIndustryCodeTextTwo,
      _CustCndnGroupTextOne,
      _CustCndnGroupTextTwo,
      _DataExchangeInstructionKeys,
      _CustIndustryCodeTextThree,
      _CustCndnGroupTextThree,
      _CustCndnGroupTextFour,
      _CustCndnGroupTextFive,
      _FiscalAddressValueHelp,
      _BPCustomerMultiAddrVH
    //  _OrderBlockValueHelp 


}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"C_BUSINESSPARTNER",
"I_BUSINESSPARTNERCUSTOMERTP"
],
"ASSOCIATED":
[
"C_BPCUSTOMERMULTIADDRVH",
"C_BUSINESSPARTNER",
"C_BUSINESSPARTNERCUSTOMER",
"C_COUNTYCODETEMPVALUEHELPTEXT",
"C_DATAMDMEXCHTEXTVHTEMP",
"I_BILLINGBLOCKREASON",
"I_BILLINGBLOCKREASONTEXT",
"I_BUSPARTAUTHORIZATIONGROUPTXT",
"I_CITYCODETEXT",
"I_CUSTCNDNGROUPVALUEHELPTEXT",
"I_CUSTINDUSTRYCODEVALHELPTEXT",
"I_CUSTOMERACCOUNTGROUP",
"I_CUSTOMERACCOUNTGROUPTEXT",
"I_CUSTOMERCLASSIFICATION",
"I_CUSTOMERCLASSIFICATIONTEXT",
"I_CUSTOMER_VH",
"I_DATAEXCHANGEINSTRUCTIONKEYS",
"I_DELIVERYBLOCKREASON",
"I_DELIVERYBLOCKREASONTEXT",
"I_DELIVERYDATETYPERULETEXT",
"I_GLOBALCOMPANY",
"I_PLANTSTDVH",
"I_SUPPLIER_VH"
],
"BASE":
[
"I_BUSINESSPARTNERCUSTOMERTP"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/