A_SalesQuotation

@ClientHandling.algorithm:#SESSION_VARIABLE
@EndUserText.label: 'Sales Quotation Header'
@VDM: {
  viewType: #COMPOSITE,
  lifecycle.contract.type: #PUBLIC_REMOTE_API
}
@AbapCatalog: {
  sqlViewName: 'ASALESQUOTATION',
  compiler.compareFilter: true
}
@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@ObjectModel: {
   representativeKey: 'Salesquotation',
   createEnabled: true,
   updateEnabled: true,
   deleteEnabled: true,
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #C,
     sizeCategory:   #XL
   }
}
@Metadata.ignorePropagatedAnnotations: true

define view A_SalesQuotation
  as select from I_SalesQuotationEnhanced as SalesQuotation

  association [0..*] to A_SalesQuotationItem      as _Item           on _Item.SalesQuotation = $projection.SalesQuotation

  association [0..*] to A_SalesQuotationPartner   as _Partner        on _Partner.SalesQuotation = $projection.SalesQuotation

  association [0..*] to A_SalesQuotationPrcgElmnt as _PricingElement on _PricingElement.SalesQuotation = $projection.SalesQuotation

  association [0..*] to A_SalesQuotationText      as _Text           on _Text.SalesQuotation = $projection.SalesQuotation
  
  association [0..*] to A_SalesQuotationRelatedObject  as _RelatedObject          on _RelatedObject.SalesQuotation = $projection.SalesQuotation
  
  association [0..*] to A_SlsQtanPrecdgProcFlow        as _PrecedingProcFlowDoc   on _PrecedingProcFlowDoc.SalesQuotation = $projection.SalesQuotation
  
  association [0..*] to A_SlsQtanSubsqntProcFlow       as _SubsequentProcFlowDoc  on _SubsequentProcFlowDoc.SalesQuotation = $projection.SalesQuotation
  //Extensibility

  association [0..1] to E_SalesDocumentBasic      as _Extension      on $projection.SalesQuotation = _Extension.SalesDocument

{

  key SalesQuotation,

      @ObjectModel.sapObjectNodeTypeReference: 'SalesQuotationType'
      SalesQuotationType,

      SalesOrganization,
      DistributionChannel,
      OrganizationDivision,

      SalesGroup,
      SalesOffice,
      SalesDistrict,

      SoldToParty,

      @ObjectModel.readOnly: true
      CreationDate,

      @ObjectModel.readOnly: true
      CreatedByUser,

      @ObjectModel.readOnly: true
      LastChangeDate,

      @ObjectModel.readOnly: true
      case TSTMP_IS_VALID(LastChangeDateTime)
        when 0 then cast( dats_tims_to_tstmp( CreationDate, CreationTime, 'UTC', $session.client, 'NULL' ) as timestampl )
        else LastChangeDateTime
      end as LastChangeDateTime,

      PurchaseOrderByCustomer,
      CustomerPurchaseOrderType,
      CustomerPurchaseOrderDate,

      SalesQuotationDate,

      @ObjectModel.readOnly: true
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      TotalNetAmount,

      @Semantics.currencyCode: true
      TransactionCurrency,

      @ObjectModel.sapObjectNodeTypeReference: 'SalesDocumentReason'
      SDDocumentReason,
      PricingDate,

      RequestedDeliveryDate,
      ShippingCondition,
      CompleteDeliveryIsDefined,
      ShippingType,

      HeaderBillingBlockReason,
      DeliveryBlockReason,

      BindingPeriodValidityStartDate,
      BindingPeriodValidityEndDate,

      @ObjectModel.readOnly: true
      HdrOrderProbabilityInPercent,

      @ObjectModel.readOnly: true
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      ExpectedOrderNetAmount,

      @ObjectModel.sapObjectNodeTypeReference: 'IncotermsClassification'
      IncotermsClassification,
      IncotermsTransferLocation,
      IncotermsLocation1,
      IncotermsLocation2,
      @ObjectModel.sapObjectNodeTypeReference: 'IncotermsVersion'
      IncotermsVersion,
      CustomerPaymentTerms,
      @ObjectModel.sapObjectNodeTypeReference: 'CustomerPriceGroup'
      CustomerPriceGroup, 
      PriceListType,
      @ObjectModel.sapObjectNodeTypeReference: 'PaymentMethod'
      PaymentMethod,

     //Tax Classfication

      @ObjectModel.sapObjectNodeTypeReference: 'CustomerTaxClassification'
      CustomerTaxClassification1,
      @ObjectModel.sapObjectNodeTypeReference: 'CustomerTaxClassification'
      CustomerTaxClassification2,
      @ObjectModel.sapObjectNodeTypeReference: 'CustomerTaxClassification'
      CustomerTaxClassification3,
      @ObjectModel.sapObjectNodeTypeReference: 'CustomerTaxClassification'
      CustomerTaxClassification4,
      @ObjectModel.sapObjectNodeTypeReference: 'CustomerTaxClassification'
      CustomerTaxClassification5,
      @ObjectModel.sapObjectNodeTypeReference: 'CustomerTaxClassification'
      CustomerTaxClassification6,
      @ObjectModel.sapObjectNodeTypeReference: 'CustomerTaxClassification'
      CustomerTaxClassification7,
      @ObjectModel.sapObjectNodeTypeReference: 'CustomerTaxClassification'
      CustomerTaxClassification8,
      @ObjectModel.sapObjectNodeTypeReference: 'CustomerTaxClassification'
      CustomerTaxClassification9,

      ReferenceSDDocument,
      @ObjectModel.readOnly: true
      ReferenceSDDocumentCategory,

      @ObjectModel.readOnly: true
      SalesQuotationApprovalReason,
      @ObjectModel.readOnly: true
      @ObjectModel.sapObjectNodeTypeReference: 'SalesDocApprovalStatus'
      SalesDocApprovalStatus,

      @ObjectModel.readOnly: true
      @ObjectModel.sapObjectNodeTypeReference: 'OverallSDProcessStatus'
      OverallSDProcessStatus,

      @ObjectModel.readOnly: true
      @ObjectModel.sapObjectNodeTypeReference: 'TotalCreditCheckStatus'
      TotalCreditCheckStatus,

      @ObjectModel.readOnly: true
      @ObjectModel.sapObjectNodeTypeReference: 'OverallSDDocumentRejectionSts'
      OverallSDDocumentRejectionSts,
      


      //       Expose own associations

      _Item,
      _Partner,
      _PricingElement,
      _Text,
      _RelatedObject,
      _PrecedingProcFlowDoc,
      _SubsequentProcFlowDoc
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_SALESQUOTATIONENHANCED"
],
"ASSOCIATED":
[
"A_SALESQUOTATIONITEM",
"A_SALESQUOTATIONPARTNER",
"A_SALESQUOTATIONPRCGELMNT",
"A_SALESQUOTATIONRELATEDOBJECT",
"A_SALESQUOTATIONTEXT",
"A_SLSQTANPRECDGPROCFLOW",
"A_SLSQTANSUBSQNTPROCFLOW",
"E_SALESDOCUMENTBASIC"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/