A_ServiceConfirmationItem

@ClientHandling.algorithm:#SESSION_VARIABLE
@EndUserText.label: 'Service Confirmation Item'
@VDM: {
  viewType: #COMPOSITE,
  lifecycle.contract.type: #PUBLIC_REMOTE_API
}
@AbapCatalog: {
  sqlViewName: 'ASRVCONITM',
  compiler.compareFilter: true,
  preserveKey: true
}
@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@ObjectModel: {
   createEnabled: true,
   updateEnabled: true,
   deleteEnabled: true,
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #C,
     sizeCategory:   #XXL
   }
}
@Metadata.ignorePropagatedAnnotations: true

define view A_ServiceConfirmationItem
  as select from I_ServiceDocumentItemEnhcd as ServiceConfirmationItem

  association [0..*] to A_ServiceConfirmationItemText as _Text                     on  $projection.ServiceConfirmation     = _Text.ServiceConfirmation
                                                                                   and $projection.ServiceConfirmationItem = _Text.ServiceConfirmationItem

  association [0..*] to A_ServiceConfItmRefObject     as _ReferenceObject          on  $projection.ServiceConfirmation     = _ReferenceObject.ServiceConfirmation
                                                                                   and $projection.ServiceConfirmationItem = _ReferenceObject.ServiceConfirmationItem

  association [1]    to A_ServiceConfItmRefSrvcOrd    as _RefServiceOrder          on  $projection.ServiceConfirmationItemUUID = _RefServiceOrder.ServiceConfirmationItemUUID

  association [0..1] to P_ServiceConfItmRefSrvcContr  as _RefServiceContract       on  $projection.ServiceConfirmationItemUUID = _RefServiceContract.ServiceConfirmationItemUUID

  association [0..*] to A_ServiceConfItemPriceElement as _PricingElement           on  $projection.ServiceConfirmation     = _PricingElement.ServiceConfirmation
                                                                                   and $projection.ServiceConfirmationItem = _PricingElement.ServiceConfirmationItem


  association [0..1] to I_RespyMgmtTeamHeaderDetail   as _ServiceTeamHeader        on  $projection.RespyMgmtServiceTeam = _ServiceTeamHeader.RespyMgmtTeamID

  association [1]    to A_ServiceConfirmation         as _ServiceConfirmation      on  $projection.ServiceConfirmation = _ServiceConfirmation.ServiceConfirmation
  //Extensibility

  association [0..1] to E_ServiceDocumentItem         as _Extension                on  _Extension.ServiceCategory          = 'BUS2000117'
                                                                                   and $projection.ServiceConfirmation     = _Extension.ServiceOrderItem
                                                                                   and $projection.ServiceConfirmationItem = _Extension.ServiceLineExternalID

  //External ID

  association [0..1] to I_CustMgmtExtRefID            as _CustMgmtExtRef           on  _CustMgmtExtRef.CustMgmtObjectType  = 'BUS2000117'
                                                                                   and $projection.ServiceConfirmation     = _CustMgmtExtRef.CustMgmtDocument
                                                                                   and $projection.ServiceConfirmationItem = _CustMgmtExtRef.CustMgmtDocumentItem


  //association [0..1] to I_ContingentWorker as _ServicePerformer on $projection.ServicePerformer = _ServicePerformer.BusinessPartner

  association [0..1] to I_CustMgmtPartner             as _ServicePerformer         on  CustMgmtPartnerFunction             = '00000028'
                                                                                   and CustMgmtPartFunctionCategory        = '0091'
                                                                                   and $projection.ServiceConfirmation     = _ServicePerformer.CustMgmtDocument
                                                                                   and $projection.ServiceConfirmationItem = _ServicePerformer.CustMgmtDocumentItem

  association [0..*] to A_ServiceConfItemUserStatus   as _SrvcConfItemUserStatus   on  $projection.ServiceConfirmation     = _SrvcConfItemUserStatus.ServiceConfirmation
                                                                                   and $projection.ServiceConfirmationItem = _SrvcConfItemUserStatus.ServiceConfirmationItem

  association [0..*] to A_SrvcConfItemPartner         as _Partner                  on  $projection.ServiceConfirmation     = _Partner.ServiceConfirmation
                                                                                   and $projection.ServiceConfirmationItem = _Partner.ServiceConfirmationItem

  association [0..*] to A_SrvcConfItemDuration        as _Duration                 on  $projection.ServiceConfirmation     = _Duration.ServiceConfirmation
                                                                                   and $projection.ServiceConfirmationItem = _Duration.ServiceConfirmationItem

  association [0..*] to A_SrvcConfItemAppointment     as _Appointment              on  $projection.ServiceConfirmation     = _Appointment.ServiceConfirmation
                                                                                   and $projection.ServiceConfirmationItem = _Appointment.ServiceConfirmationItem
  association [0..1] to I_WBSElementBasicData         as _WBSElement               on  _WBSElement.WBSElementInternalID = ServiceConfirmationItem.WBSElementInternalID

  association [0..*] to A_SrvcConfItemSerialNumber    as _SrvcConfItemSerialNumber on  $projection.ServiceConfirmation     = _SrvcConfItemSerialNumber.ServiceConfirmation
                                                                                   and $projection.ServiceConfirmationItem = _SrvcConfItemSerialNumber.ServiceConfirmationItem

