CTE_CDS_FIN_MON_MO

@ClientHandling.algorithm: #SESSION_VARIABLE

@AbapCatalog.sqlViewName: 'CTE_FIN_MON_MO'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'CDS View for Monotoring MO exp to Concur'
@ObjectModel.usageType.serviceQuality: #X
@ObjectModel.usageType.sizeCategory: #M
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
define view CTE_CDS_FIN_MON_MO
  with parameters
    p_system_key     : cte_system_key_number,
    p_otype          : cte_otype,
    p_start_timestmp : timestampl,
    p_end_timestmp   : timestampl,
    p_language       : spras //here we don't need that parameter, however to have a common interface for all cds views we need to provide this parameter

  as select from cte_d_com_log_mo                                                                           as com_log_mo
    inner join   CTE_CDS_FIN_LATEST_COM_LOG_MO( p_system_key:$parameters.p_system_key,
                 p_start_timestmp:$parameters.p_start_timestmp, p_end_timestmp:$parameters.p_end_timestmp ) as latest_com_log_mo on(
      latest_com_log_mo.objid         = com_log_mo.objid
      and latest_com_log_mo.timestamp = com_log_mo.timestamp
    )
    inner join   aufk                                                                                                            on aufk.aufnr = com_log_mo.objid
{
  key com_log_mo.system_key as system_key,
  key com_log_mo.otype      as otype,
  key com_log_mo.objid      as objid,
      com_log_mo.objid      as objid_ext,
      aufk.bukrs            as company_code,
      aufk.ktext            as name,
      com_log_mo.timestamp  as timestamp,
      com_log_mo.operation  as action_code,
      case com_log_mo.failed_indicator
      when 'X' then 'F'
      else 'S' end          as action_status,
      com_log_mo.lognumber  as lognumber,
      cast(1 as   int4)     as processing_time

}
where
      com_log_mo.system_key = $parameters.p_system_key
  and com_log_mo.otype      = $parameters.p_otype
  and com_log_mo.timestamp  >= $parameters.p_start_timestmp
  and com_log_mo.timestamp  <= $parameters.p_end_timestmp
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"CTE_CDS_FIN_LATEST_COM_LOG_MO",
"AUFK",
"CTE_D_COM_LOG_MO"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/