A_RecProcEquipRqmtCharc

@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.sqlViewName: 'ANGCRERCLFN3'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@VDM.viewType: #CONSUMPTION
@VDM.lifecycle.contract.type: #PUBLIC_REMOTE_API
@Metadata.ignorePropagatedAnnotations: true

@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.dataClass: #MIXED
@Consumption.filter.businessDate.at: true 

@EndUserText.label: 'Recipe Equipment Requirement Characteristic Assignments'
define view A_RecProcEquipRqmtCharc  
  with parameters
    @Consumption.hidden: true
    @Semantics.businessDate.at: true
    P_KeyDate:sydate
  as select distinct from I_ClfnObjectCharcForKeyDate( P_KeyDate: $parameters.P_KeyDate ) as Characteristics
     join A_RecipeProcessEquipRqmt( P_KeyDate: $parameters.P_KeyDate ) as RecipeProcessEquipRqmt on
          Characteristics.ClfnObjectID = bintohex( RecipeProcessEquipRqmt.RecipeProcessEquipRqmtUUID )
  
    association [0..*] to A_RecProcEquipRqmtCharcValue as _Valuation on
      $projection.RecipeProcessEquipRqmtUUID = _Valuation.RecipeProcessEquipRqmtUUID and
      $projection.CharcInternalID = _Valuation.CharcInternalID and
      $projection.ClassType = _Valuation.ClassType
    association [1..*] to A_RecProcEquipRqmtClassCharc as _ClassCharacteristics on
      $projection.RecipeProcessEquipRqmtUUID = _ClassCharacteristics.RecipeProcessEquipRqmtUUID and
      $projection.CharcInternalID = _ClassCharacteristics.CharcInternalID and
      $projection.ClassType = _ClassCharacteristics.ClassType
    association [1..1] to A_RecipeProcessEquipRqmt as _RecipeProcessEquipRqmt on
      $projection.RecipeProcessEquipRqmtUUID = _RecipeProcessEquipRqmt.RecipeProcessEquipRqmtUUID
  {
    key RecipeProcessEquipRqmt.RecipeProcessEquipRqmtUUID,
    key Characteristics.CharcInternalID,
    key Characteristics.ClassType,
    
    $parameters.P_KeyDate as KeyDate,
    
    @Consumption.hidden: true
    _Characteristic(P_KeyDate: $parameters.P_KeyDate).CharcMaintAuthGrp,
    
    _Valuation,
    _ClassCharacteristics,
    _RecipeProcessEquipRqmt
  }
    where
      ClfnObjectTable = '/PLMB/RPR_EQR' and
      ClfnObjectType = 'O'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"A_RECIPEPROCESSEQUIPRQMT",
"I_CLFNCHARACTERISTICFORKEYDATE",
"I_CLFNOBJECTCHARCFORKEYDATE"
],
"ASSOCIATED":
[
"A_RECIPEPROCESSEQUIPRQMT",
"A_RECPROCEQUIPRQMTCHARCVALUE",
"A_RECPROCEQUIPRQMTCLASSCHARC"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/