A_Recipe

@AbapCatalog.sqlViewName: 'ARECIPE'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true

@AccessControl.authorizationCheck: #CHECK

@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.dataClass: #MASTER

@VDM.viewType: #CONSUMPTION
@VDM.lifecycle.contract.type: #PUBLIC_REMOTE_API

@Metadata.ignorePropagatedAnnotations: true

@Consumption.filter.businessDate.at: true

@EndUserText.label: 'Recipe Header Data'
define root view A_Recipe
  with parameters
    @Consumption.hidden: true
    @Semantics.businessDate.at: true
    P_KeyDate : sydate
  as select from I_RecipeForKeyDateTP( P_KeyDate: $parameters.P_KeyDate )
  composition [0..*] of A_RecipeText               as _RecipeText
  composition [1..*] of A_RecipeFormulaItem        as _FormulaItem

  // Classification integration

  association [0..*] to A_RecipeClass              as _Classification           on  $projection.RecipeUUID = _Classification.RecipeUUID
  association [0..*] to A_RecipeCharc              as _Characteristics          on  $projection.RecipeUUID = _Characteristics.RecipeUUID

  // Access Control Management integration

  association [0..1] to A_LogAccMObjectTypeActive  as _LogAccMObjectTypeActive  on  _LogAccMObjectTypeActive.LogAccMObjectType = 'PLM_RCP'
  association [0..*] to A_LogAccMObjSecureIDAssgmt as _LogAccMObjSecureIDAssgmt on  $projection.RecipeUniqueID                  = _LogAccMObjSecureIDAssgmt.LogAccMObjectID
                                                                                and _LogAccMObjSecureIDAssgmt.LogAccMObjectType = 'PLM_RCP'
  association [0..*] to A_LogAccMObjectUserAuthzn  as _LogAccMObjectUserAuthzn  on  $projection.RecipeUniqueID                       = _LogAccMObjectUserAuthzn.LogAccMObjectID
                                                                                and _LogAccMObjectUserAuthzn.LogAccMObjectType       = 'PLM_RCP'
                                                                                and _LogAccMObjectUserAuthzn.LogAccMUserAuthznObject = 'PLM_RCP'
                                                                                and (
                                                                                   _LogAccMObjectUserAuthzn.LogAccMUserAuthznFrom    = '03'
                                                                                   or _LogAccMObjectUserAuthzn.LogAccMUserAuthznFrom = '*'
                                                                                 )
                                                                                and _LogAccMObjectUserAuthzn.LogAccMUserAuthznField  = 'ACTVT'
                                                                                and (
                                                                                   _LogAccMObjectUserAuthzn.LogAccMUserEntityID      = $session.user
                                                                                   or _LogAccMObjectUserAuthzn.UserID                = $session.user
                                                                                 )
  association [1..1] to E_Recipe                   as _Extension                on  $projection.RecipeUUID = _Extension.RecipeUUID

  composition [0..*] of A_RecipeProcessElement     as _RecipeProcessElement
  composition [0..*] of A_RecipeProcessEquipRqmt   as _RecipeProcessEquipRqmt
  composition [0..*] of A_RecipeProcessParamValue  as _RecipeProcessParamValue

{
      @ObjectModel.text.association: '_RecipeText'
  key RecipeUUID,

      RecipeUniqueID,
      Recipe,
      RecipePrimaryOutputInternalID,
      RecipePrimaryOutput,
      RecipeAlternativeNumber,
      RecipeVersionNumber,

      RecipeType,
      RecipePurpose,
      RecipeStatus,
      RecipeStatusSchema,
      RecipeAuthorizationGroup,

      RcpFmlaUUID,
      RecipeProcessUUID,
      RecipeValidityStartDate,
      RecipeValidityEndDate,

      @Semantics.quantity.unitOfMeasure: 'RecipeValidityUnit'
      RecipeValidityMinQuantity,
      @Semantics.quantity.unitOfMeasure: 'RecipeValidityUnit'
      RecipeValidityMaxQuantity,
      @Semantics.unitOfMeasure: true
      RecipeValidityUnit,

      _Plant.Plant,

      RecipeCreatedByUser,
      RecipeLastChangedByUser,
      RecipeCreationDateTime,
      RecipeLastChangeDateTime,

      RecipeIsDeleted,
      RecipeIsArchived,
      RecipePrimOutpAuthznGrp,
      RecipePrimOutpSpecType,

      _RecipeText,
      _FormulaItem,
      _Classification,
      _Characteristics,

      _LogAccMObjectTypeActive,
      _LogAccMObjectUserAuthzn,
      _LogAccMObjSecureIDAssgmt,

      _RecipeProcessElement,
      _RecipeProcessEquipRqmt,
      _RecipeProcessParamValue

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_RECIPEASSGDPLANT",
"I_RECIPEFORKEYDATETP"
],
"ASSOCIATED":
[
"A_LOGACCMOBJECTTYPEACTIVE",
"A_LOGACCMOBJECTUSERAUTHZN",
"A_LOGACCMOBJSECUREIDASSGMT",
"A_RECIPECHARC",
"A_RECIPECLASS",
"A_RECIPEFORMULAITEM",
"A_RECIPEPROCESSELEMENT",
"A_RECIPEPROCESSEQUIPRQMT",
"A_RECIPEPROCESSPARAMVALUE",
"A_RECIPETEXT",
"E_RECIPE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/