C_Arberp_Address

@AbapCatalog.sqlViewName: 'CARB_ADDRESS'
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #PRIVILEGED_ONLY
@EndUserText.label: 'CDS View for Addresses'
@VDM.viewType: #CONSUMPTION
  @ObjectModel.usageType.serviceQuality: #C
  @ObjectModel.usageType.sizeCategory: #L
  @ObjectModel.usageType.dataClass: #MASTER
define view C_Arberp_Address as select from I_Address_2 as I_Address 
left outer join I_AddressPhoneNumber_2 as _TMP_DefaultPhoneNumber
         on _TMP_DefaultPhoneNumber.AddressID     = I_Address.AddressID 
        and _TMP_DefaultPhoneNumber.AddressPersonID =  I_Address.AddressPersonID
        and _TMP_DefaultPhoneNumber.PhoneNumberType = '1'
left outer join t005k as _WORKARROUND_PhoneDialCode on _WORKARROUND_PhoneDialCode.land1 = _TMP_DefaultPhoneNumber.PhoneNumberCountry

left outer join I_AddressFaxNumber_2        as _WORKARROUND_DefaultFaxNumber
         on _WORKARROUND_DefaultFaxNumber.AddressID     =  I_Address.AddressID 
        and _WORKARROUND_DefaultFaxNumber.AddressPersonID        =  I_Address.AddressPersonID
        and _WORKARROUND_DefaultFaxNumber.FaxNumberIsCurrentDefault = 'X'
left outer join t005k as _WORKARROUND_FaxDialCode on _WORKARROUND_FaxDialCode.land1 = _WORKARROUND_DefaultFaxNumber.FaxNumberCountry

association [0..*] to I_RegionText as _RegionText on _RegionText.Region = I_Address.Region and _RegionText.Country = I_Address.Country
// association [0..*] to I_RegionText as _RegionText on _RegionText.Region = I_Address.Region

association [0..*] to I_CountryText as _CountryText on _CountryText.Country = I_Address.Country 
                                 


{
 key I_Address.AddressID, 
    I_Address.AddresseeFullName as FullName, 
  I_Address.CareOfName, 
  I_Address.CityName,
  I_Address.PostalCode,
  I_Address.StreetName,
  I_Address.HouseNumber, 
  I_Address.HouseNumberSupplementText,
  I_Address.Building, 
  I_Address.Floor, 
  I_Address.Country, 
  I_Address.CorrespondenceLanguage,
     coalesce (_CountryText[1: Language = $projection.CorrespondenceLanguage].CountryName,
        _CountryText[1: Language = 'E'].CountryName) as CountryName,
    coalesce (_CountryText[1: Language = $projection.CorrespondenceLanguage].Language,
        _CountryText[1: Language = 'E'].Language) as Language,
     I_Address.Region, 
    coalesce (_RegionText[1: Language = $projection.CorrespondenceLanguage].RegionName,
        _RegionText[1: Language = 'E'].RegionName) as RegionName,
    coalesce (_RegionText[1: Language = $projection.CorrespondenceLanguage].Language,
        _RegionText[1: Language = 'E'].Language) as TranslationLanguage,
    
  _CurrentDfltLandlinePhoneNmbr.InternationalPhoneNumber,
  _CurrentDfltLandlinePhoneNmbr.PhoneNumberCountry as DestinationLocationCountry,
 _WORKARROUND_PhoneDialCode.telefto as CountryDialingCode,
  _CurrentDfltFaxNumber.InternationalFaxNumber,
  _CurrentDfltFaxNumber.FaxNumberCountry as FaxCountry,
  _WORKARROUND_FaxDialCode.telefto as FaxCountryDialingCode,
  _CurrentDfltEmailAddress.EmailAddress,
  I_Address.RoomNumber
  
  
}  where I_Address.AddressRepresentationCode = ' '  //same as in I_Address                

  
  
 /*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ADDRCURDEFAULTEMAILADDRESS",
"I_ADDRCURDEFAULTFAXNUMBER",
"I_ADDRCURDFLTLANDLINEPHONENMBR",
"I_ADDRESSFAXNUMBER_2",
"I_ADDRESSPHONENUMBER_2",
"I_ADDRESS_2",
"I_COUNTRYTEXT",
"I_REGIONTEXT",
"T005K"
],
"ASSOCIATED":
[
"I_COUNTRYTEXT",
"I_REGIONTEXT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/