C_BankAddressTP

@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Consumption Bank Address TP'
@Metadata.allowExtensions: true

@ObjectModel.usageType:{
  serviceQuality: #D,
  sizeCategory: #L,
  dataClass: #MASTER
}

@VDM.viewType: #CONSUMPTION

define view entity C_BankAddressTP
  as projection on R_BankAddressTP as BankAddress
{
  key BankCountry,
  key BankInternalID,

      //@Semantics.text: true

      //LongBankName,              //char80 ... it is exposed via case condition in C_BankTP

      //LongBankBranch,            //char80

      @Semantics.address.street: true
      StreetName,
      @Semantics.address.streetNoNumber: true
      HouseNumber,
      HouseNumberSupplementText,
      @Semantics.address.city: true
      CityName,
      /*@Consumption.valueHelpDefinition: [
        { entity:  { name:  'I_PostalCityVH',
                   element: 'PostalCode' }
        }] */
      @Semantics.address.zipCode: true
      PostalCode,
      @Semantics.address.country: true
      @ObjectModel.text.element: [ 'BankCountryName' ]
      @Consumption.valueHelpDefinition: [{ entity:  { name:  'I_CountryVH', element: 'Country' } }]
      Country,
      @ObjectModel.text.element: [ 'RegionName' ]
      @Consumption.valueHelpDefinition: [
      { entity : {name: 'I_RegionVH', element: 'Region'  },
        additionalBinding : [ { localElement  : 'Country',  element  : 'Country' } ]
      }]
      Region,

      @ObjectModel.text.element: ['LanguageName']
      @Consumption.valueHelpDefinition: [{ entity:  { name:  'I_Language', element: 'Language' } }]
      CorrespondenceLanguage,
      @UI.hidden: true
      _CorrespondenceLanguage._Text.LanguageName                                                        as LanguageName : localized,

      //AddressObjectType,


      //PrfrdCommMediumType,

      //AddresseeFullName,


      DistrictName,
      VillageName,
      CompanyPostalCode,
      StreetAddrNonDeliverableReason,
      StreetPrefixName1,
      StreetPrefixName2,
      StreetSuffixName1,
      StreetSuffixName2,
      Building,
      Floor,
      RoomNumber,

      FormOfAddress,

      TaxJurisdiction,
      TransportZone,
      
      AddressSearchTerm1,
      AddressSearchTerm2,

      POBox,
      POBoxAddrNonDeliverableReason,
      POBoxIsWithoutNumber,
      POBoxPostalCode,
      POBoxLobbyName,
      POBoxDeviatingCityName,
      POBoxDeviatingRegion,
      POBoxDeviatingCountry,
      CareOfName,
      DeliveryServiceTypeCode,
      DeliveryServiceNumber,
      AddressTimeZone,
      SecondaryRegionName,
      TertiaryRegionName,

      //@ObjectModel.text.association: '_AddressRepresentationCode._Text'

      @Consumption.valueHelpDefinition: [{ entity : {name: 'I_ActiveAddressRepresentation', element: 'AddressRepresentationCode'  } }]//C_BankAddressRepCodeVH

      @ObjectModel.text.element: ['AddressCodeDesc']
      AddressRepresentationCode, //is always empty


      @UI.hidden: true
      @Semantics.text: true
      _AddressRepresentationCode._Text[1:Language = $session.system_language].AddressRepresentationDesc as AddressCodeDesc,

      AddressID,

      // Telephone

      
      @Consumption.valueHelpDefinition: [{ entity: {name: 'I_BusPartTelCountryPrefix',element: 'Country' },
        additionalBinding: [
             {element: 'TelephoneCountryPrefix',localElement:'TelephoneCountryPrefix',usage: #RESULT}
        ]
      }]
      PhoneNumberCountry,
      PhoneNumber,
      PhoneExtensionNumber,
      InternationalPhoneNumber, //Complete Number: Dialing Code+Number+Extension

      _TelCountryPrefix.TelephoneCountryPrefix,
      
      // Mobile Phone

      MobilePhoneCountry,
      MobilePhoneNumber,
      @Semantics.telephone.type: [#PREF]
      InternationalMobilePhoneNumber,

      // Fax

      FaxNumberCountry,
      FaxAreaCodeSubscriberNumber,
      FaxExtensionNumber,
      InternationalFaxNumber,

      // E-mail

//      @Semantics.eMail.address

      EmailAddress,

      // URL

      //      UniformResourceIdentifier,


      @UI.hidden: true
      @Semantics.text: true
      _Country._Text[1:Language = $session.system_language].CountryShortName                            as BankCountryName,

      @UI.hidden: true
      @Semantics.text: true
      _Region._RegionText[1:Language = $session.system_language].RegionName                             as RegionName, //INS DK01


      /* Associations */
      BankAddress._Bank              : redirected to parent C_BankTP,
      BankAddress._BankScriptVariant : redirected to composition child C_BankScriptedAddressTP,

      _Country,
      _FormOfAddress,
      _Region
      //      _AddressRepresentationCode

      //      _Language

      //      _CorrespondenceLanguage


}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ADDRESSREPRESENTATION",
"I_ADDRESSREPRESENTATIONTEXT",
"I_BUSPARTTELCOUNTRYPREFIX",
"I_COUNTRY",
"I_COUNTRYTEXT",
"I_LANGUAGE",
"I_LANGUAGETEXT",
"I_REGION",
"I_REGIONTEXT",
"R_BANKADDRESSTP"
],
"ASSOCIATED":
[
"C_BANKSCRIPTEDADDRESSTP",
"C_BANKTP",
"I_COUNTRY",
"I_FORMOFADDRESS",
"I_REGION",
"R_BANKSCRIPTEDADDRESSTP",
"R_BANKTP"
],
"BASE":
[
"R_BANKADDRESSTP"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/