A_ProductionOrder_2

@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Production Order'
@VDM.viewType: #COMPOSITE
@AccessControl.personalData.blocking: #REQUIRED
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.representativeKey: 'ManufacturingOrder'
@ObjectModel.createEnabled: true
@ObjectModel.updateEnabled: true
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #XL, dataClass: #MIXED}
@VDM.lifecycle.contract.type: #PUBLIC_REMOTE_API

  define view entity A_ProductionOrder_2 as select from I_MfgOrderDuration

  association [0..*] to A_ProductionOrderOperation_2 as _ProductionOrderOperation          // Operations

                                                     on  $projection.ManufacturingOrder = _ProductionOrderOperation.ManufacturingOrder
                                                      
  association [0..*] to A_ProductionOrderComponent_2 as _ProductionOrderComponent          // Components

                                                     on  $projection.ManufacturingOrder = _ProductionOrderComponent.ManufacturingOrder
                                                      
  association [0..*] to A_ProductionOrderComponent_3 as _ProductionOrderComponentExt  // Components with Recordtype and Extensibility

                                                     on  $projection.ManufacturingOrder = _ProductionOrderComponentExt.ManufacturingOrder

  association [0..*] to A_ProductionOrderComponent_4 as _ProductionOrderComponentExt4  // Components with Recordtype and Extensibility. Change via RAP BO

                                                     on  $projection.ManufacturingOrder = _ProductionOrderComponentExt4.ManufacturingOrder

  association [0..*] to A_ProductionOrderItem_2      as _ProductionOrderItem               // Items

                                                     on  $projection.ManufacturingOrder = _ProductionOrderItem.ManufacturingOrder
                                                      
  association [0..*] to A_ProductionOrderStatus_2    as _ProductionOrderStatus             // Status

                                                     on  $projection.ManufacturingOrder = _ProductionOrderStatus.ManufacturingOrder

//Name of the A-View A_ProductionRsceTools_2 is not correct, this should be corrected with Production Order (Version 3) see also Process Order (Version 2)                                                      

  association [0..*] to A_ProductionRsceTools_2      as _ProductionRsceTools               // PRT   

                                                     on  $projection.ManufacturingOrder = _ProductionRsceTools.ManufacturingOrder
                                                      
  association [1..1] to E_LogisticsOrder             as _Extension                         // Extensibility

                                                     on  $projection.ManufacturingOrder = _Extension.OrderID
                                                                                                                                                     
