C_BillgDocToBePostedSituation

@VDM.viewType: #CONSUMPTION
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #MANDATORY
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel:{ usageType: { serviceQuality: #D, //#X

                            sizeCategory: #XL,
                            dataClass: #MIXED },

                semanticKey:  ['BillingDocument'],
                supportedCapabilities:  [ #SITUATION_ANCHOR,  #SITUATION_TRIGGER ]
}
@EndUserText.label: 'Billing Doc To Be Posted for Situation'
define view entity C_BillgDocToBePostedSituation
  as select from I_BillingDocument as BillingDocument
  association [0..1] to I_BillingDocumentPartner  as _BillingDocumentPartner  on  $projection.BillingDocument             = _BillingDocumentPartner.BillingDocument
                                                                              and _BillingDocumentPartner.PartnerFunction = 'RE'
  association [0..1] to I_BillingIssueTypeText    as _BillingIssueTypeText    on  $projection.BillingIssueType   = _BillingIssueTypeText.BillingIssueType
                                                                              and _BillingIssueTypeText.Language = $session.system_language
  association [0..1] to I_BillingDocumentTypeText as _BillingDocumentTypeText on  $projection.BillingDocumentType   = _BillingDocumentTypeText.BillingDocumentType
                                                                              and _BillingDocumentTypeText.Language = $session.system_language
  association [0..1] to I_SDDocumentCategoryText  as _SDDocumentCategoryText  on  $projection.SDDocumentCategory   = _SDDocumentCategoryText.SDDocumentCategory
                                                                              and _SDDocumentCategoryText.Language = $session.system_language
  association [0..1] to I_SalesOrganizationText  as _SalesOrganizationText  on  $projection.SalesOrganization   = _SalesOrganizationText.SalesOrganization
                                                                              and _SalesOrganizationText.Language = $session.system_language

{
        @Consumption.hidden: true
  key   BillingDocument.BillingDocument,

        @Consumption.valueHelpDefinition: [
          { entity:  { name:    'C_BillingDocumentTypeVH',
                       element: 'BillingDocumentType' }
          }]
        BillingDocument.BillingDocumentType,

        @Consumption.hidden: true
        _BillingDocumentTypeText.BillingDocumentTypeName,

        @Consumption.valueHelpDefinition: [
          { entity:  { name: 'I_SDDocumentCategory',
                       element: 'SDDocumentCategory' }
          }]
        BillingDocument.SDDocumentCategory,

        @Consumption.hidden: true
        _SDDocumentCategoryText.SDDocumentCategoryName,

        @Consumption.valueHelpDefinition: [
          { entity:  { name:    'C_SoldToValueHelp',
                       element: 'Customer' }
          }]
        BillingDocument.PayerParty,
        @Consumption.valueHelpDefinition: [
          { entity:  { name:    'C_SoldToValueHelp',
                       element: 'Customer' }
          }]
        BillingDocument.SoldToParty,

        @EndUserText: {
           label: 'Bill-to Party',
           quickInfo: 'Bill-to Party'
         }
        @Consumption.valueHelpDefinition: [
          { entity:  { name:    'C_SoldToValueHelp',
                       element: 'Customer' }
          }]
        _BillingDocumentPartner.Customer                           as BillToParty,

        @Semantics.amount.currencyCode: 'TransactionCurrency'
        BillingDocument.TotalNetAmount,

        @Consumption.valueHelpDefinition: [
          { entity:  { name:    'I_CurrencyStdVH',
                       element: 'Currency' }
          }]
        BillingDocument.TransactionCurrency,

        @Consumption.valueHelpDefinition: [
          { entity:  { name:    'C_SalesDocSalesOrganizationVH',
                       element: 'SalesOrganization' }
          }]
        BillingDocument.SalesOrganization,
        
        @Consumption.hidden: true
        _SalesOrganizationText.SalesOrganizationName,

        BillingDocument.BillingDocumentDate,

        @Consumption.valueHelpDefinition: [
          { entity:  { name:    'I_BillingIssueType',
                       element: 'BillingIssueType' }
          }]
        BillingDocument.BillingIssueType,

        @Consumption.hidden: true
        _BillingIssueTypeText.BillingIssueTypeName                 as BillingIssueTypeName,

        @Consumption.valueHelpDefinition: [
          { entity:  { name:    'I_CompanyCodeVH',
                       element: 'CompanyCode' }
          }]
        BillingDocument.CompanyCode,

        @UI.hidden:true
        BillingDocument.CreatedByUser,



        BillingDocument._TransactionCurrency,
        _BillingDocumentPartner,
        _BillingIssueTypeText,
        _BillingDocumentTypeText,
        _SDDocumentCategoryText

}
where
      BillingDocument.BillingDocumentIsTemporary is initial
  and BillingDocument.OverallBillingStatus       = 'B'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BILLINGDOCUMENT",
"I_BILLINGDOCUMENTPARTNER",
"I_BILLINGDOCUMENTTYPETEXT",
"I_BILLINGISSUETYPETEXT",
"I_SALESORGANIZATIONTEXT",
"I_SDDOCUMENTCATEGORYTEXT"
],
"ASSOCIATED":
[
"I_BILLINGDOCUMENTPARTNER",
"I_BILLINGDOCUMENTTYPETEXT",
"I_BILLINGISSUETYPETEXT",
"I_CURRENCY",
"I_SDDOCUMENTCATEGORYTEXT"
],
"BASE":
[
"I_BILLINGDOCUMENT"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/