A_ServiceContractItem

@ClientHandling.algorithm:#SESSION_VARIABLE
@EndUserText.label: 'Service Contract Item'
@VDM: {
  viewType: #CONSUMPTION,
  lifecycle.contract.type: #PUBLIC_REMOTE_API
}
@AbapCatalog: {
  sqlViewName: 'ASRVCTRITEM',
  compiler.compareFilter: true,
  preserveKey: true
}
@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@ObjectModel: {
   createEnabled: false,
   updateEnabled: false,
   deleteEnabled: false,
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #C,
     sizeCategory:   #L
   }
}
@Metadata.ignorePropagatedAnnotations: true
define view A_ServiceContractItem
  as select from I_ServiceDocumentItemEnhcd as ServiceContractItem

  association [1]    to A_ServiceContract              as _ServiceContract           on  $projection.ServiceContract = _ServiceContract.ServiceContract
  
  // Text

  association [0..*] to A_ServiceContractItemText      as _Text                      on  $projection.ServiceContract     = _Text.ServiceContract
                                                                                     and $projection.ServiceContractItem = _Text.ServiceContractItem
  // Billing Request Line                                                                                   

  association [0..*] to A_SrvcContrItmBillgReqItem     as _BillingRequestItem        on  $projection.ServiceContract     = _BillingRequestItem.ServiceContract
                                                                                     and $projection.ServiceContractItem = _BillingRequestItem.ServiceContractItem                                                                                     
  // Object List

  association [0..*] to A_ServiceContrItemObjectList   as _ObjectList                on  $projection.ServiceContract     = _ObjectList.ServiceContract
                                                                                     and $projection.ServiceContractItem = _ObjectList.ServiceContractItem
                                                                                     
  // Product List

  association [0..*] to A_SrvcContrItemProduct         as _ProductList               on  $projection.ServiceContract     = _ProductList.ServiceContract
                                                                                     and $projection.ServiceContractItem = _ProductList.ServiceContractItem

  // ReleasedOrder

  association [0..*] to A_ServiceContrItmReleasedOrder as _ReleasedOrder             on  $projection.ServiceContract     = _ReleasedOrder.ServiceContract
                                                                                     and $projection.ServiceContractItem = _ReleasedOrder.ServiceContractItem
  // Item Price Element                                                                                   

  association [0..*] to A_ServiceContrItemPriceElement as _PricingElement            on  $projection.ServiceContract = _PricingElement.ServiceContract
                                                                                     and $projection.ServiceContractItem = _PricingElement.ServiceContractItem
  // Change Document

  association [0..1] to I_ServiceDocumentItemEnhcd     as _ChgProcSourceItem         on  $projection.SrvcTransChgProcSourceItemUUID = _ChgProcSourceItem.ServiceDocumentItemUUID

  //Extensibility

  association [0..1] to E_ServiceDocumentItem          as _Extension                 on  _Extension.ServiceCategory      = 'BUS2000112'
                                                                                     and $projection.ServiceContract     = _Extension.ServiceOrderItem                                                                                     and $projection.ServiceContractItem = _Extension.ServiceLineExternalID
  //External ID

  // 0004 Service Contract External Reference

  // 0010 Service Quotation External Reference

  association [0..1] to I_CustMgmtExtRefID             as _ReferenceServiceContract  on  _ReferenceServiceContract.CustMgmtObjectType   = 'BUS2000112'
                                                                                     and $projection.ServiceContract                    = _ReferenceServiceContract.CustMgmtDocument
                                                                                     and $projection.ServiceContractItem                = _ReferenceServiceContract.CustMgmtDocumentItem
                                                                                     and _ReferenceServiceContract.CustMgmtExtRefIDType = '0004'

  association [0..1] to I_CustMgmtExtRefID             as _ReferenceServiceQtan      on  _ReferenceServiceQtan.CustMgmtObjectType   = 'BUS2000112'
                                                                                     and $projection.ServiceContract                = _ReferenceServiceQtan.CustMgmtDocument
                                                                                     and $projection.ServiceContractItem            = _ReferenceServiceQtan.CustMgmtDocumentItem
                                                                                     and _ReferenceServiceQtan.CustMgmtExtRefIDType = '0010'