{
      // Key

  @ObjectModel.sapObjectNodeTypeReference: 'ProductionOrder'
  key cast(ManufacturingOrder                        as vdm_manufacturingorder preserving type) as ManufacturingOrder,                                                         

      // Category and Type

      @ObjectModel.sapObjectNodeTypeReference: 'ManufacturingOrderCategory'
      ManufacturingOrderCategory,
      @ObjectModel.sapObjectNodeTypeReference: 'ManufacturingOrderType'
      ManufacturingOrderType,
      
      // Text

      @Semantics.text:true
      _LongText.PlainLongText                        as OrderLongText,                     // New field in CE2008


      // Attributes

      @ObjectModel.sapObjectNodeTypeReference: 'ManufacturingOrderImportance'
      ManufacturingOrderImportance,                                                        // New change field in CE2008         


      // Status

      OrderIsCreated,
      OrderIsReleased,
      OrderIsPrinted,
      OrderIsConfirmed,
      OrderIsPartiallyConfirmed,
      OrderIsDelivered,
      OrderIsDeleted,
      OrderIsPreCosted,
      SettlementRuleIsCreated,
      OrderIsPartiallyReleased,
      OrderIsLocked,
      OrderIsTechnicallyCompleted,
      OrderIsClosed,
      OrderIsPartiallyDelivered,
      OrderIsMarkedForDeletion,
      SettlementRuleIsCrtedManually,
      OrderIsScheduled,
      OrderHasGeneratedOperations,
      OrderIsToBeHandledInBatches,
      MaterialAvailyIsNotChecked,

      // Admin

      MfgOrderCreationDate,
      MfgOrderCreationTime,      
      case LastChangeDate
        when '00000000' then                                                               // not changed yet, use create

          concat(MfgOrderCreationDate,MfgOrderCreationTime)          
        else
          concat(LastChangeDate,LastChangeTime)
      end                                            as LastChangeDateTime,                // eTag


      // Header Material data          

      Material,
      @ObjectModel.sapObjectNodeTypeReference: 'StorageLocation'                                                                            
      StorageLocation,                                                                     // New change field in CE2008

      @Semantics.text: true      
      GoodsRecipientName,                                                                  // New change field in CE2008

      @Semantics.text: true   
      UnloadingPointName,                                                                  // New change field in CE2008

      @ObjectModel.sapObjectNodeTypeReference: 'InventoryUsabilityCode'
      InventoryUsabilityCode,                                                              // New change field in CE2008       

      MaterialGoodsReceiptDuration,                                                        // New change field in CE2008

      QuantityDistributionKey,                                                             // New change field in CE2008

      StockSegment,                                                                        // New change field in CE2008

                    
      // Assignments

      OrderInternalBillOfOperations,
      ProductionPlant,
      MRPPlant                                  as Plant,
      @ObjectModel.sapObjectNodeTypeReference: 'MRPArea'      
      MRPArea,
      @ObjectModel.sapObjectNodeTypeReference: 'MRPController'
      MRPController,                                                                       // New change field in CE2008

      @ObjectModel.sapObjectNodeTypeReference: 'ProductionSupervisor'    
      ProductionSupervisor,
      ProductionVersion,                                                                   // New change field in CE2008    

      @ObjectModel.sapObjectNodeTypeReference: 'PlannedOrder'
      PlannedOrder,
      @ObjectModel.sapObjectNodeTypeReference: 'SalesOrder'
      SalesOrder,
      SalesOrderItem,
      @ObjectModel.sapObjectNodeTypeReference: 'SchedulingType'
      BasicSchedulingType,
      ObjectInternalID as ManufacturingObject,
      ProductConfiguration,                                                                // New field in CE2008

      OrderSequenceNumber,                                                                 // New change field in CE2008    

 
      // Assignments FI/CO

      @ObjectModel.sapObjectNodeTypeReference: 'BusinessArea'
      BusinessArea,                                                                        // New change field in CE2008                                

      @ObjectModel.sapObjectNodeTypeReference: 'CompanyCode'
      CompanyCode,
      @ObjectModel.sapObjectNodeTypeReference: 'ProfitCenter'
      ProfitCenter,                                                                        // New change field in CE2008

      @EndUserText.label: 'Actual Costing Variant'
      @ObjectModel.sapObjectNodeTypeReference: 'CostingVariant'
      ActualCostsCostingVariant,
      @EndUserText.label: 'Planned Costing Variant'
      PlannedCostsCostingVariant,
      FunctionalArea,                            
                   
      // Dates and Times

      MfgOrderPlannedStartDate,
      MfgOrderPlannedStartTime,
      MfgOrderPlannedEndDate,
      MfgOrderPlannedEndTime,
      MfgOrderScheduledStartDate,
      MfgOrderScheduledStartTime,
      MfgOrderScheduledEndDate,
      MfgOrderScheduledEndTime,
      MfgOrderActualReleaseDate,
                 
      // Quantities and UoM

      ProductionUnit,
      _ProductionUnit.UnitOfMeasureISOCode           as ProductionUnitISOCode,             // CE2105 

      _ProductionUnit.UnitOfMeasureSAPCode           as ProductionUnitSAPCode,             // CE2105

      @Semantics.quantity.unitOfMeasure: 'ProductionUnit'
      MfgOrderPlannedTotalQty                        as TotalQuantity,
      @Semantics.quantity.unitOfMeasure: 'ProductionUnit'
      MfgOrderPlannedScrapQty,
      @Semantics.quantity.unitOfMeasure: 'ProductionUnit'
      MfgOrderConfirmedYieldQty,
      
      // Associations

      _SalesDocument._SoldToParty.CustomerName       as CustomerName,
      _WBSElementBasicData.WBSElementExternalID,                                           // New field in CE2008

      _ProductionOrderOperation,
      _ProductionOrderComponent,
      _ProductionOrderComponentExt,
      _ProductionOrderComponentExt4,
      _ProductionOrderStatus,
      _ProductionOrderItem,
      _ProductionRsceTools

}
where
  ManufacturingOrderCategory = '10';
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CUSTOMER",
"I_MFGORDERDURATION",
"I_ORDERLONGTEXT",
"I_SALESDOCUMENT",
"I_UNITOFMEASURE",
"I_WBSELEMENTBASICDATA"
],
"ASSOCIATED":
[
"A_PRODUCTIONORDERCOMPONENT_2",
"A_PRODUCTIONORDERCOMPONENT_3",
"A_PRODUCTIONORDERCOMPONENT_4",
"A_PRODUCTIONORDERITEM_2",
"A_PRODUCTIONORDEROPERATION_2",
"A_PRODUCTIONORDERSTATUS_2",
"A_PRODUCTIONRSCETOOLS_2"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/