CIC_SOURCE_LIST

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'CIC Source of Supply Type A: Source List'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #M,
  dataClass: #MIXED
}
define view entity CIC_SOURCE_LIST
  as select from I_MPPurchasingSourceItem as sourcelist
{
  key case sourcelist.Supplier
        when '' then _SupplyingPlant.PlantSupplier
        else sourcelist.Supplier
      end                                               as Supplier,
  key _Plant.PlantCustomer                              as Receiver,
  key Material                                          as Product,
  key cast ('A' as cic_source_of_supply_type )          as SourceOfSupplyType,
  key cast('' as matkl)                                 as ProductGroup,
  key PurchasingOrganization                            as PurchasingOrganization,
  key ValidityStartDate                                 as ValidityStartDate,
  key ValidityEndDate                                   as ValidityEndDate,
  key SourceListRecordCategory                          as Category,

      _Plant._Address.AddressTimeZone                   as ReceivingTimeZone,
      SupplyingPlant,
      Plant                                             as ReceivingPlant,
      cast(case sourcelist.Supplier
              when '' then
                case IssgPlantIsFixed
                    when 'X' then '00'
                    else '01'
                end
              else
                case SupplierIsFixed
                    when 'X' then '00'
                    else '01'
                end
           end as lwrk_prio )                           as Priority,
      SourceOfSupplyIsBlocked                           as IsPurchasingBlocked,
      cast('' as infnr)                                 as PurchasingInfoRecord,
      cast('' as ltsnr)                                 as SupplierSubRange,
      OrderQuantityUnit                                 as OrderQuantityUnit,
      cast('' as waers)                                 as OrderCurrency,
      @Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'
      cast(0 as minbm)                                  as MinimumOrderQuantity,
      cast(0 as plifz)                                  as PlannedDeliveryTimeDays,
      cast('' as bkgrp)                                 as PurchasingGroup,
      cast('' as inco1)                                 as IncotermsClassification,
      cast('' as inco2)                                 as IncotermsTransferLocationName,
      SourceListRecord,
      @Semantics.amount.currencyCode: 'OrderCurrency'
      cast(0 as netpr)                                  as NetPriceAmount,
      @Semantics.quantity.unitOfMeasure: 'NetPriceUnit'
      cast(0 as peinh)                                  as NetPriceQuantity,
      cast('' as bprme)                                 as NetPriceUnit
      //  cast('' as iloea)                                     as InfoRecordIsMarkedForDeletion

}
where
  (
        sourcelist.Supplier           <> ''
    or  _SupplyingPlant.PlantSupplier <> ''
  )
  and
  (
        Plant                         <> ''
    and _Plant.PlantCustomer          <> ''
  );

// Unit tests class:  TC_CIC_SOURCE_LIST

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ADDRESS",
"I_MPPURCHASINGSOURCEITEM",
"I_PLANT"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/