{

      /* ORDERADM_I */
  key ServiceDocument                            as ServiceContract,
  key ServiceDocumentItem                        as ServiceContractItem,
      ServiceDocItemCategory                     as ServiceContractItemCategory,
      OriginallyRequestedProduct                 as Product,
      @Semantics: { quantity : {unitOfMeasure: 'QuantityUnit'} }
      ServiceDocumentItemQuantity                as Quantity,
      ServiceDocItemQuantityUnit                 as QuantityUnit,
      ServiceDocumentItemDescription             as ServiceContractItemDescription,
      Language,
      
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      ServiceDocItemGrossAmount,
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      ServiceDocumentItemNetAmount,
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      ServiceDocumentItemTaxAmount,
      TransactionCurrency,
       
      /* STATUS */
      ServiceDocumentItemIsReleased              as ServiceContractItemIsReleased,
      case ServiceDocumentItemStatus
      when 'C' then 'X'
      else ''
      end                                        as ServiceContractItemIsCompleted,

      ServiceDocumentItemCanclnParty             as ServiceContractItemCanclnParty,
      ServiceDocumentItmCanclnReason             as ServiceContractItmCanclnReason,

      SrvcDocItemCreditStatus                    as SrvcContrItemCreditStatus,

      cast ( 
      case ServiceDocumentItemCanclnParty
      when '' then 0
      else ServiceContrItemEndDateTime
      end    
      as crms4_cont_end_dec15 preserving type )  as ServiceContractItemCanclnDate,

      cast ( ServiceContrItemStartDateTime as crms4_cont_start_dec15 preserving type )  as ServiceContrItemStartDateTime,
      cast ( ServiceContrItemEndDateTime   as crms4_cont_end_dec15   preserving type )  as ServiceContrItemEndDateTime,
      
      // Item - Billing Plan

      _BillPlanDateRule.CustMgmtDateRuleName     as BillingPlanBillingDateRuleName,
      _SettlementDateRule.CustMgmtDateRuleName   as SettlementPeriodRuleName,
      BillingPlanPriceDateRule                   as BillingPlanPriceDateRule,
      BillingPlanIsFinalized,
      BillingBlockReason                         as BillingBlockReason,
      
      /* PARTNER */
      ShipToParty,
      ResponsibleEmployee                        as PersonResponsible,
      BillToParty,
      PayerParty,
      ContactPerson                              as ContactPerson,

      /* External ID */
      _ReferenceServiceContract.CustMgmtExtRefID as ReferenceServiceContractItem,
      _ReferenceServiceQtan.CustMgmtExtRefID     as ReferenceServiceQtanItem,

      ServiceDocumentRnwlDuration                as SrvcContrItemRnwlDuration,
      ServiceDocRnwlDurationUnit                 as SrvcContrItemRnwlDurationUnit,
      ServiceDocExtensionDuration                as SrvcContrItemExtensionDuration,
      ServiceDocExtnDurationUnit                 as SrvcContrItemExtnDurationUnit,

      SrvcTransChangeProcess,
      SrvcTransChangeProcessType,
      _ChgProcSourceItem.ServiceDocument         as SrvcTransChgProcSourceTransID,
      _ChgProcSourceItem.ServiceDocumentItem     as SrvcTransChgProcSourceItemID,
      SrvcTransChgProcSourceItemUUID, 
      ProfitCenter                               as ProfitCenter,
      
      //Associations

      _ServiceContract,
      _ObjectList,
      _ProductList,
      _ReleasedOrder,
      _Text,
      _BillingRequestItem,
      _PricingElement

}

where
      ServiceObjectType              = 'BUS2000112'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CUSTMGMTDATERULE",
"I_CUSTMGMTEXTREFID",
"I_SERVICEDOCUMENTITEMENHCD"
],
"ASSOCIATED":
[
"A_SERVICECONTRACT",
"A_SERVICECONTRACTITEMTEXT",
"A_SERVICECONTRITEMOBJECTLIST",
"A_SERVICECONTRITEMPRICEELEMENT",
"A_SERVICECONTRITMRELEASEDORDER",
"A_SRVCCONTRITEMPRODUCT",
"A_SRVCCONTRITMBILLGREQITEM",
"E_SERVICEDOCUMENTITEM",
"I_CUSTMGMTEXTREFID",
"I_SERVICEDOCUMENTITEMENHCD"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/