A_SourcingProject

@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #NOT_REQUIRED

@Metadata.ignorePropagatedAnnotations:true

@VDM: {
    viewType : #CONSUMPTION,
    lifecycle.contract.type: #PUBLIC_REMOTE_API,
    usage.type: [#TRANSACTIONAL_PROCESSING_SERVICE]
}

@ObjectModel: {
                representativeKey: 'SourcingProjectUUID',
                semanticKey: [ 'SourcingProject' ],

                modelingPattern:        #TRANSACTIONAL_QUERY,
                supportedCapabilities: [#TRANSACTIONAL_PROVIDER],

                usageType.dataClass: #TRANSACTIONAL,
                usageType.serviceQuality:  #C,
                usageType.sizeCategory: #L
                }


@EndUserText.label: 'Sourcing Project'

@AccessControl.privilegedAssociations: [ '_SrcgProjImprtdSuplrListBP',
                                         '_SrcgProjPubdSuplrListBP'  ]
@OData.entityType.name: 'SourcingProject_Type'

@AbapCatalog.extensibility: {
  extensible: true,
  dataSources: ['SourcingProjectTP'],
  allowNewDatasources: false,
  elementSuffix: 'SPH',
  quota: { maximumFields: 204,
           maximumBytes: 4080 },
  allowNewCompositions: true }

define root view entity A_SourcingProject
  provider contract transactional_query
  as projection on R_SourcingProjectTP as SourcingProjectTP

  association [0..*] to A_SrcgProjImprtdSuplrListBP as _SrcgProjImprtdSuplrListBP on $projection.SourcingSupplierListUUID = _SrcgProjImprtdSuplrListBP.SourcingSupplierListUUID
{
  key SourcingProjectUUID,
      SourcingProject,
      SourcingProjectVersion,
      @ObjectModel.sapObjectNodeTypeReference: 'SourcingProjectType'
      SourcingProjectType,
      SourcingProjectName,
      @ObjectModel.sapObjectNodeTypeReference: 'SrcgProjLifecycleStatus'
      SrcgProjLifecycleStatus,
      @ObjectModel.sapObjectNodeTypeReference: 'SourcingProjectPhase'
      SourcingProjectPhase,
      SourcingSupplierListUUID,
      @ObjectModel.sapObjectNodeTypeReference: 'CompanyCode'
      CompanyCode,
      @ObjectModel.sapObjectNodeTypeReference: 'PurchasingGroup'
      PurchasingGroup,
      @ObjectModel.sapObjectNodeTypeReference: 'PurchasingOrganization'
      PurchasingOrganization,
      MaterialGroup,
      @ObjectModel.sapObjectNodeTypeReference: 'Currency'
      DocumentCurrency,
      @Semantics.amount.currencyCode: 'DocumentCurrency'
      SrcgProjTotalTargetAmount,
      PurchaserRespWorkAgreement,
      _PersonWorkAgreement.Person as PurchaserResponsiblePerson,
      QtnLatestSubmissionDateTime,
      LastChangeDateTime,
      CreationDateTime,
      SrcgProjPubgDteTme,
      SrcgProjCancDteTme,
      @ObjectModel.sapObjectNodeTypeReference: 'IncotermsClassification'
      IncotermsClassification,
      IncotermsTransferLocation,
      @ObjectModel.sapObjectNodeTypeReference: 'IncotermsVersion'
      IncotermsVersion,
      IncotermsLocation1,
      IncotermsLocation2,
      @ObjectModel.sapObjectNodeTypeReference: 'PaymentTerms'
      PaymentTerms,
      CashDiscount1Days,
      CashDiscount2Days,
      CashDiscount1Percent,
      CashDiscount2Percent,
      NetPaymentDays,
      @ObjectModel.sapObjectNodeTypeReference: 'PurchasingShippingInstruction'
      ShippingInstruction,
      SrcgProjFollowOnDocumentCat,
      @ObjectModel.sapObjectNodeTypeReference: 'PurchasingDocumentType'
      SrcgProjFollowOnDocumentType,
      PurContrValidityStartDate,
      PurContrValidityEndDate,
      // TargetAmount,

      @ObjectModel.sapObjectNodeTypeReference: 'SourcingOrigin'
      SourcingOrigin,
      @ObjectModel.sapObjectNodeTypeReference: 'SourcingScenario'
      SourcingScenario,
      ExternalSourcingProjectRef,
      LogicalSystem,
      SourcingProjectUniqueID,
      SrcgProjAttchsAreForbidden,
      SrcgProjNotesAreForbidden,
      LastChangedByUser,
      CreatedByUser,
      ProcurementPlanningBundleUUID,
      @ObjectModel.sapObjectNodeTypeReference: 'SourcingProjectVersioningRsn'
      SourcingProjectVersioningRsn,
      // SourceLogicalSystem,


      /* Associations */
      _SourcingProjectItem        : redirected to composition child A_SourcingProjectItem,
      _SrcgProjAllowedCurrency    : redirected to composition child A_SrcgProjAllowedCurrency,
      _SrcgProjPubdSuplrListBP    : redirected to composition child A_SrcgProjPubdSuplrListBP,
      _SrcgProjImprtdSuplrListBP,
      _SrcgProjAllwdSuplrContact  : redirected to composition child A_SrcgProjAllwdSuplrContact,
      _SourcingProjectContact     : redirected to composition child A_SourcingProjectContact,
      _SrcgProjProcurementProject : redirected to composition child A_SrcgProjProcurementProject,
      _SourcingProjectMilestone   : redirected to composition child A_SourcingProjectMilestone,
      _SourcingProjectNote        : redirected to composition child A_SourcingProjectNote
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_WORKASSIGNMENT",
"R_SOURCINGPROJECTTP"
],
"ASSOCIATED":
[
"A_SOURCINGPROJECTCONTACT",
"A_SOURCINGPROJECTITEM",
"A_SOURCINGPROJECTMILESTONE",
"A_SOURCINGPROJECTNOTE",
"A_SRCGPROJALLOWEDCURRENCY",
"A_SRCGPROJALLWDSUPLRCONTACT",
"A_SRCGPROJIMPRTDSUPLRLISTBP",
"A_SRCGPROJPROCUREMENTPROJECT",
"A_SRCGPROJPUBDSUPLRLISTBP",
"R_SOURCINGPROJECTCONTACTTP",
"R_SOURCINGPROJECTITEMTP",
"R_SOURCINGPROJECTMILESTONETP",
"R_SOURCINGPROJECTNOTETP",
"R_SRCGPROJALLOWEDCURRENCYTP",
"R_SRCGPROJALLWDSUPLRCONTACTTP",
"R_SRCGPROJPROCUREMENTPROJECTTP",
"R_SRCGPROJPUBDSUPLRLISTBPTP"
],
"BASE":
[
"R_SOURCINGPROJECTTP"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/