CIC_SalesDocumentPartner

@ObjectModel: {
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #D,
     sizeCategory:   #XL
   }
}
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Projection on Sales Doc. Partner (Industry Cloud Solutions)'
define view entity CIC_SalesDocumentPartner
  as select from    I_SalesDocumentPartner as Partner
    left outer join CIC_GEO_COORDINATES    as Coordinates on Partner.AddressID = Coordinates.addrnumber
    left outer join adrc                   as _Address    on  Partner.AddressID  = _Address.addrnumber
                                                          and _Address.nation    is initial
                                                          and _Address.date_from = '00010101'
{
  key Partner.SalesDocument,
  key Partner.Partner,
  key Partner.PartnerFunction,
      Partner.AddressObjectType,
      coalesce( Partner._PersonAddress.CityName, Partner._OrganizationAddress.CityName )                       as CityName,
      coalesce( Partner._PersonAddress.CityNumber, Partner._OrganizationAddress.CityNumber )                   as CityNumber,
      coalesce( Partner._PersonAddress.StreetName, Partner._OrganizationAddress.StreetName )                   as StreetName,
      coalesce( Partner._PersonAddress.AddressTimeZone, Partner._OrganizationAddress.AddressTimeZone )         as AddressTimeZone,
      coalesce( Partner._PersonAddress.Country, Partner._OrganizationAddress.Country )                         as Country,
      coalesce( Partner._PersonAddress.Region, Partner._OrganizationAddress.Region )                           as Region,
      coalesce( Partner._PersonAddress.SecondaryRegion, Partner._OrganizationAddress.SecondaryRegion )         as SecondaryRegion,
      coalesce( Partner._PersonAddress.SecondaryRegionName, Partner._OrganizationAddress.SecondaryRegionName ) as SecondaryRegionName,
      coalesce( Partner._PersonAddress.TertiaryRegion, Partner._OrganizationAddress.TertiaryRegion )           as TertiaryRegion,
      coalesce( Partner._PersonAddress.TertiaryRegionName, Partner._OrganizationAddress.TertiaryRegionName )   as TertiaryRegionName,
      coalesce( Partner._PersonAddress.PostalCode, Partner._OrganizationAddress.PostalCode )                   as PostalCode,
      _Address.cityp_code                                                                                      as BPCityDistrictCode,
      coalesce( Partner._PersonAddress.DistrictName, Partner._OrganizationAddress.DistrictName )               as DistrictName,
      coalesce( Partner._PersonAddress.HouseNumber, Partner._OrganizationAddress.HouseNumber )                 as HouseNumber,
      Partner._OrganizationAddress.AddresseeName1                                                              as AddresseeName1,
      Partner._OrganizationAddress.AddresseeName2                                                              as AddresseeName2,
      Partner._OrganizationAddress.AddresseeName3                                                              as AddresseeName3,
      Partner._OrganizationAddress.AddresseeName4                                                              as AddresseeName4,
      Partner._OrganizationAddress.CareOfName                                                                  as CareOfName,
      Partner._PersonAddress.GivenName                                                                         as firstname,
      Partner._PersonAddress.PersonMiddleName                                                                  as middlename,
      Partner._PersonAddress.FamilyName                                                                        as lastname,
      Partner._PersonAddress.PersonFullName                                                                    as personfullname,
      coalesce( Partner._PersonAddress.Building, Partner._OrganizationAddress.Building )                       as Building,
      coalesce( Partner._PersonAddress.Floor, Partner._OrganizationAddress.Floor )                             as Floor,
      coalesce( Partner._PersonAddress.RoomNumber, Partner._OrganizationAddress.RoomNumber )                   as RoomNumber,
      coalesce( Partner._PersonAddress.VillageName, Partner._OrganizationAddress.VillageName )                 as AdditionalCityName,
      Coordinates.altitude                                                                                     as altidute,
      Coordinates.latitude                                                                                     as latitude,
      Coordinates.longitude                                                                                    as longitude,
      Partner.EmailAddress                                                                                     as EmailAddress,
      Partner.InternationalMobilePhoneNumber                                                                   as InternationalMobilePhoneNumber,
      Partner.InternationalPhoneNumber                                                                         as InternationalPhoneNumber ,
      Partner.InternationalFaxNumber                                                                           as InternationalFaxNumber     
}
where
     Partner.PartnerFunction = 'RE'
  or Partner.PartnerFunction = 'WE'
  or Partner.PartnerFunction = 'RG'
  or Partner.PartnerFunction = 'AG'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"CIC_GEO_COORDINATES",
"I_ORGANIZATIONADDRESS",
"I_PERSONADDRESS",
"I_SALESDOCUMENTPARTNER",
"ADRC"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/