A_MaterialDocumentItem

@VDM.lifecycle.contract.type: #PUBLIC_REMOTE_API
@AbapCatalog.preserveKey: true
@AbapCatalog.sqlViewName: 'AMATDOCITEM'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Document Items'
@VDM.viewType : #COMPOSITE
@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel.createEnabled: false
@ObjectModel.updateEnabled: false
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #TRANSACTIONAL

@Metadata.ignorePropagatedAnnotations:true
define view A_MaterialDocumentItem
  as select from I_GoodsMovementDocument

  association [1..1] to A_MaterialDocumentHeader       as _MaterialDocumentHeader        on  $projection.MaterialDocumentYear = _MaterialDocumentHeader.MaterialDocumentYear
                                                                                         and $projection.MaterialDocument     = _MaterialDocumentHeader.MaterialDocument

  association [1..1] to E_MaterialDocumentItem         as _ProcessExtension              on  $projection.MaterialDocument                 = _ProcessExtension.MaterialDocument
                                                                                         and $projection.MaterialDocumentYear             = _ProcessExtension.MaterialDocumentYear
                                                                                         and $projection.MaterialDocumentItem             = _ProcessExtension.MaterialDocumentItem
                                                                                         and _ProcessExtension.MaterialDocumentRecordType = 'MDOC'
  association [1..1] to E_MaterialDocumentItem_2       as _MaterialDocumentItemExtension on  $projection.MaterialDocument                              = _MaterialDocumentItemExtension.MaterialDocument
                                                                                         and $projection.MaterialDocumentYear                          = _MaterialDocumentItemExtension.MaterialDocumentYear
                                                                                         and $projection.MaterialDocumentItem                          = _MaterialDocumentItemExtension.MaterialDocumentItem
                                                                                         and _MaterialDocumentItemExtension.MaterialDocumentRecordType = 'MDOC'

  association [0..*] to A_SerialNumberMaterialDocument as _SerialNumbers                 on  $projection.MaterialDocument     = _SerialNumbers.MaterialDocument
                                                                                         and $projection.MaterialDocumentItem = _SerialNumbers.MaterialDocumentItem
                                                                                         and $projection.MaterialDocumentYear = _SerialNumbers.MaterialDocumentYear

  association [0..1] to A_Supplier                     as _AuthSupplier                  on  $projection.Supplier = _AuthSupplier.Supplier

  association [0..1] to A_Customer                     as _AuthCustomer                  on  $projection.Customer = _AuthCustomer.Customer

  association [0..1] to I_SupplierCompanyByPlant       as _SupplierCompanyByPlant        on  $projection.Supplier = _SupplierCompanyByPlant.Supplier
                                                                                         and $projection.Plant    = _SupplierCompanyByPlant.Plant

  association [0..1] to I_CustomerCompanyByPlant       as _CustomerCompanyByPlant        on  $projection.Customer = _CustomerCompanyByPlant.Customer
                                                                                         and $projection.Plant    = _CustomerCompanyByPlant.Plant

