A_SubscrpnContrItmStrParam

@EndUserText.label: 'Subscription Contract Item CC String Parameter'
@VDM: {
  viewType: #COMPOSITE,
  lifecycle.contract.type: #PUBLIC_REMOTE_API
}

@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #NOT_REQUIRED
}
@ObjectModel: {
   createEnabled: false,
   updateEnabled: false,
   deleteEnabled: false,
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #C,
     sizeCategory:   #XL
   }
}
@Metadata.ignorePropagatedAnnotations: true

/*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ]  } */
define view entity A_SubscrpnContrItmStrParam
  as select from I_SbscrContrItmCnvChrgParam as SbscrContrItmCnvChrgParam
  association [0..1] to I_ChargePlanParameter  as _ChargePlanParameter  on  $projection.ChargePlanAssignmentUUID = _ChargePlanParameter.ChargePlanAssignmentUUID
                                                                        and $projection.ChargePlanParameterID    = _ChargePlanParameter.ChargePlanParameterID
  association [1..1] to A_SubscriptionContract as _SubscriptionContract on  $projection.SubscriptionContract = SbscrContrItmCnvChrgParam.SubscriptionContract
{

  key    SubscriptionContract,
  key    ServiceDocumentItem         as SubscriptionContractItem,
  key    _ChargePlanParameter.ChargePlanParameterUUID,
         @Consumption.hidden: true
         SbscrContrItmCnvChrgParam.ChargePlanAssignmentUUID,
         SbscrContrItmCnvChrgParam.ChargePlanParameterID,
         SbscrContrItmCnvChrgParam.ChargePlanParameterUseValue,
         SbscrContrItmCnvChrgParam.ChargePlanParameterValue,
         SbscrContrItmCnvChrgParam.ChargePlanParameterType,

         case when SbscrContrItmCnvChrgParam.ChargePlanParameterUseValue = '2'
          then SbscrContrItmCnvChrgParam.ChargePlanParameterValue
          else ''
          end                        as ChargePlanParameterStringValue,

         case when SbscrContrItmCnvChrgParam.ChargePlanParameterUseValue = '3'
          then cast( SbscrContrItmCnvChrgParam.ChargePlanParameterValue as abap.char( 30 ))
         else cast( '' as abap.char( 30 ))
         end                         as Characteristic,


         @ObjectModel: { virtualElement: true,
                        virtualElementCalculatedBy: 'CL_CRMS4_SOM_CC_PAR_BRFPLUSTXT'
         }
         cast('' as abap.char( 30 )) as BRFFunction,


         //Association

         @Consumption.hidden: true
         _SubscriptionContract

}
where
      _ChargePlanParameter.ChargePlanParameterType  = '2'
  and _ChargePlanParameter.ChargePlanParameterUsage = '1'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CHARGEPLANPARAMETER",
"I_SBSCRCONTRITMCNVCHRGPARAM"
],
"ASSOCIATED":
[
"A_SUBSCRIPTIONCONTRACT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/