A_ServiceOrderTemplate

@ClientHandling.algorithm:#SESSION_VARIABLE
@EndUserText.label: 'Service Order Template'
@VDM: {
  viewType: #COMPOSITE,
  lifecycle.contract.type: #PUBLIC_REMOTE_API
}
@AbapCatalog: {
  sqlViewName: 'ASRVORDTMPL',
  compiler.compareFilter: true,
  preserveKey: true

}
@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}

@ObjectModel: {
   representativeKey: 'ServiceOrderTemplate',
   createEnabled: true,
   updateEnabled: true,
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #C,
     sizeCategory:   #L
   }
}
@Metadata.ignorePropagatedAnnotations: true

define view A_ServiceOrderTemplate
  as select from I_ServiceDocumentEnhcd as ServiceOrderTemplate

  association [0..*] to A_ServiceOrderTemplateItem   as _Item                  on  $projection.ServiceOrderTemplate = _Item.ServiceOrderTemplate
  association [0..*] to A_ServiceOrderTmplPersonResp as _PersonResponsible     on  $projection.ServiceOrderTemplate = _PersonResponsible.ServiceOrderTemplate

  association [0..*] to A_ServiceOrderTmplRefObject  as _ReferenceObject       on  $projection.ServiceOrderTemplate = _ReferenceObject.ServiceOrderTemplate
  association [0..*] to A_ServiceOrderTmplText       as _Text                  on  $projection.ServiceOrderTemplate = _Text.ServiceOrderTemplate

  //Extensibility

  association [0..1] to E_ServiceDocument            as _Extension             on  _Extension.ServiceCategory       = 'BUS2000116'
                                                                               and $projection.ServiceOrderTemplate = _Extension.ServiceOrder

  association [0..*] to A_SrvcOrdTmplUserStatus      as _SrvcOrdTmplUserStatus on  $projection.ServiceOrderTemplate = _SrvcOrdTmplUserStatus.ServiceOrderTemplate

  association [0..*] to A_SrvcOrdTmplPartner         as _Partner               on  $projection.ServiceOrderTemplate = _Partner.ServiceOrderTemplate

  association [0..*] to A_SrvcOrdTmplDuration        as _Duration              on  $projection.ServiceOrderTemplate = _Duration.ServiceOrderTemplate

  association [0..*] to A_SrvcOrdTmplAppointment     as _Appointment           on  $projection.ServiceOrderTemplate = _Appointment.ServiceOrderTemplate

{

  key  ServiceDocument            as ServiceOrderTemplate,
       ServiceDocumentUUID        as ServiceOrderTemplateUUID,
       @ObjectModel.sapObjectNodeTypeReference: 'ServiceDocumentType'
       ServiceDocumentType        as ServiceOrderTemplateType,
       ServiceObjectType,

       ServiceDocumentDescription as SrvcOrdTmplDescription,
       ServiceDocumentTemplateType,
       SrvcDocTemplateSearchTermText,

       Language,
       @ObjectModel.sapObjectNodeTypeReference: 'ServiceDocumentPriority'
       ServiceDocumentPriority,
       SrvcDocTmplValdtyStartDateTime,
       SrvcDocTmplValdtyEndDateTime,

       /* STATUS */
       ServiceDocumentIsReleased  as SrvcOrdTmplIsReleased,
       //case ServiceDocumentStatus

       //when 'C' then 'X'

       //else ''

       //end                        as SrvcOrdTmplIsCompleted,


       case ServiceDocumentIsOpen
       when '' then
       case ServiceDocumentIsReleased
       when '' then 'X' else ''
       end
       else ''
       end                        as SrvcOrdTmplIsCompleted,

       ServiceObjectType          as ServiceOrderType,
       ServiceDocumentType,

       /* ORG */
       /********************************************************/
       /*********  OP Specific Fields **************************/
       @feature: 'BF:API_FULLSCOPE'
       SalesOrganizationOrgUnitID,

       SalesOrganization,

       @feature: 'BF:API_FULLSCOPE'
       SalesOfficeOrgUnitID,

       @feature: 'BF:API_FULLSCOPE'
       SalesGroupOrgUnitID,

       @feature: 'BF:API_FULLSCOPE'
       @ObjectModel.sapObjectNodeTypeReference: 'EnterpriseServiceOrganization'
       EnterpriseServiceOrganization,
       /********************************************************/
       DistributionChannel,
       @ObjectModel.sapObjectNodeTypeReference: 'Division'
       Division,
       SalesOffice,
       SalesGroup,

       //Associations

       _Item,
       _PersonResponsible,
       _ReferenceObject,
       _Text,
       _SrvcOrdTmplUserStatus,
       //@feature: 'BF:API_FULLSCOPE'

       _Partner,
       _Duration,
       _Appointment
}
where
      ServiceObjectType           = 'BUS2000116' // Service Process

  and ServiceDocumentIsQuotation  is initial
  and ServiceDocumentTemplateType is not initial
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_SERVICEDOCUMENTENHCD"
],
"ASSOCIATED":
[
"A_SERVICEORDERTEMPLATEITEM",
"A_SERVICEORDERTMPLPERSONRESP",
"A_SERVICEORDERTMPLREFOBJECT",
"A_SERVICEORDERTMPLTEXT",
"A_SRVCORDTMPLAPPOINTMENT",
"A_SRVCORDTMPLDURATION",
"A_SRVCORDTMPLPARTNER",
"A_SRVCORDTMPLUSERSTATUS",
"E_SERVICEDOCUMENT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/