A_RecProcParamValCharc

@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.sqlViewName: 'ANGCRPPCLFN3'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@VDM.viewType: #CONSUMPTION
@VDM.lifecycle.contract.type: #PUBLIC_REMOTE_API
@Metadata.ignorePropagatedAnnotations: true

@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.dataClass: #MIXED
@Consumption.filter.businessDate.at: true

@EndUserText.label: 'Recipe Process Parameter Value Characteristic Assignments'
define view A_RecProcParamValCharc 
  with parameters
    @Consumption.hidden: true
    @Semantics.businessDate.at: true
    P_KeyDate:sydate
  as select distinct from I_ClfnObjectCharcForKeyDate( P_KeyDate: $parameters.P_KeyDate ) as Characteristics
     join A_RecipeProcessParamValue( P_KeyDate: $parameters.P_KeyDate ) as RecipeProcessParamValue on
          Characteristics.ClfnObjectID = bintohex( RecipeProcessParamValue.RecipeProcessParamValUUID )

    association [0..*] to A_RecProcParamValCharcValue as _Valuation on
      $projection.RecipeProcessParamValUUID = _Valuation.RecipeProcessParamValUUID and
      $projection.CharcInternalID = _Valuation.CharcInternalID and
      $projection.ClassType = _Valuation.ClassType
    association [1..*] to A_RecProcParamValClassCharc as _ClassCharacteristics on
      $projection.RecipeProcessParamValUUID = _ClassCharacteristics.RecipeProcessParamValUUID and
      $projection.CharcInternalID = _ClassCharacteristics.CharcInternalID and
      $projection.ClassType = _ClassCharacteristics.ClassType
    association [1..1] to A_RecipeProcessParamValue as _RecipeProcessParamValue on
      $projection.RecipeProcessParamValUUID  = _RecipeProcessParamValue.RecipeProcessParamValUUID   
  {
    key RecipeProcessParamValue.RecipeProcessParamValUUID,
    key Characteristics.CharcInternalID,
    key Characteristics.ClassType,
    
    $parameters.P_KeyDate as KeyDate,
    
    @Consumption.hidden: true
    _Characteristic(P_KeyDate: $parameters.P_KeyDate).CharcMaintAuthGrp,
    
    _Valuation,
    _ClassCharacteristics,
    _RecipeProcessParamValue
  }
    where
      ClfnObjectTable = '/PLMB/RPR_PP_VAL' and
      ClfnObjectType = 'O'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"A_RECIPEPROCESSPARAMVALUE",
"I_CLFNCHARACTERISTICFORKEYDATE",
"I_CLFNOBJECTCHARCFORKEYDATE"
],
"ASSOCIATED":
[
"A_RECIPEPROCESSPARAMVALUE",
"A_RECPROCPARAMVALCHARCVALUE",
"A_RECPROCPARAMVALCLASSCHARC"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/