Arun_Open_Delivery_C

@AbapCatalog.sqlViewName: 'ARUN_V_OPEN_DLVC'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.serviceQuality: #X
@ObjectModel.usageType.dataClass:#TRANSACTIONAL
@ClientHandling.algorithm: #AUTOMATED
@EndUserText.label: 'Supply Assignment open deliveries'
define view Arun_Open_Delivery_C
  as select from vbbe as v
    inner join   marc as mc on(
      v.matnr     = mc.matnr
      and v.werks = mc.werks
    )
{
  v.matnr      as Material,
  v.werks      as Plant,
  v.lgort      as StorageLocation,
  ( case
  when mc.arun_fix_batch = '1' then v.charg
  else ' '
  end ) as Batch,
  sum(v.vmeng) as deliveryQuantity
}
where
      v.vbtyp            = 'J' and
      v.sobkz            = ''
  and mc.fsh_mg_arun_req = '1'
group by
  v.matnr,
  v.werks,
  v.lgort,
  v.charg,
  mc.arun_fix_batch

union all select from arun_bdbs as b
  inner join          vbbe      as v on  b.salesdoc_num  = v.vbeln
                                     and b.salesdoc_item = v.posnr
                                     and v.vbtyp         = 'J'
                                     and v.charg         = ''
{
  b.material         as Material,
  b.plant            as Plant,
  b.storage_location as StorageLocation,
  b.batch            as Batch,
  sum(b.alloc_qty)   as deliveryQuantity
}
where
      b.req_ind      =  'VJ'
  and b.stock_source =  'C'
  and b.batch        <> ''
group by
  b.material,
  b.plant,
  b.storage_location,
  b.batch
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"ARUN_BDBS",
"MARC",
"VBBE"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/