CIC_InitialOpenItem

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Proj. View on Initial Open Item'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #D,
  sizeCategory: #XXL,
  dataClass: #MIXED
}
define view entity CIC_InitialOpenItem as select from I_OperationalAcctgDocItem as OpenInvoiceItem
  inner join I_AccountingDocument as OpenInvoiceHeader on
        OpenInvoiceItem.CompanyCode        = OpenInvoiceHeader.CompanyCode and
        OpenInvoiceItem.AccountingDocument = OpenInvoiceHeader.AccountingDocument and
        OpenInvoiceItem.FiscalYear         = OpenInvoiceHeader.FiscalYear and
        // We are not interested in residual items. They are already taken care by other extractors

        // We are currently also not interested in partial payment items, credit memo items and down payment items.

        (
            OpenInvoiceItem.FollowOnDocumentType is null or
            OpenInvoiceItem.FollowOnDocumentType = ''
        )
        and
        // We are only interested in open items (i.e. no clearing happened yet)

        (
            OpenInvoiceItem.ClearingAccountingDocument is null or
            OpenInvoiceItem.ClearingAccountingDocument = ''
        )
        // We are only intereseted in items of catagory '', 'S', or 'A'

        and
        (
            OpenInvoiceItem.AccountingDocumentCategory    = '' or
            OpenInvoiceItem.AccountingDocumentCategory    = 'S' or
            OpenInvoiceItem.AccountingDocumentCategory    = 'A'
       )
       // We are only interested in A/R items

       and
            OpenInvoiceItem.FinancialAccountType             = 'D'
{
  key OpenInvoiceItem.CompanyCode,
  key OpenInvoiceItem.FiscalYear,
  key OpenInvoiceItem.AccountingDocument,
  key OpenInvoiceItem.AccountingDocumentItem,
      OpenInvoiceItem.DebitCreditCode,
      OpenInvoiceItem.CompanyCodeCurrency,
      @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
      OpenInvoiceItem.AmountInCompanyCodeCurrency,
      OpenInvoiceItem.TransactionCurrency,
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      OpenInvoiceItem.AmountInTransactionCurrency,
      OpenInvoiceItem.Customer,
      OpenInvoiceItem.BillingDocument,
      OpenInvoiceItem.AssignmentReference,
      OpenInvoiceHeader.AccountingDocumentType,
      OpenInvoiceHeader.AccountingDocumentHeaderText, //                 as HeaderText,

      OpenInvoiceItem.DocumentItemText,//                               as ItemtText,

      OpenInvoiceItem.PaymentDifferenceReason,
      OpenInvoiceHeader.AccountingDocumentCreationDate               as CreationDate,
      OpenInvoiceHeader.CreationTime                                 as CreationTime,
      OpenInvoiceHeader.LastChangeDate,
      OpenInvoiceItem.PostingDate,
      OpenInvoiceItem.DocumentDate,
      OpenInvoiceItem.NetDueDate,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      OpenInvoiceItem.CashDiscountBaseAmount,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      OpenInvoiceItem.CashDiscountAmount,
      OpenInvoiceItem.PaymentTerms,
      OpenInvoiceItem.CashDiscount1Days,
      OpenInvoiceItem.CashDiscount2Days,
      OpenInvoiceItem.NetPaymentDays,
      OpenInvoiceItem.CashDiscount1Percent,
      OpenInvoiceItem.CashDiscount2Percent,
      OpenInvoiceItem.DueCalculationBaseDate,
      OpenInvoiceItem.FixedCashDiscount,
      OpenInvoiceItem.PaymentBlockingReason
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ACCOUNTINGDOCUMENT",
"I_OPERATIONALACCTGDOCITEM"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/