C_AllocationFieldGroupVH

@AbapCatalog.sqlViewName: 'CALLOCFDGRVH'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Allocation Field Group Value Help'

@VDM.viewType: #CONSUMPTION

@ObjectModel.usageType.sizeCategory: #S
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.dataClass: #CUSTOMIZING
@ClientHandling.algorithm: #SESSION_VARIABLE
//@ObjectModel.dataCategory: #VALUE_HELP



@Search.searchable: true

@ObjectModel.representativeKey: 'AllocationFieldGroup'
define view C_AllocationFieldGroupVH
  as select from I_AllocationFieldGroup
    inner join   I_AllocationContextType as Context on Context.AllocationType = I_AllocationFieldGroup.AllocationType

  association [1..1] to I_AllocationFieldGroupText   as _Text                    on  $projection.AllocationType       = _Text.AllocationType
                                                                                 and $projection.AllocationFieldGroup = _Text.AllocationFieldGroup
                                                                                 and _Text.Language                   = $session.system_language

  association [0..*] to I_AllocActualPlanVariantText as _ActualPlanText          on  $projection.AllocFldActlPlnVarValue = _ActualPlanText.AllocationActualPlanVariant

  association [0..1] to C_AllocFieldGroupInformation as _AllocFieldGroupInfo     on  $projection.AllocationType              = _AllocFieldGroupInfo.AllocationType
                                                                                 and $projection.AllocationPostingType       = _AllocFieldGroupInfo.AllocationPostingType
                                                                                 and $projection.AllocationActualPlanVariant = _AllocFieldGroupInfo.AllocationActualPlanVariant
                                                                                 and $projection.AllocationFieldGroup        = _AllocFieldGroupInfo.AllocationFieldGroup

  association [0..*] to C_AllocFldGrpExtnDataField   as _ExtnAllocFieldGroupInfo on  $projection.AllocationType              = _ExtnAllocFieldGroupInfo.AllocationType
                                                                                 and $projection.AllocationPostingType       = _ExtnAllocFieldGroupInfo.AllocationPostingType
                                                                                 and $projection.AllocationActualPlanVariant = _ExtnAllocFieldGroupInfo.AllocationActualPlanVariant

{
//      @UI.hidden: true

  key I_AllocationFieldGroup.AllocationType,
//      @UI.hidden: true

  key AllocationPostingType,
//      @UI.hidden: true

  key AllocationActualPlanVariant,
      @ObjectModel.text.element: ['AllocFieldGroupRowText']
      @Consumption.labelElement: 'AllocFieldGroupRowText'
      @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.6 }
  key AllocationFieldGroup,
      AllocVariablePortingType,
      @ObjectModel.text.element: ['AllocActualPlanVariantText']
      @Consumption.labelElement: 'AllocActualPlanVariantText'
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_AllocActlPlnVarVH', element: 'AllocFldActlPlnVarValue'  } } ]
      AllocFldActlPlnVarValue,

      cast('' as fis_bukrs)          as CompanyCode,

      cast('' as fis_rldnr)          as Ledger,

      cast('' as fco_alloc_template) as TopDwnDistrTmplName,

      //    AllocVariablePortingType,

      @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8 }
      _Text[1:Language = $session.system_language].AllocFieldGroupRowText,
      //@UI.hidden: true

      @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8 }
      _Text[1:Language = $session.system_language].AllocFieldGroupColumnText,

      @ObjectModel.readOnly: true
      _ActualPlanText[1:Language = $session.system_language].AllocActualPlanVariantText,

      @Consumption.filter.hidden: true
      @UI.selectionField: [{exclude: true}]  
      _AllocFieldGroupInfo,
      @Consumption.filter.hidden: true
      @UI.selectionField: [{exclude: true}]
      _ExtnAllocFieldGroupInfo
}
//where _Text.Language = $session.system_language

//where AllocationType = 'ACDOCA'

where
     AllocVariablePortingType is not null
  or AllocVariablePortingType <> '999'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ALLOCACTUALPLANVARIANTTEXT",
"I_ALLOCATIONCONTEXTTYPE",
"I_ALLOCATIONFIELDGROUP",
"I_ALLOCATIONFIELDGROUPTEXT"
],
"ASSOCIATED":
[
"C_ALLOCFIELDGROUPINFORMATION",
"C_ALLOCFLDGRPEXTNDATAFIELD",
"I_ALLOCACTUALPLANVARIANTTEXT",
"I_ALLOCATIONFIELDGROUPTEXT"
],
"BASE":
[],
"ANNO_REF":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/