C_AR_StRpVATPrintSlsJrnlEntrC

@AbapCatalog.sqlViewName: 'CARSTRPVTPRTSLSC'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #MANDATORY
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.dataClass: #MIXED
@VDM.viewType: #CONSUMPTION
@Analytics: { dataCategory: #CUBE }
@Analytics.internalName: #LOCAL
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.personalData.blocking: #BLOCKED_DATA_INCLUDED
@EndUserText.label: 'Argentina VAT Print Sales - Cube'
@Metadata.allowExtensions:true

define view C_AR_StRpVATPrintSlsJrnlEntrC
  as select from           P_AR_VATPrintSalesDetail as VATPrintSalesDetail
    inner join             I_StRpJournalEntryLog          as StRpJournalEntryLog    on  StRpJournalEntryLog.CompanyCode        = VATPrintSalesDetail.CompanyCode
                                                                                    and StRpJournalEntryLog.FiscalYear         = VATPrintSalesDetail.FiscalYear
                                                                                    and StRpJournalEntryLog.AccountingDocument = VATPrintSalesDetail.AccountingDocument

    left outer to one join I_Ar_FrgnNatlTxCode            as ForeignNationalTaxCode on  ForeignNationalTaxCode.Country                  = VATPrintSalesDetail.BusinessPartnerCountry
                                                                                    and ForeignNationalTaxCode.NFPartnerIsNaturalPerson = VATPrintSalesDetail.IsNaturalPerson

{
  key VATPrintSalesDetail.CompanyCode,
  key VATPrintSalesDetail.FiscalYear,
  key VATPrintSalesDetail.AccountingDocument,
  key StRpJournalEntryLog.StatryRptgEntity,
  key StRpJournalEntryLog.StatryRptCategory,
  key StRpJournalEntryLog.StatryRptRunID,
      VATPrintSalesDetail.Customer,
      VATPrintSalesDetail.BusinessPartnerCountry,
      VATPrintSalesDetail.ExchangeRate,
      VATPrintSalesDetail.AccountingDocumentType,
      VATPrintSalesDetail.AR_OfficialDocumentClass,
      VATPrintSalesDetail.FiscalPeriod,
      VATPrintSalesDetail.PostingDate,
      VATPrintSalesDetail.DocumentDate,
      VATPrintSalesDetail.ReportingDate,
      VATPrintSalesDetail.AR_OfficialDocumentType,
      VATPrintSalesDetail.AR_OfficialDocTypeLongDesc,
      VATPrintSalesDetail.AR_IsSubjectToFiscalController,
      VATPrintSalesDetail.ClearingAccountingDocument,
      VATPrintSalesDetail.ClearingDate,
      VATPrintSalesDetail.ReferenceDocumentType,
      VATPrintSalesDetail.DocumentReferenceID,
      VATPrintSalesDetail.AR_PrintCharacter,
      VATPrintSalesDetail.AR_OfficialDocumentNumber,
      VATPrintSalesDetail.IsReversal,
      VATPrintSalesDetail.IsReversed,
      VATPrintSalesDetail.ReverseDocument,
      VATPrintSalesDetail.ReversalReferenceDocument,
      VATPrintSalesDetail.OriginalReferenceDocument,
      VATPrintSalesDetail.AR_Branch,
      VATPrintSalesDetail.BusinessPartnerName,

      cast(
        case VATPrintSalesDetail.BusinessPartnerCountry
          when 'AR'
            then VATPrintSalesDetail.TaxNumber1
          else ForeignNationalTaxCode.AR_CUIT
        end as stcd1 preserving type
      )                                   as TaxNumber1,

      cast(
        case VATPrintSalesDetail.BusinessPartnerCountry
          when 'AR'
            then VATPrintSalesDetail.TaxNumberType
          else '80'
        end as j_1atoid preserving type
      )                                   as TaxNumberType,

      VATPrintSalesDetail.AR_CAE,

      @Semantics.currencyCode: true
      VATPrintSalesDetail.CompanyCodeCurrency,

      @Semantics.currencyCode:true
      VATPrintSalesDetail.TransactionCurrency,

      @Aggregation.default: #SUM
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      VATPrintSalesDetail.TaxAmountInCoCodeCrcy,

      @Aggregation.default: #SUM
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      VATPrintSalesDetail.AmountInCompanyCodeCurrency,

      @Aggregation.default: #SUM
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      VATPrintSalesDetail.AmountInTransactionCurrency,

      @Aggregation.default: #SUM
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      VATPrintSalesDetail.TaxedAmountInCoCoCrcy,

      @Aggregation.default: #SUM
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      VATPrintSalesDetail.NotTaxedAmount,

      @Aggregation.default: #SUM
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      VATPrintSalesDetail.TaxExemptionAmount,

      @Aggregation.default: #SUM
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      VATPrintSalesDetail.ImportAmountInCompanyCodeCrcy,

      @Aggregation.default: #SUM
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      VATPrintSalesDetail.RegisteredBPTaxAmount,

      @Aggregation.default: #SUM
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      VATPrintSalesDetail.NotRegisteredBPTxAmtInCoCoCrcy,

      @Aggregation.default: #SUM
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      VATPrintSalesDetail.PerceptionVATAmount,

      @Aggregation.default: #SUM
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      VATPrintSalesDetail.OtherTaxAmount,

      @Aggregation.default: #SUM
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      VATPrintSalesDetail.GrossIncomeTaxAmount,

      @Aggregation.default: #SUM
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      VATPrintSalesDetail.MunicipalTaxAmount,

      @Aggregation.default: #SUM
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      cast (
          VATPrintSalesDetail.TaxedAmountInCoCoCrcy +
          VATPrintSalesDetail.NotTaxedAmount +
          VATPrintSalesDetail.RegisteredBPTaxAmount +
          VATPrintSalesDetail.NotRegisteredBPTxAmtInCoCoCrcy +
          VATPrintSalesDetail.PerceptionVATAmount +
          VATPrintSalesDetail.OtherTaxAmount +
          VATPrintSalesDetail.GrossIncomeTaxAmount +
          VATPrintSalesDetail.MunicipalTaxAmount +
          VATPrintSalesDetail.TaxExemptionAmount +
          VATPrintSalesDetail.ImportAmountInCompanyCodeCrcy
        as fiar_total_amount_incompcrcy ) as TotalAmountInCoCodeCrcy
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_AR_FRGNNATLTXCODE",
"I_STRPJOURNALENTRYLOG",
"P_AR_VATPRINTSALESDETAIL"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/