A_ServiceRequest

@ClientHandling.algorithm:#SESSION_VARIABLE
@EndUserText.label: 'Service Request'
@VDM: {
  viewType: #COMPOSITE,
  lifecycle.contract.type: #PUBLIC_REMOTE_API
}
@AbapCatalog: {
  sqlViewName: 'ASRVREQ',
  compiler.compareFilter: true,
  preserveKey: true
}
@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@ObjectModel: {
   representativeKey: 'ServiceRequest',
   createEnabled: true,
   updateEnabled: true,
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #B,
     sizeCategory:   #L
   }
}
@Metadata.ignorePropagatedAnnotations: true
define view A_ServiceRequest
  as select from I_ServiceDocumentEnhcd as ServiceRequest
  
  association [0..1] to I_ServiceDocumentItemEnhcd as _Item              on  $projection.ServiceRequest          = _Item.ServiceDocument
                                                                         and _Item.ServiceDocumentItemObjectType = 'BUS2000140'
                                                                         and _Item.ServiceObjectType             = 'BUS2000223'

  association [0..*] to A_ServiceRequestPersonResp as _PersonResponsible on  $projection.ServiceRequest = _PersonResponsible.ServiceRequest

  association [0..*] to A_ServiceRequestRefObject  as _ReferenceObject   on  $projection.ServiceRequest = _ReferenceObject.ServiceRequest

  association [0..*] to A_ServiceRequestText       as _Text              on  $projection.ServiceRequest = _Text.ServiceRequest

  association [0..*] to A_ServiceRequestDefect     as _Defect            on  $projection.ServiceRequest = _Defect.ServiceRequest

  association [0..1] to A_ServiceRequestReason     as _Reason            on  $projection.ServiceRequest = _Reason.ServiceRequest

  association [0..*] to A_ServiceRequestOrder      as _Order             on  $projection.ServiceRequest = _Order.ServiceRequest
  //Extensibility

  association [0..1] to E_ServiceDocument          as _Extension         on  _Extension.ServiceCategory = 'BUS2000223'
                                                                          and $projection.ServiceRequest    = _Extension.ServiceOrder
{

  key ServiceDocument                   as ServiceRequest,
      ServiceDocumentType               as ServiceRequestType,
      ServiceDocumentUUID               as ServiceRequestUUID,
      ServiceDocumentDescription        as ServiceRequestDescription,
      Language,
      ServiceDocumentPriority,
      BusinessActivityCategory          as ServiceDocumentCategory,
      RequestedServiceStartDateTime,
      RequestedServiceEndDateTime,
      ServiceFirstResponseByDateTime,
      ServiceDueByDateTime,
      PurchaseOrderByCustomer,
      CustomerPurchaseOrderDate,
      RecommendedServicePriority,
      ServiceDocumentUrgency            as ServiceRequestUrgency,
      ServiceDocumentImpact             as ServiceRequestImpact,
      ServiceDocumentProblemCategory    as ServiceRequestProblemCategory,
      ServiceDocumentIsRejected         as ServiceRequestIsCanceled,

      case ServiceDocumentStatus
      when 'C' then 'X'
      else ''
      end                               as ServiceRequestIsCompleted,

      SalesOrganization,
      DistributionChannel,
      Division,
      SalesOffice,
      SalesGroup,
      SoldToParty,
      ContactPerson                     as ServiceRequestReporter,
      /* ServiceDefectSchema,
         ServiceDefectCategory,
         ServiceReasonSchema,
         ServiceReasonCategory, */
      _Item.ResponseProfile             as ResponseProfile,
      _Item.ServiceProfile              as ServiceProfile,
      
      
       
       
       SalesOrganizationOrgUnitID,
       ServiceOrganization,
       SalesOfficeOrgUnitID,
       SalesGroupOrgUnitID,


      //Associations

      _PersonResponsible,
      _ReferenceObject,
      _Text,
      _Defect,
      _Reason,
      _Order

}

where
  ServiceObjectType = 'BUS2000223' // Service Request

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_SERVICEDOCUMENTENHCD",
"I_SERVICEDOCUMENTITEMENHCD"
],
"ASSOCIATED":
[
"A_SERVICEREQUESTDEFECT",
"A_SERVICEREQUESTORDER",
"A_SERVICEREQUESTPERSONRESP",
"A_SERVICEREQUESTREASON",
"A_SERVICEREQUESTREFOBJECT",
"A_SERVICEREQUESTTEXT",
"E_SERVICEDOCUMENT",
"I_SERVICEDOCUMENTITEMENHCD"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/