{
  key MaterialDocumentYear,
  key MaterialDocument,
  key MaterialDocumentItem,

      Material,
      Plant,
      @ObjectModel.sapObjectNodeTypeReference: 'StorageLocation'
      StorageLocation,
      Batch,
      @ObjectModel.sapObjectNodeTypeReference: 'GoodsMovementType'
      GoodsMovementType,
      @ObjectModel.sapObjectNodeTypeReference: 'InventoryStockType'
      InventoryStockType,
      @ObjectModel.sapObjectNodeTypeReference: 'ProductValuationType'
      InventoryValuationType,
      @ObjectModel.sapObjectNodeTypeReference: 'InventorySpecialStockType'
      InventorySpecialStockType,

      Supplier,
      Customer,
      SalesOrder,
      SalesOrderItem,
      SalesOrderScheduleLine,
      PurchaseOrder,
      PurchaseOrderItem,
      _WBSElement.WBSElement,

      ManufacturingOrder,
      ManufacturingOrderItem,
      @ObjectModel.sapObjectNodeTypeReference: 'GoodsMovementReferenceDocType'
      GoodsMovementRefDocType,
      @ObjectModel.sapObjectNodeTypeReference: 'GoodsMovementReason'
      GoodsMovementReasonCode,

      //Delivery - aliasing is done to be consistent with SOAP service

      DeliveryDocument                                    as Delivery,
      DeliveryDocumentItem                                as DeliveryItem,

      //Accounting information

      @ObjectModel.sapObjectNodeTypeReference: 'AccountAssignmentCategory'
      AccountAssignmentCategory,
      CostCenter,
      ControllingArea,
      CostObject,
      GLAccount,
      FunctionalArea,
      ProfitabilitySegment_2 as ProfitabilitySegment,
      ProfitCenter,
      MasterFixedAsset,
      FixedAsset,

      //Quantities

      @Semantics.unitOfMeasure: true
      MaterialBaseUnit,
      @Semantics.quantity.unitOfMeasure: 'MaterialBaseUnit'
      QuantityInBaseUnit,
      @Semantics.unitOfMeasure: true
      EntryUnit,
      @Semantics.quantity.unitOfMeasure: 'EntryUnit'
      QuantityInEntryUnit,

      //Amounts

      @ObjectModel.sapObjectNodeTypeReference: 'Currency'
      @Semantics.currencyCode: true
      CompanyCodeCurrency,
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      GdsMvtExtAmtInCoCodeCrcy,
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      case when EnteredSlsAmtInCoCodeCrcy <> 0 then SlsPrcAmtInclVATInCoCodeCrcy
                                               else 0 end as SlsPrcAmtInclVATInCoCodeCrcy,

      FiscalYear,
      FiscalYearPeriod,
      @ObjectModel.sapObjectNodeTypeReference: 'FiscalYearVariant'
      FiscalYearVariant,

      IssgOrRcvgMaterial,
      IssgOrRcvgBatch,
      IssuingOrReceivingPlant,
      IssuingOrReceivingStorageLoc,
      @ObjectModel.sapObjectNodeTypeReference: 'InventoryStockType'
      IssuingOrReceivingStockType,
      @ObjectModel.sapObjectNodeTypeReference: 'InventorySpecialStockType'
      IssgOrRcvgSpclStockInd,
      @ObjectModel.sapObjectNodeTypeReference: 'ProductValuationType'
      IssuingOrReceivingValType,

      IsCompletelyDelivered,
      @Semantics.text: true
      MaterialDocumentItemText,
      GoodsRecipientName,                                                      //3250177

      UnloadingPointName,
      ShelfLifeExpirationDate,
      ManufactureDate,
      SerialNumbersAreCreatedAutomly,

      Reservation,
      ReservationItem,
      ReservationIsFinallyIssued,

      SpecialStockIdfgSalesOrder,
      SpecialStockIdfgSalesOrderItem,
      _SpecialStockIdfgWBSElement.WBSElement              as SpecialStockIdfgWBSElement,


      //Automatically created entries

      IsAutomaticallyCreated,
      MaterialDocumentLine,
      MaterialDocumentParentLine,
      HierarchyNodeLevel,

      // Cancellation information

      GoodsMovementIsCancelled,
      ReversedMaterialDocumentYear,
      ReversedMaterialDocument,
      ReversedMaterialDocumentItem,

      //Reference Document

      ReferenceDocumentFiscalYear,
      InvtryMgmtRefDocumentItem,
      InvtryMgmtReferenceDocument,
      @ObjectModel.sapObjectNodeTypeReference: 'MaterialDocumentPostingType'
      MaterialDocumentPostingType,

      //Stock type

      @ObjectModel.sapObjectNodeTypeReference: 'InventoryUsabilityCode'
      InventoryUsabilityCode,

      //EWM Data

      @ObjectModel.sapObjectNodeTypeReference: 'Warehouse'
      EWMWarehouse,
      EWMStorageBin,
      
      DebitCreditCode,

      // Serial Numbers

      _SerialNumbers,

      @ObjectModel: { association: { type: [#TO_COMPOSITION_PARENT , #TO_COMPOSITION_ROOT] } }
      _MaterialDocumentHeader,

      //only for DCL

      @Consumption.hidden: true
      _AuthSupplier,
      @Consumption.hidden: true
      _AuthCustomer,
      @Consumption.hidden: true
      _SupplierCompanyByPlant,
      @Consumption.hidden: true
      _CustomerCompanyByPlant

}
where
  MaterialDocumentRecordType = 'MDOC'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_GOODSMOVEMENTDOCUMENT",
"I_WBSELEMENTBYINTERNALKEY"
],
"ASSOCIATED":
[
"A_CUSTOMER",
"A_MATERIALDOCUMENTHEADER",
"A_SERIALNUMBERMATERIALDOCUMENT",
"A_SUPPLIER",
"E_MATERIALDOCUMENTITEM",
"E_MATERIALDOCUMENTITEM_2",
"I_CUSTOMERCOMPANYBYPLANT",
"I_SUPPLIERCOMPANYBYPLANT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/