A_ProcOrdConfMatlDocItem

@EndUserText.label: 'Material Movements for Confirmation'
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED

@ObjectModel.usageType: {serviceQuality: #D, sizeCategory: #XL, dataClass: #MIXED}

@OData.entitySet.name: 'ProcOrdConfMatlDocItm'

@VDM.viewType: #COMPOSITE
@VDM.lifecycle.contract.type: #PUBLIC_REMOTE_API
@Metadata.ignorePropagatedAnnotations: true
define view entity A_ProcOrdConfMatlDocItem 
  as select from I_MfgOrderConfMatlDocItem
  association to parent A_ProcOrdConfirmation_2 as _ProcOrdConf on $projection.ConfirmationGroup = _ProcOrdConf.ConfirmationGroup
                                                               and $projection.ConfirmationCount = _ProcOrdConf.ConfirmationCount
  association [0..1] to A_Supplier              as _Supplier    on $projection.Supplier          = _Supplier.Supplier
  association [0..1] to A_Customer              as _Customer    on $projection.Customer          = _Customer.Customer      
  composition [0..*] of A_ProcOrderConfBatchCharc as _ProcOrderConfBatchCharc              // new in CE2102

{

//Key

  key MfgOrderConfirmationGroup                 as ConfirmationGroup, 
  key MfgOrderConfirmation                      as ConfirmationCount,
  @ObjectModel.sapObjectNodeTypeReference: 'MaterialDocument'
  key MaterialDocument,
  key MaterialDocumentItem,
  key MaterialDocumentYear, 

//General remarks

//eTag Field is not necessary in the proessuction orrder confirmation process.

//Same behavior implemented like in the material document.


//Order and Operation Data

  @ObjectModel.sapObjectNodeTypeReference: 'WorkOrderType'
  ManufacturingOrderType                        as OrderType,
  ManufacturingOrder                            as OrderID,
  ManufacturingOrderItem                        as OrderItem,
  @ObjectModel.sapObjectNodeTypeReference: 'ManufacturingOrderCategory'
  ManufacturingOrderCategory,                   // new field in CE2002

  
//Goods Movement Data  

  Material,
  Plant,
  @ObjectModel.sapObjectNodeTypeReference: 'ReservationDocument'
  Reservation,
  ReservationItem,
  @ObjectModel.sapObjectNodeTypeReference: 'StorageLocation'
  StorageLocation,
  cast( '' as prvbe ) as ProductionSupplyArea,     // only needed for create, "write-only"       // New field in CE2008!

  Batch,
  @ObjectModel.sapObjectNodeTypeReference: 'ProductValuationType'
  InventoryValuationType,
  @ObjectModel.sapObjectNodeTypeReference: 'GoodsMovementType'
  GoodsMovementType,
  @ObjectModel.sapObjectNodeTypeReference: 'GoodsMovementReason'
  GoodsMovementReasonCode,
  @ObjectModel.sapObjectNodeTypeReference: 'GoodsMovementReferenceDocType'
  GoodsMovementRefDocType,
  @ObjectModel.sapObjectNodeTypeReference: 'InventoryUsabilityCode'
  InventoryUsabilityCode,
  @ObjectModel.sapObjectNodeTypeReference: 'InventorySpecialStockType'
  InventorySpecialStockType,
  @ObjectModel.sapObjectNodeTypeReference: 'SalesOrder'
  SalesOrder,
  SalesOrderItem,
  _WBSElement.WBSElementExternalID,
  Supplier,
  Customer,
  ReservationIsFinallyIssued,
  IsCompletelyDelivered,                                                
  ShelfLifeExpirationDate,
  ManufactureDate,
  StorageType,
  StorageBin,
  
// EWM Data

  @ObjectModel.sapObjectNodeTypeReference: 'Warehouse'
  EWMWarehouse,
  @ObjectModel.sapObjectNodeTypeReference: 'WarehouseStorageBin'
  EWMStorageBin,

// Text

  MaterialDocumentItemText,

//Quantities and UoM

  EntryUnit,
  _EntryUnit.UnitOfMeasureISOCode               as EntryUnitISOCode,                  // New field in CE2002!

  _EntryUnit.UnitOfMeasureSAPCode               as EntryUnitSAPCode,                  // CE2102 

  @Semantics.quantity.unitOfMeasure: 'EntryUnit'
  QuantityInEntryUnit,
 
//Associations

  _ProcOrdConf,
  @Consumption.hidden: true 
  _Supplier,
  @Consumption.hidden: true 
  _Customer,
  _ProcOrderConfBatchCharc
}
where ManufacturingOrderCategory = '40';
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_MFGORDERCONFMATLDOCITEM",
"I_UNITOFMEASURE",
"I_WBSELEMENTBASICDATA"
],
"ASSOCIATED":
[
"A_CUSTOMER",
"A_PROCORDCONFIRMATION_2",
"A_PROCORDERCONFBATCHCHARC",
"A_SUPPLIER"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/