C_BusSolnOrdNetAmountSitn

@AbapCatalog.sqlViewName: 'CSOLENTPRJVALCHN'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true

@ClientHandling.algorithm: #SESSION_VARIABLE

@AccessControl: {
authorizationCheck: #CHECK,
personalData.blocking: #('TRANSACTIONAL_DATA')
}

@ObjectModel:{
  usageType: {
    dataClass: #TRANSACTIONAL,
    serviceQuality: #C,
    sizeCategory: #XL
  }
}

@ObjectModel.supportedCapabilities:[ #SITUATION_ANCHOR, #SITUATION_TRIGGER]

@VDM: {
  viewType: #CONSUMPTION,
  lifecycle.contract.type: #PUBLIC_LOCAL_API
}
@Metadata.ignorePropagatedAnnotations:true

/* Semantic key used for navigation */
@ObjectModel.semanticKey: ['BusinessSolutionOrder', 'BusinessSolutionOrderItem']
/* Unique key for situation */
@ObjectModel.uniqueIdField: 'BusSolnOrderItemCharUUID'

@EndUserText.label: 'Situation for project cost change'

/* 
    ***    Customer Project Amount Value Changed Situation
    ***    Anchor and Trigger are same for this situation
*/
define view C_BusSolnOrdNetAmountSitn
  as select from I_ServiceDocumentItemEnhcd as SolutionOrderProjectItem
  left outer to many join  I_ServiceDocumentEnhcd as _ServiceDocument on SolutionOrderProjectItem.ServiceDocument = _ServiceDocument.ServiceDocument  
                                                                  and SolutionOrderProjectItem.ServiceObjectType = _ServiceDocument.ServiceObjectType 
                                                                  
   left outer to many join  I_BusinessUser as _ResponsibleEmployee on _ServiceDocument.ResponsibleEmployee = _ResponsibleEmployee.BusinessPartner
                                                                   or SolutionOrderProjectItem.ResponsibleEmployee = _ResponsibleEmployee.BusinessPartner
{

      //Key fields

      @Consumption.hidden: true
  key SolutionOrderProjectItem.ServiceDocument as BusinessSolutionOrder,

      @Consumption.hidden: true
  key cast(ltrim(SolutionOrderProjectItem.ServiceDocumentItem, '0') as abap.numc( 6 )) as BusinessSolutionOrderItem,

      @UI.hidden: true
  key SolutionOrderProjectItem.ServiceObjectType,

      @UI.hidden: true
      SolutionOrderProjectItem.ServiceDocumentType,

      //Unique key for situation

      @Consumption.hidden: true
      @Semantics.uuid: true
      SolutionOrderProjectItem.ServiceDocumentItemCharUUID as BusSolnOrderItemCharUUID,

       //Employee responsible for notification/action

      @UI.hidden: true
      @EndUserText.label: 'Responsible Employee'
      _ResponsibleEmployee.UserID  as                      ResponsibleEmployeeUserID,

   
      // Sales Area and Related fields for authorization

      @UI.hidden: true
      @ObjectModel.foreignKey.association: '_SalesOrganization'
      SolutionOrderProjectItem.SalesOrganization,

      @UI.hidden: true
      @ObjectModel.foreignKey.association: '_DistributionChannel'
      SolutionOrderProjectItem.DistributionChannel,


      @UI.hidden: true
      @ObjectModel.foreignKey.association: '_Division'
      SolutionOrderProjectItem.Division,

      @UI.hidden: true
      @ObjectModel.foreignKey.association: '_SalesOffice'
      SolutionOrderProjectItem.SalesOffice,

      @UI.hidden: true
      @ObjectModel.foreignKey.association: '_SalesGroup'
      SolutionOrderProjectItem.SalesGroup,

      @UI.hidden: true
   
      @ObjectModel.foreignKey.association: '_SalesOfficeOrgUnit_2'
      SolutionOrderProjectItem.SalesOfficeOrgUnitID,

      @UI.hidden: true
  
      @ObjectModel.foreignKey.association: '_SalesOrganizationOrgUnit_2'
      SolutionOrderProjectItem.SalesOrganizationOrgUnitID,

      @UI.hidden: true
      
      @ObjectModel.foreignKey.association: '_SalesGroupOrgUnit_2'
      SolutionOrderProjectItem.SalesGroupOrgUnitID,

      @UI.hidden: true
      
      @ObjectModel.foreignKey.association: '_ServiceOrganizationOrgUnit_2'
      SolutionOrderProjectItem.ServiceOrganization,


     
      @UI.hidden:true
      _SalesOrganization,
      @UI.hidden:true
      _SalesOffice,
      @UI.hidden:true
      _SalesGroup,
      @UI.hidden:true
      _DistributionChannel,
      @UI.hidden:true
      _Division,
      @UI.hidden:true
      _SalesOrganizationOrgUnit_2,
      @UI.hidden:true
      _SalesOfficeOrgUnit_2,
      @UI.hidden:true
      _SalesGroupOrgUnit_2,
      @UI.hidden:true
      _ServiceOrganizationOrgUnit_2,
      @UI.hidden:true
      _ServiceDocument
    
}
where
  SolutionOrderProjectItem.ServiceDocumentItemObjectType = 'BUS2000193'
  and SolutionOrderProjectItem.ServiceDocumentItemIsReleased = 'X'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BUSINESSUSER",
"I_SERVICEDOCUMENTENHCD",
"I_SERVICEDOCUMENTITEMENHCD"
],
"ASSOCIATED":
[
"I_DISTRIBUTIONCHANNEL",
"I_DIVISION",
"I_SALESGROUP",
"I_SALESOFFICE",
"I_SALESORGANIZATION",
"I_SERVICEDOCUMENTENHCD",
"I_SRVCMGMTORGANIZATIONUNIT"
],
"BASE":
[
"I_SERVICEDOCUMENTITEMENHCD"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/