C_BusinessPartnerAddress

@AbapCatalog.sqlViewName: 'CBUPAADDRESS1'
@AbapCatalog.compiler.compareFilter: true

@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@EndUserText.label: 'Business Partner Address'

@Metadata.allowExtensions: true

@ObjectModel.type: #CONSUMPTION
@ObjectModel.writeEnabled: true
@ObjectModel: {
    semanticKey: ['BusinessPartner','AddressNumber' ],
    createEnabled,
    updateEnabled,
    deleteEnabled
}
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #MASTER

@Search.searchable: true

@UI.headerInfo:{
  typeName: 'Address Details',
  typeNamePlural: 'Address Details',
  title:  { label:'Address', value: 'FormattedPostalAddressText' }
  }

@VDM.viewType: #CONSUMPTION

define view C_BusinessPartnerAddress
  as select from I_BusinessPartnerAddressTP as BusinessPartnerAddress

  association [1..1] to C_BusinessPartner          as _BusinessPartner          on  $projection.BusinessPartner = _BusinessPartner.BusinessPartner

  association [1..1] to C_BusinessPartnerSupplier  as _BusinessPartnerSupplier  on  $projection.BusinessPartner = _BusinessPartnerSupplier.BusinessPartner

  association [1..1] to C_BusinessPartnerCustomer  as _BusinessPartnerCustomer  on  $projection.BusinessPartner = _BusinessPartnerCustomer.BusinessPartner

  association [1..*] to C_Businesspartneraddrusage as _BusinessPartnerAddrUsage on  $projection.BusinessPartner = _BusinessPartnerAddrUsage.BusinessPartner
                                                                                and $projection.AddressNumber   = _BusinessPartnerAddrUsage.AddressNumber

  association [0..*] to C_BPTelephoneNumber        as _BPTelephoneNumber        on  $projection.BusinessPartner = _BPTelephoneNumber.BusinessPartner
                                                                                and $projection.AddressNumber   = _BPTelephoneNumber.AddressID

  association [0..1] to C_BPTelephoneNumber        as _BPStdTelephoneNumber        on  $projection.BusinessPartner = _BPStdTelephoneNumber.BusinessPartner
                                                                                and $projection.AddressNumber   = _BPStdTelephoneNumber.AddressID
                                                                                and _BPStdTelephoneNumber.IsDefaultPhoneNumber = 'X'
                                                                                
  association [0..*] to C_BPMobilePhoneNumber      as _BPMobilePhoneNumber      on  $projection.BusinessPartner = _BPMobilePhoneNumber.BusinessPartner
                                                                                and $projection.AddressNumber   = _BPMobilePhoneNumber.AddressID

  association [0..1] to C_BPMobilePhoneNumber      as _BPStdMobilePhoneNumber      on  $projection.BusinessPartner = _BPStdMobilePhoneNumber.BusinessPartner
                                                                                and $projection.AddressNumber   = _BPStdMobilePhoneNumber.AddressID
                                                                                and _BPStdMobilePhoneNumber.IsDefaultPhoneNumber = 'X'
                                                                                
  association [0..*] to C_BPFaxNumber              as _BPFaxNumber              on  $projection.BusinessPartner = _BPFaxNumber.BusinessPartner
                                                                                and $projection.AddressNumber   = _BPFaxNumber.AddressID

  association [0..1] to C_BPFaxNumber              as _BPStdFaxNumber              on  $projection.BusinessPartner = _BPStdFaxNumber.BusinessPartner
                                                                                and $projection.AddressNumber   = _BPStdFaxNumber.AddressID
                                                                                and _BPStdFaxNumber.IsDefaultFaxNumber = 'X'
                                                                                
  association [0..*] to C_BPWebsiteURL             as _BPWebsiteURL             on  $projection.BusinessPartner = _BPWebsiteURL.BusinessPartner
                                                                                and $projection.AddressNumber   = _BPWebsiteURL.AddressID
                                                                                
  association [0..1] to C_BPWebsiteURL             as _BPStdWebsiteURL             on  $projection.BusinessPartner = _BPStdWebsiteURL.BusinessPartner
                                                                                and $projection.AddressNumber   = _BPStdWebsiteURL.AddressID
                                                                                and _BPStdWebsiteURL.IsDefaultURLAddress = 'X'  

  association [0..*] to C_BPEmailAddress           as _BPEmailAddress           on  $projection.BusinessPartner = _BPEmailAddress.BusinessPartner
                                                                                and $projection.AddressNumber   = _BPEmailAddress.AddressID
                                                                                
  association [0..1] to C_BPEmailAddress           as _BPStdEmailAddress           on  $projection.BusinessPartner = _BPStdEmailAddress.BusinessPartner
                                                                                and $projection.AddressNumber   = _BPStdEmailAddress.AddressID
                                                                                and _BPStdEmailAddress.IsDefaultEmailAddress = 'X'
                                                                                                                                                               
  association [0..*] to C_Countrytextvhtemp        as _CountryText              on  $projection.Country = _CountryText.Country

  association [1..*] to C_RegionTextVHTemp         as _RegionText               on  $projection.Country = _RegionText.Country
                                                                                and $projection.Region  = _RegionText.Region

  association [0..1] to I_Country                  as _Country                  on  $projection.Country = _Country.Country

  association [0..*] to C_BPLanguageTextValueHelp  as _LanguageText             on  $projection.CorrespondenceLanguage = _LanguageText.LanguageCode

  association [0..*] to C_CommMethTextVhTemp       as _CommMethText             on  $projection.PrfrdCommMediumType = _CommMethText.CommunicationMediumType

  association [1..*] to C_TelCountryTextVHTemp     as _TelCountryText           on  $projection.PhoneNumberCountry = _TelCountryText.Country

  association [1..*] to C_TelCountryTextVHTemp     as _MblCountryText           on  $projection.MobilePhoneCountry = _MblCountryText.Country

  association [1..*] to C_TelCountryTextVHTemp     as _FaxCountryText           on  $projection.FaxCountry = _FaxCountryText.Country

  association [0..*] to I_TimeZoneText             as _TimeZoneText             on  $projection.AddressTimeZone = _TimeZoneText.TimeZoneID

  association [0..*] to I_Transportation_Zone_Text as _TransportZoneText        on  $projection.TransportZone = _TransportZoneText.TransportZone
                                                                                and $projection.Country       = _TransportZoneText.CountryCode
  

