A_ProcessOrderOperation_2

@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Process Order Operations'
@VDM.viewType: #COMPOSITE
@AccessControl.personalData.blocking: #NOT_REQUIRED
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #XL, dataClass: #MIXED}
@VDM.lifecycle.contract.type: #PUBLIC_REMOTE_API

define view entity A_ProcessOrderOperation_2
  as select from I_MfgOrderOperationDurn
  association [1..1] to E_OrderOperation              as _Extension   // Extensibility

                                                      on  $projection.OrderInternalBillOfOperations = _Extension.OrderInternalID
                                                      and $projection.OrderIntBillOfOperationsItem  = _Extension.OrderOperationInternalID
  association [1..1] to I_MfgOrderSequence      as _OrderSequence             on  $projection.ManufacturingOrder            = _OrderSequence.ManufacturingOrder
                                                                              and $projection.ManufacturingOrderSequence    = _OrderSequence.ManufacturingOrderSequence
                                                                              and $projection.OrderInternalBillOfOperations = _OrderSequence.OrderInternalID                                                                                       
  
{
      // Technical Key

  key OrderInternalBillOfOperations,
  key OrderIntBillOfOperationsItem,
  
      // Semantical Key

      @ObjectModel.sapObjectNodeTypeReference: 'ProductionOrder'
      cast(ManufacturingOrder as co_bid preserving type)                                as ManufacturingOrder, 
      ManufacturingOrderSequence,
      cast(_OrderSequence.MfgOrderSequenceText as mfgordersequencetext preserving type) as MfgOrderSequenceText,
      @ObjectModel.text.element: ['MfgOrderOperationText']
      ManufacturingOrderOperation,    
      ManufacturingOrderSubOperation,
      
      // Order header data

      @ObjectModel.sapObjectNodeTypeReference: 'ManufacturingOrderCategory'
      ManufacturingOrderCategory,
      @ObjectModel.sapObjectNodeTypeReference: 'ManufacturingOrderType'
      ManufacturingOrderType,
          
      // Text

      MfgOrderOperationText,
      @Semantics.text:true
      _LongText.OrderOperationLongText,
      
      // Attributes

      MfgOrderOperationIsPhase,       // CE2208

      MfgOrdPhaseSuperiorOperation_2 as MfgOrderPhaseSuperiorOperation, // CE2208 No conv. exit


      // Status

      OperationIsCreated,
      OperationIsReleased,
      OperationIsPrinted,
      OperationIsConfirmed,
      OperationIsPartiallyConfirmed,
      OperationIsDeleted,
      OperationIsTechlyCompleted,
      OperationIsClosed,
      OperationIsScheduled,
      OperationIsPartiallyDelivered,
      OperationIsDelivered,
      
      // Assignments

      ProductionPlant,
      WorkCenterInternalID,       
      @EndUserText.label: 'Work Center Type Code ' 
      WorkCenterTypeCode,
      WorkCenter,
      OperationControlProfile, 
      
      // Dates and Times      

      OpErlstSchedldExecStrtDte,       
      OpErlstSchedldExecStrtTme,  
      OpErlstSchedldExecEndDte,            
      OpErlstSchedldExecEndTme,     
      OpActualExecutionStartDate,     
      OpActualExecutionStartTime, 
      OpActualExecutionEndDate,       
      OpActualExecutionEndTime, 

      // Durations               

      @EndUserText.label:'Scheduled Execution Duration'
      ErlstSchedldExecDurnInWorkdays, 
      @EndUserText.label:'Actual Execution Duration'
      OpActualExecutionDays,
      
      // Quantities and UoM

      OperationUnit,
      _OperationUnit.UnitOfMeasureISOCode as OperationUnitISOCode,        // CE2105

      _OperationUnit.UnitOfMeasureSAPCode as OperationUnitSAPCode,        // CE2105

      @Semantics.quantity.unitOfMeasure: 'OperationUnit'
      OpPlannedTotalQuantity,
      @Semantics.quantity.unitOfMeasure: 'OperationUnit'
      OpTotalConfirmedYieldQty,       
     
      // Admin 

      case I_MfgOrderOperationDurn._MfgOrder.LastChangeDate
        when '00000000' then  // not changed yet, use create

          concat(I_MfgOrderOperationDurn._MfgOrder.MfgOrderCreationDate , I_MfgOrderOperationDurn._MfgOrder.MfgOrderCreationTime)
        else
          concat(I_MfgOrderOperationDurn._MfgOrder.LastChangeDate,I_MfgOrderOperationDurn._MfgOrder.LastChangeTime)
      end                                 as LastChangeDateTime           //eTag


}
where
  ManufacturingOrderCategory = '40';
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_MFGORDER",
"I_MFGORDEROPERATIONDURN",
"I_MFGORDERSEQUENCE",
"I_ORDEROPERATIONLONGTEXT",
"I_UNITOFMEASURE"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/