{

      /* ORDERADM_I */
  key ServiceDocument                                     as ServiceConfirmation,
  key ServiceDocumentItem                                 as ServiceConfirmationItem,
      ServiceDocumentItemUUID                             as ServiceConfirmationItemUUID,
      ServiceDocumentItemDescription                      as ServiceConfItemDescription,
      ServiceObjectType,
      ServiceDocumentItemObjectType,
      Language,
      OriginallyRequestedProduct                          as Product,
      @Semantics: { quantity : {unitOfMeasure: 'QuantityUnit'} }
      ServiceDocumentItemQuantity                         as Quantity,
      ServiceDocItemQuantityUnit                          as QuantityUnit,
      ActualServiceDuration,
      ActualServiceDurationUnit,
      @ObjectModel.sapObjectNodeTypeReference: 'ServiceDocumentItemCategory'
      ServiceDocItemCategory                              as ServiceConfItemCategory,
      //case ServiceDocumentItemStatus

      //when 'C' then 'X'

      //else ''

      //end                                        as ServiceConfItemIsCompleted,


      case ServiceDocumentItemIsOpen
       when '' then
       case ServiceDocumentItemIsReleased
       when '' then 'X' else ''
       end
       else ''
       end                                                as ServiceConfItemIsCompleted,

      ServiceEmployee                                     as ExecutingServiceEmployee,
      _ServicePerformer.CustMgmtPartner                   as ServicePerformer,
      BillableControl,

      _RefServiceOrder.ReferenceServiceOrder              as ReferenceServiceOrder,
      _RefServiceOrder.ReferenceServiceOrderItem          as ReferenceServiceOrderItem,


      cast('' as crms4_is_unplanned_item preserving type) as RefSrvcOrdItemIsUnplanned,

      _RefServiceContract.ReferenceServiceContract        as ReferenceServiceContract,
      _RefServiceContract.ReferenceServiceContractItem    as ReferenceServiceContractItem,

      /* Shipping */
      ShippingCondition,
      RequestedDeliveryUTCDateTime                        as ErlstRequestedDeliveryDateTime,

      // Start of 1908 CE

      _ParentServiceDocItem.ServiceDocumentItem           as ParentServiceConfItem,
      //ServiceConfirmationItem.RequestedServiceStartDateTime                                                         as  RequestedServiceStartDateTime,

      //ServiceConfirmationItem.RequestedServiceEndDateTime                                                           as  RequestedServiceEndDateTime,

      ActualServiceStartDateTime,
      ActualServiceEndDateTime,
      ServicesRenderedDate,
      // End of 1908 CE


      _CustMgmtExtRef.CustMgmtExtRefID                    as FSMServiceConfirmationItem,

      //Inheritance of complex set

      @ObjectModel.readOnly: true
      SrvcDocItmPartReferenceItem,
      @ObjectModel.readOnly: true
      SrvcDocItmApptReferenceItem,
      @ObjectModel.readOnly: true
      SrvcDocItmApptRefObjectUUID,

      /********************************************************/
      /*********  Cloud Specific Fields **************************/
      //@feature: 'BF:API_ESSENTIALSCOPE'

      TimeSheetOvertimeCategory,

      //Service Team

      //@ObjectModel.editableFieldFor: 'RespyMgmtServiceTeamName'

      //@feature: 'BF:API_ESSENTIALSCOPE'

      RespyMgmtServiceTeam,

      //@feature: 'BF:API_ESSENTIALSCOPE'

      @ObjectModel.readOnly: true
      _ServiceTeamHeader.TeamName                         as RespyMgmtServiceTeamName,

      @Feature: 'BF:API_ESSENTIALSCOPE'
      cast(0 as vfprc_element_amount)                     as SrvcConfItmCndnRateAmount,
      @Feature: 'BF:API_ESSENTIALSCOPE'
      cast('' as waers)                                   as SrvcConfItmCndnRateCurrency,

      //@feature: 'BF:API_ESSENTIALSCOPE'

      _ServiceTeamHeader.RespyMgmtGlobalTeamID            as RespyMgmtGlobalTeamID,

      //@Feature: 'BF:API_ESSENTIALSCOPE'

      @ObjectModel.sapObjectNodeTypeReference: 'PaymentTerms'
      PaymentTerms,
      @ObjectModel.sapObjectNodeTypeReference: 'PaymentMethod'
      PaymentMethod,
      //@Feature: 'BF:API_ESSENTIALSCOPE'

      SEPAMandate,
      //@Feature: 'BF:API_ESSENTIALSCOPE'

      @ObjectModel.readOnly: true
      @ObjectModel.sapObjectNodeTypeReference: 'SrvcSEPAMandateRelevance'
      SrvcSEPAMandateRelevance,

      //      @Feature: 'BF:API_ESSENTIALSCOPE'

      _WBSElement.WBSElementExternalID,

      /********************************************************/
      /*********  OP Specific Fields **************************/

      @Feature: 'BF:API_FULLSCOPE'
      ServiceTransactionChargeType,
      @Feature: 'BF:API_FULLSCOPE'
      SrvcTransactionValuationType,
      @Feature: 'BF:API_FULLSCOPE'
      ContractAccount,

      /********************************************************/
      //Associations

      _ReferenceObject,
      _Text,
      _PricingElement,
      _ServiceConfirmation,
      _SrvcConfItemUserStatus,
      //@feature: 'BF:API_FULLSCOPE'

      _Partner,
      _Duration,
      _Appointment,
      _SrvcConfItemSerialNumber
}

