@EndUserText.label: 'Manage Lockbox Batch'
@VDM.viewType: #CONSUMPTION
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #NOT_REQUIRED //only company data
@AbapCatalog.sqlViewName: 'CARLOCKBOXBATCH'
@Search.searchable: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.serviceQuality: #X
@ObjectModel.usageType.dataClass: #MIXED
@UI.headerInfo:{
typeName: 'Lockbox Batch',
typeNamePlural: 'Lockbox Batches',
title: { value: 'LockboxBatch' },
description: { label: 'Lockbox No.', value: 'Lockbox' }
}
define view C_ARLockBoxBatch
as select from I_ARLockBoxBatch as header
association [0..*] to C_ARLockBoxBatchItem as _Item on $projection.LockboxBatchInternalKey = _Item.LockboxBatchInternalKey
and $projection.LockboxBatch = _Item.LockboxBatch
association [0..1] to I_Currency as _Currency on _Currency.Currency = $projection.Currency
association [1] to I_CompanyCode as _CompanyCode on $projection.CompanyCode = _CompanyCode.CompanyCode
association [0..1] to I_Housebank as _HouseBank on $projection.HouseBank = _HouseBank.HouseBank
and $projection.CompanyCode = _HouseBank.CompanyCode
association [0..*] to I_HouseBankAccountText as _HouseBankAccount on _HouseBankAccount.CompanyCode = $projection.CompanyCode
and _HouseBankAccount.HouseBank = $projection.HouseBank
and _HouseBankAccount.HouseBankAccount = $projection.HouseBankAccount
{
@UI.facet: [
{
label: 'Lockbox Batch',
id: 'COLLFAC1',
type: #COLLECTION,
position: 10
},
{
label: '',
id: 'Q1',
parentId: 'COLLFAC1',
type: #FIELDGROUP_REFERENCE,
position: 10,
targetQualifier: 'Q1'
},
{
label: '',
id: 'Q2',
parentId: 'COLLFAC1',
type: #FIELDGROUP_REFERENCE,
position: 20,
targetQualifier: 'Lockbox Batch'
},
{
label: 'Lockbox Batch Items',
id: 'FACET1',
type: #LINEITEM_REFERENCE,
position: 20,
targetElement: '_Item'
}
]
key LockboxBatchInternalKey,
@UI.lineItem: { position: 60, importance: #HIGH,
type: #WITH_NAVIGATION_PATH,
url: '_Item'}
@UI.selectionField.position: 60
@UI.dataPoint: { title: 'Batch No.' }
key LockboxBatch,
@UI.lineItem: { position: 40, importance: #HIGH }
@UI.selectionField.position: 50
@UI.fieldGroup:[{qualifier:'Lockbox Batch',position:10}]
@UI.identification: [ { qualifier: 'Q1', position: 30} ]
@ObjectModel.foreignKey.association: '_Lockbox'
@Consumption.valueHelpDefinition: [
{ entity: { name: 'I_ARLockbox',
element: 'Lockbox' },
additionalBinding: [{ localElement: 'CompanyCode',
element: 'CompanyCode' },
{ localElement: 'HouseBank',
element: 'HouseBank' },
{ localElement: 'HouseBankAccount',
element: 'HouseBankAccount' }]
}]
@Consumption.valueHelp: '_Lockbox'
Lockbox,
@UI.fieldGroup: { qualifier: 'Q1', position: 30 }
@UI.lineItem: { position: 20, importance: #HIGH }
@UI.selectionField: { position: 30 }
@UI.identification: [ { qualifier: 'Q1', position: 10} ]
@Consumption.semanticObject: 'CompanyCode'
@Search.defaultSearchElement: true
@Search.fuzzinessThreshold: 0.8
@Search.ranking: #HIGH
@Consumption.valueHelpDefinition: [
{ entity: { name: 'I_CompanyCodeStdVH',
element: 'CompanyCode' }
}]
@UI.textArrangement: #TEXT_LAST
@ObjectModel.text.association: '_CompanyCode'
CompanyCode,
@UI.fieldGroup: { qualifier: 'Q1', position: 20 }
@UI.lineItem: { position: 30, importance: #HIGH }
@UI.selectionField.position: 20
@UI.identification: [ { qualifier: 'Q1', position: 20} ]
@Search.defaultSearchElement: true
@Search.fuzzinessThreshold: 0.8
@ObjectModel.text.element: 'BankName'
@Consumption.valueHelpDefinition: [
{ entity: { name: 'I_HouseBankStdVH',
element: 'HouseBank' },
additionalBinding: [{ localElement: 'CompanyCode',
element: 'CompanyCode' }]
}]
@ObjectModel.foreignKey.association: '_HouseBank'
@UI.textArrangement: #TEXT_LAST
HouseBank,
@Search.defaultSearchElement: true
@Search.fuzzinessThreshold: 0.8
@Consumption.valueHelpDefinition: [
{ entity: { name: 'I_HouseBankAccountVH',
element: 'HouseBankAccount' },
additionalBinding: [{ localElement: 'CompanyCode',
element: 'CompanyCode' },
{ localElement: 'HouseBank',
element: 'HouseBank' }]
}]
@Consumption.semanticObject: 'HouseBankAccount'
@ObjectModel.text.association: '_HouseBankAccount'
@EndUserText.label: 'House Bank Account'
@UI.textArrangement: #TEXT_LAST
HouseBankAccount,
@UI.fieldGroup:[{qualifier:'Lockbox Batch',position:30}]
@UI.lineItem: { position: 10, importance: #HIGH }
@UI.selectionField.position: 40
@UI.identification: [ { qualifier: 'Q2', position: 40} ]
@Consumption.filter.selectionType:#INTERVAL
DepositDate,
@UI.fieldGroup:[{qualifier:'Lockbox Batch',position:20}]
@Consumption.semanticObject: 'IncomingPaymentFile'
IncomingPaymentFile,
@UI.selectionField.position: 40
LockboxBatchStatus,
@UI.lineItem: [{ position: 75, importance: #HIGH }]
LockboxBatchStatusName,
@UI.lineItem: [{ position: 70, importance: #HIGH }]
NumberOfItems,
@Semantics: { currencyCode: true }
@Consumption.semanticObject: 'Currency'
@UI.textArrangement: #TEXT_LAST
@Consumption.valueHelpDefinition: [
{ entity: { name: 'I_CurrencyStdVH',
element: 'Currency' }
}]
Currency,
@UI.lineItem: [{ position: 90, importance: #HIGH }]
@UI.dataPoint: { title: 'Payment Amount' }
AmountInTransactionCurrency,
@UI.lineItem: [{ position: 80, importance: #HIGH }]
NumberOfIncompleteCheques,
@UI.selectionField.position: 60
BatchIsLatest,
header.BankName as BankName,
@Consumption.filter.hidden:true
_CompanyCode,
@Consumption.filter.hidden:true
_HouseBank,
@Consumption.filter.hidden:true
_HouseBankAccount,
@Consumption.filter.hidden:true
_Lockbox,
@Consumption.filter.hidden:true
_Currency,
@Consumption.filter.hidden:true
_Item
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ARLOCKBOXBATCH"
],
"ASSOCIATED":
[
"C_ARLOCKBOXBATCHITEM",
"I_ARLOCKBOX",
"I_COMPANYCODE",
"I_CURRENCY",
"I_HOUSEBANK",
"I_HOUSEBANKACCOUNTTEXT"
],
"BASE":
[
"I_ARLOCKBOXBATCH"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/