C_BE_TaxReturnBoxCube

@AbapCatalog.sqlViewName: 'CBETAXRETURNBOXC'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'ATR enabled tax Items for BE VAT Return'
@VDM.viewType: #CONSUMPTION
@Analytics: { dataCategory: #CUBE }
@Analytics.internalName: #LOCAL
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.serviceQuality: #X
@ObjectModel.usageType.dataClass: #MIXED
@AccessControl.personalData.blocking:#BLOCKED_DATA_INCLUDED
@Metadata.allowExtensions: true
@AbapCatalog.preserveKey: true


define view C_BE_TaxReturnBoxCube
   with parameters
    P_StatryRptgEntity  : srf_reporting_entity,
    P_StatryRptCategory : srf_rep_cat_id,
    P_StatryRptRunID    : srf_report_run_id,
    P_ReportingCountry  : land1
  as select from    I_StRpTaxReturnBoxCube( P_TaxIsDeferredRelevant : 'N',
                                            P_TaxIsMossRelevant     : 'N',
                                            P_StatryRptgEntity      : $parameters.P_StatryRptgEntity ,
                                            P_StatryRptCategory     : $parameters.P_StatryRptCategory,
                                            P_StatryRptRunID        : $parameters.P_StatryRptRunID,
                                            P_ReportingCountry      : $parameters.P_ReportingCountry,
                                            P_TaxBoxConfiguration   : '1'
                                           ) 
    
 left outer to one join P_CompanyCodeDetailsPA on I_StRpTaxReturnBoxCube.CompanyCode = P_CompanyCodeDetailsPA.CompanyCode
                                              and I_StRpTaxReturnBoxCube.Country = P_CompanyCodeDetailsPA.Country
                                               
{
  key I_StRpTaxReturnBoxCube.CompanyCode,
  key AccountingDocument,
  key FiscalYear,
  key TaxItem,
  key TransactionTypeDetermination,
  key DebitCreditCode,
  key AccountingDocumentType,
  key SupplierAccountGroup,
  
  key case when UnifiedTaxBoxStructureType = ' '
           and TaxBox = '10' then '00'
           else TaxBox
           end as TaxBox,  
             
  key TaxDeclnAmountType,
  key TaxBoxStrucValidityStartDate as ValidityStartDate,    
  key case when UnifiedTaxBoxStructureType = ' '
           then 'F625'
           else UnifiedTaxBoxStructureType
           end as UnifiedTaxBoxStructureType,
  key  TaxGroup,
  key  TaxItemGrpgDebitCreditCode,
  key  TaxItemGrpgAcctgDocumentType,
  key  TaxItemGrpgSupplierAcctGroup,
  key  TaxItemGrpgSpecialGLCode,                  
  key  StatryRptgEntity,
  key  StatryRptCategory,
  key  StatryRptRunID,
       
      I_StRpTaxReturnBoxCube.Country,
      cast(P_CompanyCodeDetailsPA.VATRegistration as glo_company_vatreg preserving type) as CompanyVATRegistration,
      TaxCode,
      TaxItemGroupingVersion,
      TaxBoxStructureType,
      TaxBoxStrucValidityEndDate as ValidityEndDate,     
 
      TaxCalculationProcedure,
      TaxRate,     
      TaxRateValidityStartDate,      
      GLAccount,
      TaxItemGroup,
      ReferenceDocumentType,
      PostingDate,
      DocumentDate,
      TaxReportingDate,
      ReportingDate,
      FiscalPeriod,
      CompanyCodeCountry,
      ReportingCountry,
      TaxReturnCountry,
      @Semantics.currencyCode:true
      CompanyCodeCurrency,
      @Semantics.currencyCode:true
      DocumentCurrency,
      @Semantics.currencyCode:true
      ReportingCurrency,
      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'ReportingCurrency'
      AmountInReportingCurrency,
      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'ReportingCurrency'
      TaxBaseAmountInRptgCrcy,
      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'ReportingCurrency'
      TaxAmountInRptgCrcy,     
      @DefaultAggregation:#SUM                                  
      @Semantics.amount.currencyCode: 'ReportingCurrency'       
      NonDeductibleInputTaxAmount,                           
      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      TaxBaseAmountInCoCodeCrcy,
      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      TaxAmountInCoCodeCrcy,
      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'DocumentCurrency'
      TaxBaseAmountInTransCrcy,
      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'DocumentCurrency'
      TaxAmount,         
      TaxType,
      TargetTaxCode,
      CAReconciliationKey,
      StatryRptRun,
      TaxTypeName,
      TaxIsNotDeductible,
      TaxBoxStructure,
      TaxBoxStructureName,
      TaxBoxName,
      TaxBoxCondition,
      _TaxTypeText 
                     
}
 where IsVATRelevant = 'X' 
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_STRPTAXRETURNBOXCUBE",
"P_COMPANYCODEDETAILSPA"
],
"ASSOCIATED":
[
"I_TAXTYPETEXT"
],
"BASE":
[
"I_STRPTAXRETURNBOXCUBE"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/