A_SalesContractPartner

@ClientHandling.algorithm:#SESSION_VARIABLE
@EndUserText.label: 'Header Partner'
@VDM: {
  viewType: #COMPOSITE,
  lifecycle.contract.type: #PUBLIC_REMOTE_API
}
@AbapCatalog: {
  sqlViewName: 'ASCPARTNER',
  compiler.compareFilter: true
}
@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@ObjectModel: {
   createEnabled: true,
   updateEnabled: true,
   deleteEnabled: true,
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #C,
     sizeCategory:   #XL
   }
}
@Metadata.ignorePropagatedAnnotations: true

define view A_SalesContractPartner
  as select from I_SDDocumentPartner  as Partner
    inner join   I_SalesDocumentBasic as SalesContract on  SalesContract.SalesDocument      = Partner.SDDocument // needed for DCL

                                                       and SalesContract.SDDocumentCategory = 'G'

  association [1..1] to A_SalesContract  as _SalesContract            on  _SalesContract.SalesContract = $projection.SalesContract

  association [0..1] to I_BusPartAddress as _BusinessPartnerAddressCP on  Partner.AddressID                  = _BusinessPartnerAddressCP.AddressID
                                                                      and $projection.ContactPerson          is not initial
                                                                      and Partner.SDDocPartnerAddressRefType = 'I'

{
      @ObjectModel.readOnly: true
  key cast(SalesDocument as sales_contract preserving type)                           as SalesContract,
      @ObjectModel.sapObjectNodeTypeReference: 'PartnerFunction'
  key PartnerFunction,

      Customer,

      Supplier,

      Personnel,

      ContactPerson,

      @Feature: 'SW:Q2C_MULTIPLE_BP_ADDRESSES, SW:Q2C_MULTIPLE_BP_ADDRESSES2'
      case ContactPerson
              when '0000000000' then
               _BusinessPartnerAddress.AddressUUID
             else
               _BusinessPartnerAddressCP.AddressUUID
                                                          end                         as BusinessPartnerAddressUUID,
      @Feature: 'SW:Q2C_MULTIPLE_BP_ADDRESSES, SW:Q2C_MULTIPLE_BP_ADDRESSES2'
      @ObjectModel.readOnly: true
      _BPRefAddressForDocSpcfcAddr.AddressUUID                                        as BPRefAddrForDocSpcfcAddrUUID,

      // For Access control

      @Consumption.hidden: true
      @ObjectModel.sapObjectNodeTypeReference: 'SalesContractType'
      cast ( SalesContract.SalesDocumentType as sales_contract_type preserving type ) as SalesContractType,
      @Consumption.hidden: true
      SalesContract.OrganizationDivision,
      @Consumption.hidden: true
      SalesContract.SalesOrganization,
      @Consumption.hidden: true
      SalesContract.DistributionChannel,

      //Expose associations

      _SalesContract
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BUSPARTADDRESS",
"I_SALESDOCUMENTBASIC",
"I_SDDOCUMENTPARTNER"
],
"ASSOCIATED":
[
"A_SALESCONTRACT",
"I_BUSPARTADDRESS"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/