C_BPEmplWorkplaceAddr

@AbapCatalog.sqlViewName: 'CBPEMPWORKADDR'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Business Partner Employee Workplace address'
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #CONSUMPTION
@AccessControl.personalData.blocking: #REQUIRED
@Metadata.allowExtensions: true
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel: {
    semanticKey: ['BusinessPartner'],
    createEnabled,
    updateEnabled,
    deleteEnabled
}
@Search.searchable: true
define view C_BPEmplWorkplaceAddr
  as select from I_BPEmplWorkplaceAddrTP
  
  association [1..1] to C_BusinessPartner   as _BusinessPartner on  $projection.BusinessPartner = _BusinessPartner.BusinessPartner
 
  association [0..*] to C_Countrytextvhtemp as _CountryText     on  $projection.Country = _CountryText.Country
  association [1..*] to C_RegionTextVHTemp  as _RegionText      on  $projection.Country = _RegionText.Country
                                                                and $projection.Region  = _RegionText.Region
  association [0..*] to I_TimeZoneText      as _TimeZoneText    on  $projection.AddressTimeZone = _TimeZoneText.TimeZoneID

  association [0..1] to I_TimeZone          as _TimeZone        on  $projection.AddressTimeZone = _TimeZone.TimeZoneID
  association [0..1] to I_Region            as _Region          on  $projection.Region  = _Region.Region
                                                                and $projection.Country = _Region.Country
  association [0..1] to I_Country           as _Country         on  $projection.Country = _Country.Country

{
  key     BusinessPartner,
          BusinessPartnerUUID,
          AddressID,
          AddressPersonID,
          StreetName,
          HouseNumber,
          @ObjectModel.text.association: '_TimeZoneText'
          @ObjectModel.foreignKey.association: '_TimeZone'
          AddressTimeZone,
          CityName,
          @ObjectModel.foreignKey.association: '_Country'
          @ObjectModel.text.association: '_CountryText'
          Country,
          @ObjectModel.text.association: '_RegionText'
          @ObjectModel.foreignKey.association: '_Region'
          Region,
          PostalCode,
          EmailAddress,
          InternationalPhoneNumber,
          InternationalFaxNumber,
          InternationalMobilePhoneNumber,
          WorkplaceBuilding,
          WorkplaceFloor,
          WorkplaceDepartmentName,
          WorkplaceFunctionalTitleName,
          WorkplaceRoomNumber,
          @Consumption.filter.hidden : true
          AuthorizationGroup,
          IsBusinessPurposeCompleted,

          _PersonWPAddr,
          @ObjectModel.association.type: [#TO_COMPOSITION_ROOT, #TO_COMPOSITION_PARENT]
           _BusinessPartner,
          _CountryText,
          _RegionText,
          _TimeZoneText,
          _TimeZone,
          _Region,
          _Country
          
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BPEMPLWORKPLACEADDRTP"
],
"ASSOCIATED":
[
"C_BUSINESSPARTNER",
"C_COUNTRYTEXTVHTEMP",
"C_REGIONTEXTVHTEMP",
"I_COUNTRY",
"I_PERSONWORKPLACEADDRESS",
"I_REGION",
"I_TIMEZONE",
"I_TIMEZONETEXT"
],
"BASE":
[
"I_BPEMPLWORKPLACEADDRTP"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/