C_BankTP

@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Consumption Bank TP'
@Metadata.allowExtensions: true

@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #L,
  dataClass: #MASTER
}

@AbapCatalog.extensibility: {
  extensible: true,
  elementSuffix: 'BNK',
  allowNewDatasources: true,
  dataSources: ['Bank'],
  quota: {
    maximumFields: 500,
    maximumBytes: 5000
  },
  allowNewCompositions: true
}


@VDM.viewType: #CONSUMPTION
@VDM.usage.type:[#TRANSACTIONAL_PROCESSING_SERVICE]
@Search.searchable: true

define root view entity C_BankTP
  provider contract transactional_query
  as projection on R_BankTP as Bank

  association [0..*] to C_BankChangeDocument as _BankChangeDocument on  $projection.BankCountry    = _BankChangeDocument.BankCountry
                                                                    and $projection.BankInternalID = _BankChangeDocument.BankInternalID
{
      @ObjectModel.text.element: [ 'BankCountryName' ]
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.95
      @Search.ranking: #HIGH
      @Consumption.valueHelpDefinition: [{ entity:  { name:  'C_BankCountryVH_2', element: 'BankCountry' } }]
  key BankCountry,

//      @ObjectModel.text.element: [ 'LongBankName' ]

      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.96
      @Search.ranking: #HIGH
      @Consumption.valueHelpDefinition: [{ entity: { name: 'C_BankInternalIDVH', element : 'BankInternalID' },
          additionalBinding : [ { localElement  : 'BankCountry',  element  : 'BankCountry' } ]
      }]
  key BankInternalID,

      @EndUserText.label: 'Bank Key (Bank Name)'
      BankKeyForDisplay,

      //@ObjectModel.mandatory: true

      //_BankAddress.LongBankName, // -> field is not editable.

        //Data from BankAddress

      @Consumption.valueHelpDefinition: [ { entity: { name: 'C_BankNameVH', element: 'BankName' },
          additionalBinding : [ { localElement  : 'BankCountry',  element  : 'BankCountry' } ]
      }]
      LongBankName,

      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.90
      @Search.ranking: #MEDIUM
      @Semantics.text: true
      @UI.hidden: true
      BankName,

      @Consumption.valueHelpDefinition: [{ entity: { name: 'C_BankBranchVH', element: 'BankBranch' },
        additionalBinding : [ { localElement  : 'BankCountry',  element  : 'BankCountry' } ]
      }]
      LongBankBranch,

      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.80
      @Search.ranking: #MEDIUM
      @Semantics.text: true
      @UI.hidden: true
      BankBranch,

      @ObjectModel.text.element: ['RegionName']
      @Consumption.valueHelpDefinition: [{ entity: { name: 'C_BankRegionVH',  element: 'Region' }
      }]
      AddressRegion, //char3     Fallback BNKA-REGION

      @UI.hidden: true
      Region,

      @Semantics.text: true
      StreetName, //char,   Fallback ShortStreetName = BNKA-STRAS,  Street

      CityName,   //char,   Fallback ShortCityName = BNKA-ORT01


      @UI.hidden: true
      ShortStreetName,

      @Semantics.text: true
      @UI.hidden: true
      ShortCityName,

      //@Consumption.hidden: true

      //      hasAddress, // JV 06122022

      @UI.hidden: true
      BankIsInternal,
      @UI.hidden: true
      BankIsStandard,
      @Consumption.valueHelpDefinition: [{ entity: { name: 'C_BankSwiftCodeVH_2',  element: 'SWIFTCode' },
          additionalBinding : [ { localElement  : 'BankCountry',  element  : 'BankCountry' } ]
      }]
      SWIFTCode,
      BankNetworkGrouping,
      IsMarkedForDeletion,

      //      @Consumption.valueHelpDefinition: [{ entity: { name: 'C_BankNumberVH_2',  element: 'Bank' },

      //          additionalBinding : [ { localElement  : 'BankCountry',  element  : 'BankCountry' } ]

      //      }]

      //      Bank,


      @Consumption.valueHelpDefinition: [{ entity: { name: 'C_BankNumberVH_2',  element: 'Bank' },
          additionalBinding : [ { localElement  : 'BankCountry',  element  : 'BankCountry' } ]
      }]
      BankNumber,

      @ObjectModel.text.element: ['BankCategoryDescription']
      @Consumption.valueHelpDefinition: [{ entity:{name: 'C_BankCategoryVH' } }]

      BankCategory,
      @UI.hidden: true
      BankCategoryDescription,
//      _BankCategory.BankCategoryDescription                                  as BankCategoryDescription, //: localized,

      //_BankCategory._Text.BankCategoryDescription as BankCategoryDescription: localized,


//      @Consumption.hidden: true

//      @Semantics.systemDateTime.localInstanceLastChangedAt: true

//      LocalLastChangedAt,

      //total ETag field

      @EndUserText.label: 'Created On'
      @Consumption.filter.selectionType: #INTERVAL
      @Semantics.systemDateTime.lastChangedAt: true
      LastChangeDateTime,
      @Consumption.hidden: true
      @Semantics.systemDate.createdAt: true
      CreationDate,

      @UI.hidden: true
      @Semantics.text: true
      _Country._Text[1:Language = $session.system_language].CountryShortName as BankCountryName,
      @UI.hidden: true
      @Semantics.text: true
      _Region._RegionText[1:Language = $session.system_language].RegionName  as RegionName,
      //_BankAddress._Region._RegionText[1:Language = $session.system_language].RegionName  as RegionName,


      @UI.hidden: true
      LongBankBranchIsHidden,
      @UI.hidden: true
      BankNumberIsHidden,
      @UI.hidden: true
      SWIFTCodeIsHidden,
      @UI.hidden: true
      BankNetworkGroupingIsHidden,
      @UI.hidden: true
      BankCategoryIsHidden,
      @UI.hidden: true
      BankAddressIsHidden,
      @UI.hidden: true
      BankScriptedAddressIsHidden,
//      @UI.hidden: true

//      UICT_HideScrpAddr,


      /* Associations */
      _BankChangeDocument,
      _BankCategory,
      _Country,

      _BankAddress : redirected to composition child C_BankAddressTP

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_COUNTRY",
"I_COUNTRYTEXT",
"I_REGION",
"I_REGIONTEXT",
"R_BANKTP"
],
"ASSOCIATED":
[
"C_BANKADDRESSTP",
"C_BANKCATEGORYVH",
"C_BANKCHANGEDOCUMENT",
"I_COUNTRY",
"R_BANKADDRESSTP"
],
"BASE":
[
"R_BANKTP"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/