@AbapCatalog.sqlViewName: 'CBOMCREATE'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@VDM.viewType: #CONSUMPTION
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Consumption view for Create BOM scenario'
@ObjectModel.usageType: {serviceQuality: #X, sizeCategory: #XL,dataClass:#MIXED}
@ObjectModel.action: [{enabled: true}]
//@Search.searchable: true
@ObjectModel.updateEnabled: true
@ClientHandling.algorithm : #SESSION_VARIABLE
define view C_BOMCreateForUI as select from I_BOMModificationParameters
{
@UI.hidden: true
key BOMApplicationArea,
@UI.hidden: true
key cast(' ' as char8 preserving type ) as BillOfMaterial,
@UI.hidden: true
key cast(' ' as stlty preserving type ) as BillOfMaterialCategory,
@EndUserText.label:'Selected Alternative'
key cast(' ' as stlal preserving type ) as BillOfMaterialVariant,
@EndUserText.label:'Version'
key cast(' ' as cs_versn preserving type ) as BillOfMaterialVersion,
@Consumption.valueHelpDefinition: [
{ entity: { name: 'I_CHANGEMASTERSTDVH',
element: 'ChangeNumber' }
}]
@EndUserText.label:'Change Number'
key cast(' ' as aennr preserving type ) as EngineeringChangeDocument,
@Consumption.valueHelpDefinition: [
{ entity: { name: 'C_BOMMaterialVH',
element: 'Material' }
}]
@EndUserText.label:'Material'
key cast(' ' as matnr preserving type) as Material,
@Consumption.valueHelpDefinition: [
{ entity: { name: 'I_PlantStdVH',
element: 'Plant' }
}]
@EndUserText.label:'Plant'
key cast(' ' as werks_d preserving type ) as Plant,
@EndUserText.label:'BOM Usage'
@Consumption.valueHelpDefinition: [
{ entity: { name: 'I_BillOfMaterialUsage',
element: 'BillOfMaterialVariantUsage' }
}]
@UI.textArrangement: #TEXT_LAST
@ObjectModel.text.element: [ 'BillOfMaterialVariantUsageDesc' ]
cast(' ' as stlan preserving type ) as BillOfMaterialVariantUsage,
@Semantics.text: true
cast(' ' as antxt ) as BillOfMaterialVariantUsageDesc,
@EndUserText.label:'Alternative'
cast(' ' as stlal preserving type ) as BillOfMaterialVariantForEdit,
@Consumption.valueHelpDefinition: [
{ entity: { name: 'I_CHANGEMASTERSTDVH',
element: 'ChangeNumber' }
}]
@EndUserText.label:'Change Number'
cast(' ' as aennr preserving type ) as EngineeringChangeDocForEdit,
@Consumption.valueHelpDefinition: [
{ entity: { name: 'I_PlantStdVH',
element: 'Plant' }
}]
@EndUserText.label:'Plant'
cast(' ' as werks_d preserving type ) as PlantForEdit,
@EndUserText.label:'Valid From'
$session.system_date as HeaderValidityStartDate,
@Consumption.valueHelpDefinition: [
{ distinctValues: true,
entity: { name: 'C_MngUnassgdEngBOMChgRecd',
element: 'ChangeRecord' }
}]
@UI.hidden: true
cast(' ' as /plmb/cr_id preserving type) as ChangeRecord,
@EndUserText.label:'Copy Items'
cast('X' as boolean preserving type) as BOMComponentCopyIsRequired
}
union all select from P_BillOfMaterialHeader as bomBO
association [1..1] to I_BillOfMaterialUsage as _BillOfMaterialVariantUsage on $projection.BillOfMaterialVariantUsage = _BillOfMaterialVariantUsage.BillOfMaterialVariantUsage
and _BillOfMaterialVariantUsage.Language = $session.system_language
{
@UI.hidden: true
key cast(' ' as agb29 preserving type ) as BOMApplicationArea,
@UI.hidden: true
key cast(bomBO.BillOfMaterial as char8 preserving type ) as BillOfMaterial,
@UI.hidden: true
key bomBO.BillOfMaterialCategory,
@EndUserText.label:'Selected Alternative'
key bomBO.BillOfMaterialVariant,
@EndUserText.label:'Version'
key bomBO.BillOfMaterialVersion,
@Consumption.valueHelpDefinition: [
{ entity: { name: 'I_CHANGEMASTERSTDVH',
element: 'ChangeNumber' }
}]
@EndUserText.label:'Change Number'
key bomBO.EngineeringChangeDocument,
@Consumption.valueHelpDefinition: [
{ entity: { name: 'C_BOMMaterialVH',
element: 'Material' }
}]
@EndUserText.label:'Material'
key bomBO.Material,
@Consumption.valueHelpDefinition: [
{ entity: { name: 'I_PlantStdVH',
element: 'Plant' }
}]
@EndUserText.label:'Plant'
key bomBO.Plant,
@EndUserText.label:'BOM Usage'
@Consumption.valueHelpDefinition: [
{ entity: { name: 'I_BillOfMaterialUsage',
element: 'BillOfMaterialVariantUsage' }
}]
@ObjectModel.text.element: [ 'BillOfMaterialVariantUsageDesc' ]
@UI.textArrangement: #TEXT_LAST
bomBO.BillOfMaterialVariantUsage,
@Semantics.text: true
_BillOfMaterialVariantUsage.BillOfMaterialVariantUsageDesc,
@EndUserText.label:'Alternative'
cast(' ' as stlal preserving type ) as BillOfMaterialVariantForEdit,
@Consumption.valueHelpDefinition: [
{ entity: { name: 'I_CHANGEMASTERSTDVH',
element: 'ChangeNumber' }
}]
@EndUserText.label:'Change Number'
cast(' ' as aennr preserving type ) as EngineeringChangeDocForEdit,
@Consumption.valueHelpDefinition: [
{ entity: { name: 'I_PlantStdVH',
element: 'Plant' }
}]
@EndUserText.label:'Plant'
cast(' ' as werks_d preserving type ) as PlantForEdit,
@EndUserText.label:'Valid From'
$session.system_date as HeaderValidityStartDate,
@Consumption.valueHelpDefinition: [
{ distinctValues: true,
entity: { name: 'C_MngUnassgdEngBOMChgRecd',
element: 'ChangeRecord' }
}]
@UI.hidden: true
cast(' ' as /plmb/cr_id preserving type) as ChangeRecord,
@EndUserText.label:'Copy Items'
cast('X' as boolean preserving type) as BOMComponentCopyIsRequired
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BILLOFMATERIALUSAGE",
"I_BOMMODIFICATIONPARAMETERS",
"P_BILLOFMATERIALHEADER"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/