C_BE_DomesticSalesListCube

@EndUserText.label: 'Domestic Sales List for Belgium'
@AbapCatalog.sqlViewName: 'CBEDOMSLSLSTCUBE'
@VDM.viewType: #CONSUMPTION
@Analytics.dataCategory: #CUBE
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #BLOCKED_DATA_INCLUDED
@ClientHandling: { type: #INHERITED, algorithm: #SESSION_VARIABLE }
@ObjectModel.usageType: { dataClass: #MIXED, sizeCategory: #XL, serviceQuality: #X }
@Metadata.ignorePropagatedAnnotations: true
@Metadata.allowExtensions: true

////////////////////////////////////////////////////////////////////////////////

// This Cube publishes a specific Domestic Sales List for Belgium.

////////////////////////////////////////////////////////////////////////////////


define view C_BE_DomesticSalesListCube
  as select from    P_BE_DomesticSalesList20 as sl
    left outer join I_StRpJournalEntryLog    as log_fi   on  sl.CompanyCode        = log_fi.CompanyCode
                                                         and sl.AccountingDocument = log_fi.AccountingDocument
                                                         and sl.FiscalYear         = log_fi.FiscalYear
                                                         and sl.DOCSource          = 'FI'
    left outer join I_CAStRepLog             as log_fica on  sl.CompanyCode      = log_fica.CompanyCode
                                                         and sl.CADocumentNumber = log_fica.CADocumentNumber
                                                         and sl.FiscalYear       = log_fica.FiscalYear
                                                         and sl.DOCSource        = 'CA'

{
  key   sl.CompanyCode,
  key   sl.FiscalYear,
  key   sl.AccountingDocument,
  key   sl.CADocumentNumber,
  key   sl.TaxCode,
  key   sl.TransactionTypeDetermination,
        @Semantics.currencyCode: true
  key   cast(sl.ReportingCurrency as waers)                                   as ReportingCurrency,

  key
        case
          when log_fi.StatryRptCategory is null
            then log_fica.StatryRptCategory
          else log_fi.StatryRptCategory
        end                                                                   as StatryRptCategory,

  key
        case
          when log_fi.StatryRptgEntity is null
            then log_fica.StatryRptgEntity
          else log_fi.StatryRptgEntity
        end                                                                   as StatryRptgEntity,


  key
        case
          when log_fi.StatryRptRunID is null
            then log_fica.StatryRptRunID
          else log_fi.StatryRptRunID
        end  
                                                                              as StatryRptRunID,
        
        cast(min(sl.BusinessPartner) as bu_partner preserving type)           as BusinessPartner,
        cast(min(sl.BusinessPartnerName) as bp_name_ca preserving type)       as BusinessPartnerName,                                                   
        @DefaultAggregation:#SUM
        @Semantics.amount.currencyCode: 'ReportingCurrency'
        cast(sum(sl.TaxBaseAmountInRptgCrcy) as glo_taxbase_amount_rptg_crcy) as TaxBaseAmountInRptgCrcy,
        @DefaultAggregation:#SUM
        @Semantics.amount.currencyCode: 'ReportingCurrency'
        cast(sum(sl.TaxAmountInRptgCrcy) as glo_tax_amount_rptg_crcy)         as TaxAmountInRptgCrcy,

        cast(min(sl.PostingDate) as fis_budat)                                as PostingDate,
        cast(min(sl.TaxReportingDate) as vatdate)                             as TaxReportingDate,
        cast(min(sl.ReportingDate) as glo_reporting_date)                     as ReportingDate,
        cast(min(sl.Debtor) as kunnr)                                         as Debtor,
        cast(min(sl.Creditor) as lifnr)                                       as Creditor,
        cast(min(sl.Country) as land1_gp)                                     as Country, // Country of supplier / customer

        cast(min(sl.IsOneTimeAccount) as xcpdk)                               as IsOneTimeAccount,
        cast(min(sl.BPTaxNumber) as bptaxnum)                                 as BPTaxNumber
}
group by
  sl.CompanyCode,
  sl.FiscalYear,
  sl.AccountingDocument,
  sl.CADocumentNumber,
  sl.TaxCode,
  sl.TransactionTypeDetermination,
  sl.ReportingCurrency,
  log_fi.StatryRptCategory,
  log_fica.StatryRptCategory,
  log_fi.StatryRptgEntity,
  log_fica.StatryRptgEntity,
  log_fi.StatryRptRunID,
  log_fica.StatryRptRunID
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CASTREPLOG",
"I_STRPJOURNALENTRYLOG",
"P_BE_DOMESTICSALESLIST20"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/