C_BusinessPartnerContact

@AbapCatalog.sqlViewName: 'CBUPACONTACT'
@AbapCatalog.compiler.compareFilter: true

@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE

@EndUserText.label: 'Consumption BusinessPartner Contact'

@Metadata.allowExtensions: true

@ObjectModel.type: #CONSUMPTION
@ObjectModel: {
    semanticKey: ['BusinessPartner', 'BusinessPartnerPersonForEdit', 'RelationshipNumber'],
    createEnabled,
    updateEnabled,
    deleteEnabled
}
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #MASTER

@Search.searchable: true

@UI.headerInfo:{
  typeName: 'Contact',
    typeNamePlural: 'Contacts',
  title:  { label:'Contact Person Name', value: 'FullName' }
  }

@VDM.viewType: #CONSUMPTION

define view C_BusinessPartnerContact
  as select from I_BusinessPartnerContactTP as BusinessPartnerContact
  
  association [1..1] to C_BusinessPartner         as _BusinessPartner         on $projection.BusinessPartner = _BusinessPartner.BusinessPartner
  
  association [1..1] to C_BusinessPartnerSupplier as _BusinessPartnerSupplier on $projection.BusinessPartner = _BusinessPartnerSupplier.BusinessPartner
  
  association [1..1] to C_BusinessPartnerCustomer as _BusinessPartnerCustomer on $projection.BusinessPartner = _BusinessPartnerCustomer.BusinessPartner
  
  association [0..*] to C_TitleTextVHTemp         as _TitleText               on $projection.FormOfAddress = _TitleText.FormOfAddress
  
  association [0..*] to C_TelCountryTextVHTemp    as _PhoneNumberCountryText  on $projection.PhoneNumberCountry = _PhoneNumberCountryText.Country
  
  association [0..*] to C_TelCountryTextVHTemp    as _MobilePhoneCountryText  on $projection.PhoneNumberCountry = _MobilePhoneCountryText.Country
  
  association [0..*] to C_TelCountryTextVHTemp    as _FaxCountryText          on $projection.PhoneNumberCountry = _FaxCountryText.Country

  association [0..*] to C_BPContactAddress        as _BPContactAddress         on $projection.BusinessPartner = _BPContactAddress.BusinessPartner1
                                                                               and $projection.BusinessPartnerPerson = _BPContactAddress.BusinessPartner2
                                                                               and $projection.RelationshipNumber = _BPContactAddress.RelationshipNumber
                                                                               and $projection.ValidityEndDate = _BPContactAddress.ValidityEndDate
  association [0..*] to C_BPLanguageTextValueHelp  as _BPLanguageText           on  $projection.CorrespondenceLanguage = _BPLanguageText.LanguageCode
//  association [0..1] to I_BusPartRelshpCategoryVH as _BPRoleCategoryText      on $projection.RelationshipCategory = _BPRoleCategoryText.RelationshipCategory                    

//                                                                            and $projection.BPRelshpCatIsInFwdDirection = _BPRoleCategoryText.BPRelshpCatIsInFwdDirection                                                                     

                                                                            
{
  key BusinessPartnerContact.BusinessPartner,      
  key BusinessPartnerContact.BusinessPartnerPerson,      
  key BusinessPartnerContact.RelationshipNumber,
  key BusinessPartnerContact.ValidityEndDate,      
      BusinessPartnerContact.BusinessPartnerForEdit,
      BusinessPartnerContact.BusinessPartnerPersonForEdit,      
      BusinessPartnerContact.RelationshipNumberForEdit,  
      BusinessPartnerContact.ValidityEndDateForEdit,      // Internal Incident: 2280164720

 //     @ObjectModel.readOnly: true

  //    @ObjectModel.text.element: ['BusPartRelshpCatDescription']

//      BusinessPartnerContact.RelationshipCategory,

//      BusinessPartnerContact.BPRelshpCatIsInFwdDirection,

      BusinessPartnerContact.PersonUUID, 
      @ObjectModel.text.association: '_TitleText'
      BusinessPartnerContact.FormOfAddress,
      BusinessPartnerContact.FirstName,
      BusinessPartnerContact.LastName,
      BusinessPartnerContact.BirthDate,
      @ObjectModel.text.association: '_BPLanguageText'
      //@ObjectModel.readOnly: true  

      BusinessPartnerContact.CorrespondenceLanguage,
      BusinessPartnerContact.ValidityStartDate,
      @ObjectModel.text.association: '_PhoneNumberCountryText'
      BusinessPartnerContact.PhoneNumberCountry,
      BusinessPartnerContact.PhoneNumber,
      BusinessPartnerContact.PhoneNumberExtension,
      @ObjectModel.text.association: '_MobilePhoneCountryText'
      BusinessPartnerContact.MobilePhoneCountry,
      BusinessPartnerContact.MobilePhoneNumber,
      @ObjectModel.text.association: '_FaxCountryText'
      BusinessPartnerContact.FaxCountry,
      BusinessPartnerContact.FaxNumber,
      BusinessPartnerContact.FaxNumberExtension,
      BusinessPartnerContact.EmailAddress,
      @UI.textArrangement: #TEXT_FIRST 
      BusinessPartnerContact.ContactPersonFunction,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      @UI.textArrangement: #TEXT_FIRST 
      BusinessPartnerContact.ContactPersonDepartment,
      BusinessPartnerContact.Building,
      BusinessPartnerContact.Floor,
      BusinessPartnerContact.RoomNumber,
      @ObjectModel.readOnly: true      
      BusinessPartnerContact.FullName,      
      BusinessPartnerContact.BusinessPartnerCategory, 
      
      BusinessPartnerContact.ContactPersonVIPType,
      BusinessPartnerContact.ContactPersonAuthorityType,
      BusinessPartnerContact.ContactPersonRemarkText,
      
      @ObjectModel.association.type: [#TO_COMPOSITION_ROOT, #TO_COMPOSITION_PARENT]
      _BusinessPartnerSupplier,
      @ObjectModel.association.type: [#TO_COMPOSITION_ROOT, #TO_COMPOSITION_PARENT]
      _BusinessPartnerCustomer,
      @ObjectModel.association.type: [#TO_COMPOSITION_ROOT, #TO_COMPOSITION_PARENT]
      _BusinessPartner,
//       @ObjectModel.readOnly: true

//      _BPRoleCategoryText.BusPartRelshpCatDescription,

      _CntctPersnFuncValueHelp,
      _CntctPersnDeptValueHelp,
      _ContactPersonFunction,
      _TitleText,
      _PhoneNumberCountryText, 
      _MobilePhoneCountryText,
      _BPLanguageText,
      _FaxCountryText,
       @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _BPContactAddress,
//      _BPRoleCategoryText,

       /* Associations */
       @Consumption.filter.hidden:true
      _BusinessPartnerCompany,
      @Consumption.filter.hidden:true
      _BusinessPartnerPerson
      
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BUSINESSPARTNERCONTACTTP"
],
"ASSOCIATED":
[
"C_BPCONTACTADDRESS",
"C_BPLANGUAGETEXTVALUEHELP",
"C_BUSINESSPARTNER",
"C_BUSINESSPARTNERCUSTOMER",
"C_BUSINESSPARTNERSUPPLIER",
"C_TELCOUNTRYTEXTVHTEMP",
"C_TITLETEXTVHTEMP",
"I_BUSINESSPARTNER",
"I_CONTACTPERSONDEPARTMENT",
"I_CONTACTPERSONFUNCTION"
],
"BASE":
[
"I_BUSINESSPARTNERCONTACTTP"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/