where
  ServiceObjectType = 'BUS2000117' //  Service Confirmation

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"A_SERVICECONFITMREFSRVCORD",
"I_CUSTMGMTEXTREFID",
"I_CUSTMGMTPARTNER",
"I_RESPYMGMTTEAMHEADERDETAIL",
"I_SERVICEDOCUMENTITEMENHCD",
"I_WBSELEMENTBASICDATA",
"P_SERVICECONFITMREFSRVCCONTR"
],
"ASSOCIATED":
[
"A_SERVICECONFIRMATION",
"A_SERVICECONFIRMATIONITEMTEXT",
"A_SERVICECONFITEMPRICEELEMENT",
"A_SERVICECONFITEMUSERSTATUS",
"A_SERVICECONFITMREFOBJECT",
"A_SERVICECONFITMREFSRVCORD",
"A_SRVCCONFITEMAPPOINTMENT",
"A_SRVCCONFITEMDURATION",
"A_SRVCCONFITEMPARTNER",
"A_SRVCCONFITEMSERIALNUMBER",
"E_SERVICEDOCUMENTITEM",
"I_CUSTMGMTEXTREFID",
"I_CUSTMGMTPARTNER",
"I_RESPYMGMTTEAMHEADERDETAIL",
"I_WBSELEMENTBASICDATA",
"P_SERVICECONFITMREFSRVCCONTR"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/