C_APProcessFlowPoItem

@VDM.viewType: #CONSUMPTION
@AbapCatalog.sqlViewName: 'CAPPFPOITEM'
@AbapCatalog.compiler.compareFilter: true

@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@AccessControl.privilegedAssociations:  [ '_PurchaseOrder']
@ClientHandling.algorithm: #SESSION_VARIABLE
@DataAging.noAgingRestriction: false

@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #MIXED

@EndUserText.label: 'AP Process Flow Purchase Order Item'
@AbapCatalog.preserveKey:true
define view C_APProcessFlowPoItem
  as select from I_PurchaseOrderItem as purchOrderItem

  //  association [1..1] to I_PurchaseOrder          as _PurchaseOrder          on  $projection.ProcessFlowNodeDocument = _PurchaseOrder.PurchaseOrder

  association [1..1] to C_APProcessFlowPurchaseOrder as _PurchaseOrder          on  $projection.ProcessFlowNodeDocument = _PurchaseOrder.PurchaseOrder


  association        to I_PurchasingDocumentItem     as _PurchasingDocumentItem on  _PurchasingDocumentItem.PurchasingDocument     = purchOrderItem.PurchaseOrder
                                                                                and _PurchasingDocumentItem.PurchasingDocumentItem = purchOrderItem.PurchaseOrderItem

{

      //Current Document

  key purchOrderItem.PurchaseOrder                                                                          as ProcessFlowNodeDocument,
  key purchOrderItem.PurchaseOrderItem                                                                      as ProcessFlowNodeDocumentItem,
      concat(purchOrderItem.PurchaseOrder,concat(concat('0',purchOrderItem.PurchaseOrderItem),'____0000F')) as ProcessFlowNode,
      cast( 'F' as farp_bstat_d preserving type )                                                           as ProcessFlowNodeDocCategory,
      cast('0000' as fis_gjahr preserving type )                                                            as FiscalYear,
      @ObjectModel.text.element: ['CompanyCodeName']
      @UI.textArrangement: #TEXT_LAST
      purchOrderItem.CompanyCode                                                                            as CompanyCode,

      //Parent Document

      cast( ' ' as farp_processflownode)                                                                    as ParentProcessFlowNode,
      cast( ' ' as ebeln  )                                                                                 as ParentProcessFlowNodeDocument,
      '000000'                                                                                              as ParentProcessFlowNodeDocItem,
      cast( ' ' as farp_bstat_d preserving type )                                                           as ParentProcFlwNodeDocCategory,
      cast('0000' as fis_gjahr preserving type )                                                            as ParentProcFlowNodeFiscalYear,
      cast('    ' as bukrs preserving type )                                                                as ParentProcFlowNodeCompanyCode,

      //Additional consumption fields

      _PurchaseOrder.CreatedByUser                                                                          as CreatedByUser,
      _PurchaseOrder.FullName                                                                               as FullName,
      @ObjectModel.readOnly
      @Consumption.semanticObject: 'CompanyCode'
      @Semantics.text: true
      purchOrderItem._CompanyCode.CompanyCodeName                                                           as CompanyCodeName,
      PurchasingDocumentDeletionCode                                                                        as PurchasingDocumentDeletionCode,
      cast( '' as ebeln )                                                                                   as ReferenceDocument,
      purchOrderItem.OrderQuantity                                                                          as Quantity,
      purchOrderItem.PurchaseOrderQuantityUnit                                                              as PurchaseOrderQuantityUnit,
      purchOrderItem._PurchaseOrder.PurchaseOrderDate                                                       as PurchaseOrderDate,
      purchOrderItem.Customer                                                                               as Customer,
      purchOrderItem._Customer.CustomerName                                                                 as CustomerName,
      purchOrderItem.NetAmount                                                                              as NetAmount,
      purchOrderItem.DocumentCurrency                                                                       as DocumentCurrency,
      purchOrderItem.AccountAssignmentCategory                                                              as AccountAssignmentCategory,
      _PurchasingDocumentItem.PurchasingDocumentItemCategory                                                as PurchasingDocumentItemCategory,
      _PurchaseOrder.Supplier                                                                               as Supplier,
      _PurchaseOrder.SupplierName                                                                           as SupplierName,


      @Consumption.hidden: true
      purchOrderItem.Plant                                                                                  as Plant,

      @Consumption.hidden: true
      _PurchaseOrder,

      @Consumption.hidden: true
      purchOrderItem._PurchaseOrder._Supplier.AuthorizationGroup
      

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"C_APPROCESSFLOWPURCHASEORDER",
"I_COMPANYCODE",
"I_CUSTOMER",
"I_PURCHASEORDER",
"I_PURCHASEORDERITEM",
"I_PURCHASINGDOCUMENTITEM",
"I_SUPPLIER"
],
"ASSOCIATED":
[
"C_APPROCESSFLOWPURCHASEORDER",
"I_PURCHASINGDOCUMENTITEM"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/