CIC_PlantAddress

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Proj. view on Plant address'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
    serviceQuality: #X,
    sizeCategory: #S,
    dataClass: #MIXED
}
define view entity CIC_PlantAddress
  as select from    adrc    as _PlantAddress
    inner join      I_Plant as _Plant on _Plant.AddressID = _PlantAddress.addrnumber
  association [1..1] to CIC_GEO_COORDINATES as _geolocation on  $projection.AddressID = _geolocation.addrnumber
  association [1..1] to CIC_IANATimeZone    as _IANAZone    on  $projection.AddressTimeZone = _IANAZone.tzone
                                                            and _IANAZone.flagsapdefault    = 'X'
{
  key _PlantAddress.addrnumber    as AddressID,
  key _Plant.Plant,
      _IANAZone.ianatzone         as IANATimeZone,
      _PlantAddress.region        as Region,
      _PlantAddress.country       as Country,
      _PlantAddress.county        as SecondaryRegionName,
      _PlantAddress.county_code   as SecondaryRegion,
      _PlantAddress.township_code as TertiaryRegion,
      _PlantAddress.township      as TertiaryRegionName,
      _PlantAddress.post_code1    as PostalCode,
      _PlantAddress.city1         as CityName,
      _PlantAddress.city_code     as CityCode,
      _PlantAddress.home_city     as AdditionalCityName,
      /* District */
      _PlantAddress.city2         as DistrictName,
      _PlantAddress.cityp_code    as BPCityDistrictCode,
      /* Street */
      _PlantAddress.street        as StreetName,
      _PlantAddress.streetcode   as Street,
      _PlantAddress.house_num1    as HouseNumber,
      _PlantAddress.building      as Building,
      _PlantAddress.floor         as Floor,
      _PlantAddress.roomnumber    as RoomNumber,

      /* Geolocation */
      _geolocation.latitude,
      _geolocation.longitude,
      _geolocation.altitude,

      _PlantAddress.name1         as BusinessPartnerName1,
      _PlantAddress.name2         as BusinessPartnerName2,
      _PlantAddress.name3         as BusinessPartnerName3,
      _PlantAddress.name4         as BusinessPartnerName4,
      _PlantAddress.time_zone     as AddressTimeZone

}where
      _PlantAddress.date_from = '00010101'
  and _PlantAddress.nation    = ' '
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"CIC_GEO_COORDINATES",
"CIC_IANATIMEZONE",
"I_PLANT",
"ADRC"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/