A_PurgInfoRecdOrgPlantData

@AbapCatalog.sqlViewName: 'APINPLORG'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@VDM.viewType : #BASIC
@EndUserText.label: 'Purchasing Info Record Purch. Org. Data'
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.sizeCategory: #L
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.lifecycle.contract.type:#PUBLIC_REMOTE_API
@ObjectModel.createEnabled: true
@ObjectModel.updateEnabled: true

define view A_PurgInfoRecdOrgPlantData
  as select from I_PurgInfoRecdOrgPlantData

  association [1..1] to A_PurchasingInfoRecord as _PurgInfoRecd on $projection.PurchasingInfoRecord = _PurgInfoRecd.PurchasingInfoRecord
  association [0..*] to A_PurInfoRecdPrcgCndnValidity as _PurInfoRecdPrcgCndnValidity  on $projection.PurchasingInfoRecord  = _PurInfoRecdPrcgCndnValidity.PurchasingInfoRecord
                                                                  and  $projection.PurchasingInfoRecordCategory = _PurInfoRecdPrcgCndnValidity.PurchasingInfoRecordCategory
                                                                  and $projection.PurchasingOrganization = _PurInfoRecdPrcgCndnValidity.PurchasingOrganization
  association [0..*] to A_PurgInfoRecdOrgPOText as _PurInfoRecdPurOrgText on  $projection.PurchasingInfoRecord = _PurInfoRecdPurOrgText.PurchasingInfoRecord
                                                                 and  $projection.PurchasingInfoRecordCategory = _PurInfoRecdPurOrgText.PurchasingInfoRecordCategory
                                                                 and  $projection.PurchasingOrganization = _PurInfoRecdPurOrgText.PurchasingOrganization
                                                                 and  $projection.Plant = _PurInfoRecdPurOrgText.Plant

{

  key PurchasingInfoRecord,

  key PurchasingInfoRecordCategory,

  key PurchasingOrganization,

  key Plant,

      CreatedByUser,

      IsMarkedForDeletion,
      @ObjectModel.sapObjectNodeTypeReference: 'PurchasingGroup'
      PurchasingGroup,
      @ObjectModel.sapObjectNodeTypeReference: 'Currency'
      Currency,
      @Semantics.quantity.unitOfMeasure: 'PurchaseOrderPriceUnit'
      MinimumPurchaseOrderQuantity,
      @Semantics.quantity.unitOfMeasure: 'PurchaseOrderPriceUnit'
      StandardPurchaseOrderQuantity,

      MaterialPlannedDeliveryDurn,

      OverdelivTolrtdLmtRatioInPct,

      UnderdelivTolrtdLmtRatioInPct,

      UnlimitedOverdeliveryIsAllowed,

      LastReferencingPurchaseOrder,

      LastReferencingPurOrderItem,

      _PurgInfoRecd.Material                            as Material,
      _PurgInfoRecd.Supplier                            as Supplier,
      _PurgInfoRecd.MaterialGroup                       as MaterialGroup,
      _PurgInfoRecd.PurgDocOrderQuantityUnit            as PurgDocOrderQuantityUnit,
      
      @ObjectModel: {
        readOnly: true,
        virtualElement: true,
        virtualElementCalculatedBy: 'CL_INFOREC_NETPRICE_API_EXIT'
      }
      cast(NetPriceAmount as abap.sstring(50))          as NetPriceQuantityUnit,
      @Semantics.amount.currencyCode: 'Currency'
      NetPriceAmount,
      @Semantics.quantity.unitOfMeasure: 'PurchaseOrderPriceUnit'
      MaterialPriceUnitQty,

      PurchaseOrderPriceUnit,

      PriceValidityEndDate,
      
      @ObjectModel.sapObjectNodeTypeReference: 'PurchasingShippingInstruction'
      ShippingInstruction,

      InvoiceIsGoodsReceiptBased,
      @ObjectModel.sapObjectNodeTypeReference: 'SalesTaxCode'
      TaxCode,
      
      @ObjectModel.sapObjectNodeTypeReference: 'IncotermsClassification'
      IncotermsClassification,

      IncotermsTransferLocation,

      IncotermsLocation1,
      @Semantics.quantity.unitOfMeasure: 'PurchaseOrderPriceUnit'
      MaximumOrderQuantity,

      IsRelevantForAutomSrcg,

      SupplierQuotation,

      SupplierQuotationDate,

      MinRemainingShelfLife,

      IsEvaluatedRcptSettlmtAllowed,

      IsPurOrderAllwdForInbDeliv,

      IsOrderAcknRqd,

      IsRetMatlAuthznRqdBySupplier,

      IsCashDiscountGranted,

      MaterialConditionGroup,

      PurchasingDocumentDate,

      ShelfLifeExpirationDatePeriod,

      IsEndOfPurposeBlocked,
      
      @ObjectModel.sapObjectNodeTypeReference: 'SupplierConfirmationControlKey'
      SupplierConfirmationControlKey,
      
      PricingDateControl,
      
      TimeDependentTaxValidFromDate,
   //   @ObjectModel.sapObjectNodeTypeReference: 'Country'

      TaxCountry,
      
      MaterialRoundingProfile,
      
      MatlMstrTxtIsNotRlvtForPOItm,
      
      @ObjectModel.association.type: [#TO_COMPOSITION_PARENT, #TO_COMPOSITION_ROOT]
      _PurgInfoRecd,
      
      _PurInfoRecdPrcgCndnValidity,
      
      _PurInfoRecdPurOrgText
      

}
//where

//       IsEndOfPurposeBlocked        <> 'X'

//  or   IsEndOfPurposeBlocked        is null

//

//  and(

//       PurchasingOrganization       <> ''

//  )

//  and(

//       PurchasingInfoRecordCategory =  '0'

//    or PurchasingInfoRecordCategory =  ''

//    or PurchasingInfoRecordCategory is null

//  )

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"A_PURCHASINGINFORECORD",
"I_PURGINFORECDORGPLANTDATA"
],
"ASSOCIATED":
[
"A_PURCHASINGINFORECORD",
"A_PURGINFORECDORGPOTEXT",
"A_PURINFORECDPRCGCNDNVALIDITY"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/