C_BankBusinessPartnerVH

@AbapCatalog: {
  sqlViewName: 'CBANKBPVH',
  compiler.compareFilter: true
}

@ClientHandling: {
  type:      #CLIENT_DEPENDENT,
  algorithm: #SESSION_VARIABLE
}

@ObjectModel: {
  usageType: {
    serviceQuality: #C,
    sizeCategory:   #XL,
    dataClass:      #MASTER
  }
}
@AccessControl.authorizationCheck: #CHECK //#NOT_REQUIRED

@VDM.viewType: #CONSUMPTION
@EndUserText.label: 'Value Help for Bank Business Partner'
@Search.searchable: true
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED
@UI.headerInfo: {
  typeName:       'Business Partner',
  typeNamePlural: 'Business Partners',
  title:          { value: 'BusinessPartnerNumber' }
}
@ObjectModel.dataCategory:#VALUE_HELP
@Consumption.ranked: true
@Metadata.ignorePropagatedAnnotations: true
define view C_BankBusinessPartnerVH
  as select distinct from I_BusinessPartner_to_BP_Role as BP //I_BPBankLinkage

    inner join            but000                       as but000 on  BP.BusinessPartner =  but000.partner
                                                                 and but000.xdele       <> 'X'
  association [0..1] to I_BusinessPartnerVH as _BusinessPartnerVH on $projection.BusinessPartnerNumber = _BusinessPartnerVH.BusinessPartner

{
      @Search: {
      defaultSearchElement: true,
      ranking: #HIGH,
      fuzzinessThreshold: 0.8
      }
      @UI.lineItem: [
      { position: 1, importance: #HIGH, label: 'Business Partner Number' }
      ]   
      @ObjectModel.text.element: [ 'BusinessPartnerName' ] 
  key BP.BusinessPartner                             as BusinessPartnerNumber,
      @Search: {
        defaultSearchElement: true,
        ranking: #HIGH,
        fuzzinessThreshold: 0.8
      }
      @EndUserText.label: 'Business Partner Name'
      @UI.lineItem: [
      { position: 2, importance: #HIGH, label: 'Business Partner Name' }
      ]
      @Semantics.text: true     
      BP._BusinessPartner.OrganizationBPName1        as BusinessPartnerName,

      //CE2302:security-blocked business partner

      @Consumption.hidden: true
      BP.AuthorizationGroup                          as AuthorizationGroup,
      @Consumption.hidden: true
      @Semantics.booleanIndicator
      BP._BusinessPartner.IsBusinessPurposeCompleted as IsBusinessPurposeCompleted,
      @Consumption.hidden:true
      @UI.hidden:true
      BP._BusinessPartner.DataControllerSet          as DataControllerSet,
      @Consumption.hidden:true
      @UI.hidden:true
      BP._BusinessPartner.DataController1            as DataController1,
      @Consumption.hidden:true
      @UI.hidden:true
      BP._BusinessPartner.DataController2            as DataController2,
      @Consumption.hidden:true
      @UI.hidden:true
      BP._BusinessPartner.DataController3            as DataController3,
      @Consumption.hidden:true
      @UI.hidden:true
      BP._BusinessPartner.DataController4            as DataController4,
      @Consumption.hidden:true
      @UI.hidden:true
      BP._BusinessPartner.DataController5            as DataController5,
      @Consumption.hidden:true
      @UI.hidden:true
      BP._BusinessPartner.DataController6            as DataController6,
      @Consumption.hidden:true
      @UI.hidden:true
      BP._BusinessPartner.DataController7            as DataController7,
      @Consumption.hidden:true
      @UI.hidden:true
      BP._BusinessPartner.DataController8            as DataController8,
      @Consumption.hidden:true
      @UI.hidden:true
      BP._BusinessPartner.DataController9            as DataController9,
      @Consumption.hidden:true
      @UI.hidden:true
      BP._BusinessPartner.DataController10           as DataController10,
      _BusinessPartnerVH
}
where
  BP.BusinessPartnerRole = 'TR0703';
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BUSINESSPARTNER",
"I_BUSINESSPARTNER_TO_BP_ROLE",
"BUT000"
],
"ASSOCIATED":
[
"I_BUSINESSPARTNERVH"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/