A_ServiceEntrySheetItem

@AbapCatalog.sqlViewName: 'ASRVCENTRSHTITM'
@AbapCatalog.compiler.compareFilter: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Item'
@VDM.viewType : #BASIC
@Metadata.ignorePropagatedAnnotations:true
@VDM.lifecycle.contract.type: #PUBLIC_REMOTE_API

@ObjectModel: {
   usageType.serviceQuality: #A,
   usageType.sizeCategory: #L,
   usageType.dataClass: #TRANSACTIONAL,
   createEnabled: false,
   updateEnabled: true,
   deleteEnabled: false
}
define view A_ServiceEntrySheetItem
  as select from I_ServiceEntrySheetItemBasic
  association [1..*] to A_SrvcEntrShtAcctAssignment as _AccountAssignment on  _AccountAssignment.ServiceEntrySheet     = $projection.ServiceEntrySheet
                                                                          and _AccountAssignment.ServiceEntrySheetItem = $projection.ServiceEntrySheetItem
  --Extension Association
  association [0..1] to E_ServiceEntrySheetItem     as _Extension         on  _Extension.ServiceEntrySheet     = $projection.ServiceEntrySheet
                                                                          and _Extension.ServiceEntrySheetItem = $projection.ServiceEntrySheetItem
{
  key ServiceEntrySheet,
  key ServiceEntrySheetItem,

      @ObjectModel.sapObjectNodeTypeReference: 'AccountAssignmentCategory'
      AccountAssignmentCategory,

      @Semantics.quantity.unitOfMeasure: 'QuantityUnit'
      ConfirmedQuantity,

      //  CreatedByUser,

      cast(CreatedByUser as mmpur_ses_createdbyuser preserving type )   as CreatedByUser,

      CreationDateTime,
      PurchasingOrganization,
      PurchasingGroup,
      Plant,

      @Semantics.currencyCode:true
      @ObjectModel.sapObjectNodeTypeReference: 'Currency'
      Currency,

      IsDeleted,
      LastChangeDateTime,
      //  LastChangeUser as LastChangedByUser,

      cast(LastChangeUser as mmpur_ses_lastchangeuser preserving type ) as LastChangedByUser,
      cast( ' ' as ismaterialgroupinitial) as SESItemMaterialGroupIsInitial,
      MaterialGroup,
      MultipleAcctAssgmtDistribution,

      @Semantics.amount.currencyCode: 'Currency'
      NetAmount,

      @Semantics.amount.currencyCode: 'Currency'
      NetPriceAmount,

      OriginObject,
      PurchaseOrder,
      PurchaseOrderItem,
      PurchaseContract,
      PurchaseContractItem,

      @Semantics.unitOfMeasure: true
      QuantityUnit,

      Service,
      ServiceEntrySheetItemDesc,
      ServiceEntrySheetItemUUID,
      ServiceEntrySheetUUID,
      ServicePerformanceDate,
      ServicePerformanceEndDate,
      ServicePerformer,
      WorkItem,
      PurgDocItemExternalReference,
      SESItemIsFinalEntry,

      cast( ' ' as istaxcodeinitial) as SESItemTaxCodeIsInitial,
      TaxCode,

      cast( ' ' as istaxcountrycodeinitial) as SESItemTaxCountryCodeIsInitial,
      TaxCountry,

      cast( ' ' as istaxjurisdictioncodeinitial) as SESItmTaxJurisdictionIsInitial,
      TaxJurisdiction,

      _AccountAssignment

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_SERVICEENTRYSHEETITEMBASIC"
],
"ASSOCIATED":
[
"A_SRVCENTRSHTACCTASSIGNMENT",
"E_SERVICEENTRYSHEETITEM"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/