{
  key BusinessPartnerAddress.BusinessPartner,
  key BusinessPartnerAddress.AddressNumber,
      //BusinessPartnerAddress.CompleteAddress,

     // BusinessPartnerAddress.AddressLine1Text,//replaced with Formatted address 

     // BusinessPartnerAddress.AddressLine2Text, // replaced with InternationalPhoneNumber and EmailAddress

      BusinessPartnerAddress.BusinessPartnerForEdit,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      BusinessPartnerAddress.AddressNumberForEdit,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      @ObjectModel.text.association: '_CountryText'
      BusinessPartnerAddress.Country as Country,
      @EndUserText.label: 'Address Validity Start Date'
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      BusinessPartnerAddress.AddressValidityStartDate,
      @EndUserText.label: 'Address Validity End Date'
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      BusinessPartnerAddress.AddressValidityEndDate,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      BusinessPartnerAddress.CareOfName,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      BusinessPartnerAddress.StreetPrefixName,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      BusinessPartnerAddress.AdditionalStreetPrefixName,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      BusinessPartnerAddress.HouseNumber,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      BusinessPartnerAddress.StreetName,
      @ObjectModel.enabled: true
      BusinessPartnerAddress.CustomerSupplierStreetName,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      BusinessPartnerAddress.HouseNumberSupplementText,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      BusinessPartnerAddress.StreetSuffixName,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      BusinessPartnerAddress.AdditionalStreetSuffixName,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      BusinessPartnerAddress.HomeCityName,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      BusinessPartnerAddress.District,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      BusinessPartnerAddress.PostalCode,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      BusinessPartnerAddress.CityName,
      @ObjectModel.enabled: true
      BusinessPartnerAddress.CustomerSupplierCityName,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      @ObjectModel.text.association: '_RegionText'
      BusinessPartnerAddress.Region,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      BusinessPartnerAddress.County,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      BusinessPartnerAddress.TownshipName,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      @ObjectModel.text.association: '_TimeZoneText'
      BusinessPartnerAddress.AddressTimeZone,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      @ObjectModel.text.association: '_TransportZoneText'
      BusinessPartnerAddress.TransportZone,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      @ObjectModel.enabled: 'EXTERNAL_CALCULATION'
      BusinessPartnerAddress.TaxJurisdiction,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      @ObjectModel.enabled: 'EXTERNAL_CALCULATION'
      BusinessPartnerAddress.TaxJurisdictionByProvider,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      BusinessPartnerAddress.CompanyPostalCode,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      BusinessPartnerAddress.DeliveryServiceTypeCode,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      BusinessPartnerAddress.DeliveryServiceNumber,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      BusinessPartnerAddress.POBox,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      BusinessPartnerAddress.POBoxIsWithoutNumber,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      BusinessPartnerAddress.POBoxPostalCode,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      BusinessPartnerAddress.POBoxLobbyName,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      BusinessPartnerAddress.POBoxDeviatingCityName,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      BusinessPartnerAddress.POBoxDeviatingRegion,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      BusinessPartnerAddress.POBoxDeviatingCountry,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      @ObjectModel.text.association: '_LanguageText'
      BusinessPartnerAddress.CorrespondenceLanguage,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      @ObjectModel.text.association: '_CommMethText'
      BusinessPartnerAddress.PrfrdCommMediumType,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      @ObjectModel.text.association: '_TelCountryText'
      BusinessPartnerAddress.PhoneNumberCountry,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      BusinessPartnerAddress.PhoneNumber,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      BusinessPartnerAddress.PhoneNumberExtension,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      @ObjectModel.text.association: '_MblCountryText'
      BusinessPartnerAddress.MobilePhoneCountry,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      BusinessPartnerAddress.MobilePhoneNumber,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      @ObjectModel.text.association: '_FaxCountryText'
      BusinessPartnerAddress.FaxCountry,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      BusinessPartnerAddress.FaxNumber,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      BusinessPartnerAddress.FaxNumberExtension,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'      
      BusinessPartnerAddress.EmailAddress,
      @ObjectModel.readOnly: true
      @Environment.sql.passValue: true
      BusinessPartnerAddress.StandardUsage,
      BusinessPartnerAddress.BPTargetAddressID,
      BusinessPartnerAddress.AddressMoveDate,
      
      //@ObjectModel.readOnly: true

      //BusinessPartnerAddress.FormattedAddress,

      @ObjectModel.virtualElement
      @ObjectModel.readOnly: true
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MD_FORMAT_ADDRESS_CALC_EXIT'
      cast( '                                        ' as abap.sstring( 260 )  ) as FormattedPostalAddressText,
      BusinessPartnerAddress.BPTargetAddressText,
      InternationalPhoneNumber,      
      BusinessPartnerAddress.URLFieldLength,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      BusinessPartnerAddress.WebsiteURL,
    


      @ObjectModel.association.type: [ #TO_COMPOSITION_ROOT , #TO_COMPOSITION_PARENT ]
      _BusinessPartnerSupplier,
      @ObjectModel.association.type: [ #TO_COMPOSITION_ROOT , #TO_COMPOSITION_PARENT ]
      _BusinessPartnerCustomer,
      @ObjectModel.association.type: [ #TO_COMPOSITION_ROOT , #TO_COMPOSITION_PARENT ]
      _BusinessPartner,
      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _BusinessPartnerAddrUsage,
      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _BPTelephoneNumber,
      //@ObjectModel.association.type: [#TO_COMPOSITION_CHILD]

      _BPStdTelephoneNumber,
      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _BPMobilePhoneNumber,
      //@ObjectModel.association.type: [#TO_COMPOSITION_CHILD]

      _BPStdMobilePhoneNumber,
      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _BPFaxNumber,
      //@ObjectModel.association.type: [#TO_COMPOSITION_CHILD]

      _BPStdFaxNumber,
      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _BPWebsiteURL,
      //@ObjectModel.association.type: [#TO_COMPOSITION_CHILD]

      _BPStdWebsiteURL,
      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _BPEmailAddress,
      //@ObjectModel.association.type: [#TO_COMPOSITION_CHILD]

      _BPStdEmailAddress,      
      _LanguageText,
      _CountryText,
      _RegionText,
      _CommMethText,
      _TelCountryText,
      _MblCountryText,
      _FaxCountryText,
      _TimeZoneText,
      _TransportZoneText,
      _BPProtectedAddress
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BUSINESSPARTNERADDRESSTP"
],
"ASSOCIATED":
[
"C_BPEMAILADDRESS",
"C_BPFAXNUMBER",
"C_BPLANGUAGETEXTVALUEHELP",
"C_BPMOBILEPHONENUMBER",
"C_BPTELEPHONENUMBER",
"C_BPWEBSITEURL",
"C_BUSINESSPARTNER",
"C_BUSINESSPARTNERADDRUSAGE",
"C_BUSINESSPARTNERCUSTOMER",
"C_BUSINESSPARTNERSUPPLIER",
"C_COMMMETHTEXTVHTEMP",
"C_COUNTRYTEXTVHTEMP",
"C_REGIONTEXTVHTEMP",
"C_TELCOUNTRYTEXTVHTEMP",
"I_BPPROTECTEDADDRESS",
"I_COUNTRY",
"I_TIMEZONETEXT",
"I_TRANSPORTATION_ZONE_TEXT"
],
"BASE":
[
"I_BUSINESSPARTNERADDRESSTP"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/