A_ProjectNetworkStatus

DDL: A_PROJECTNETWORKSTATUS Type: view_entity COMPOSITE

Project Network Status

A_ProjectNetworkStatus is a Composite CDS View that provides data about "Project Network Status" in SAP S/4HANA. It reads from 1 data source (I_ProjectNetworkBasicData) and exposes 9 fields with key fields ProjectNetwork, StatusCode. It has 1 association to related views.

1 data source(s) 9 fields

Data Sources (1)

SourceAliasJoin Type
I_ProjectNetworkBasicData _ProjectNetworkBasicData inner

Associations (1)

CardinalityTargetAliasCondition
[1..1] A_ProjectNetwork _ProjectNetwork $projection.ProjectNetwork = _ProjectNetwork.ProjectNetwork

Annotations (10)

NameValueLevelField
AccessControl.authorizationCheck #CHECK view
EndUserText.label Project Network Status view
Metadata.ignorePropagatedAnnotations true view
ObjectModel.usageType.serviceQuality #D view
ObjectModel.usageType.sizeCategory #XL view
ObjectModel.usageType.dataClass #MIXED view
VDM.viewType #COMPOSITE view
VDM.lifecycle.contract.type #PUBLIC_REMOTE_API view
OData.entitySet.name ProjectNetworkStatus view
OData.entityType.name ProjectNetworkStatus_Type view

Fields (9)

KeyFieldSource TableSource FieldDescription
KEY ProjectNetwork I_ProjectNetworkBasicData ProjectNetwork
KEY StatusCode _StatusObject StatusCode
StatusObject _StatusObject StatusObject
StatusProfile _StatusObject StatusProfile
StatusIsActive _StatusObject StatusIsActive
IsUserStatus _StatusObject IsUserStatus
StatusShortNameendasStatusShortName
StatusNameendasStatusName
_ProjectNetwork _ProjectNetwork 
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Project Network Status'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #D,
  sizeCategory: #XL,
  dataClass: #MIXED
}
@VDM: {
    viewType: #COMPOSITE,
    lifecycle.contract.type: #PUBLIC_REMOTE_API
}
@OData.entitySet.name: 'ProjectNetworkStatus'
@OData.entityType.name: 'ProjectNetworkStatus_Type'

define view entity A_ProjectNetworkStatus
  as select distinct from  I_StatusObjectStatus      as _StatusObject
    inner join             I_ProjectNetworkBasicData as _ProjectNetworkBasicData on _ProjectNetworkBasicData.ProjectNetworkObject = _StatusObject.StatusObject
    left outer to one join I_StatusCodeText          as _StatusCodeText          on  _StatusObject.StatusCode = _StatusCodeText.StatusCode
                                                                                 and _StatusCodeText.Language = $session.system_language

  //Get user status short name and description

    left outer to one join I_UserStatusText          as _UserStatusText          on  _StatusObject.StatusProfile = _UserStatusText.StatusProfile
                                                                                 and _StatusObject.StatusCode    = _UserStatusText.UserStatus
                                                                                 and _UserStatusText.Language    = $session.system_language

  association [1..1] to A_ProjectNetwork as _ProjectNetwork on $projection.ProjectNetwork = _ProjectNetwork.ProjectNetwork
{
  key _ProjectNetworkBasicData.ProjectNetwork,
  key _StatusObject.StatusCode,
      _StatusObject.StatusObject,
      _StatusObject.StatusProfile,
      _StatusObject.StatusIsActive,

      _StatusObject.IsUserStatus as IsUserStatus,      

      case _StatusObject.IsUserStatus
       when 'X' then _UserStatusText.UserStatusShortName
       else  _StatusCodeText.StatusShortName
      end                        as StatusShortName,

      case _StatusObject.IsUserStatus
        when 'X' then _UserStatusText.UserStatusName
        else _StatusCodeText.StatusName
      end                        as StatusName,

      _ProjectNetwork
}
where
  _StatusCodeText._StatusCode.StatusIsHidden = ''
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_PROJECTNETWORKBASICDATA",
"I_STATUSCODE",
"I_STATUSCODETEXT",
"I_STATUSOBJECTSTATUS",
"I_USERSTATUSTEXT"
],
"ASSOCIATED":
[
"A_PROJECTNETWORK"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More